config/zconf.y

   1 %{
   2 /*
   3  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   4  * Released under the terms of the GNU GPL v2.0.
   5  */
   6
   7 #include <ctype.h>
   8 #include <stdarg.h>
   9 #include <stdio.h>
  10 #include <stdlib.h>
  11 #include <string.h>
  12 #include <stdbool.h>
  13
  14 #include "lkc.h"
  15
  16 #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  17
  18 #define PRINTD          0x0001
  19 #define DEBUG_PARSE     0x0002
  20
  21 int cdebug = PRINTD;
  22
  23 extern int zconflex(void);
  24 static void zconfprint(const char *err, ...);
  25 static void zconf_error(const char *err, ...);
  26 static void zconferror(const char *err);
  27 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);
  28
  29 struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  30
  31 static struct menu *current_menu, *current_entry;
  32
  33 %}
  34 %expect 32
  35
  36 %union
  37 {
  38         char *string;
  39         struct file *file;
  40         struct symbol *symbol;
  41         struct expr *expr;
  42         struct menu *menu;
  43         const struct kconf_id *id;
  44 }
  45
  46 %token <id>T_MAINMENU
  47 %token <id>T_MENU
  48 %token <id>T_ENDMENU
  49 %token <id>T_SOURCE
  50 %token <id>T_CHOICE
  51 %token <id>T_ENDCHOICE
  52 %token <id>T_COMMENT
  53 %token <id>T_CONFIG
  54 %token <id>T_MENUCONFIG
  55 %token <id>T_HELP
  56 %token <string> T_HELPTEXT
  57 %token <id>T_IF
  58 %token <id>T_ENDIF
  59 %token <id>T_DEPENDS
  60 %token <id>T_OPTIONAL
  61 %token <id>T_PROMPT
  62 %token <id>T_TYPE
  63 %token <id>T_DEFAULT
  64 %token <id>T_SELECT
  65 %token <id>T_IMPLY
  66 %token <id>T_RANGE
  67 %token <id>T_VISIBLE
  68 %token <id>T_OPTION
  69 %token <id>T_ON
  70 %token <string> T_WORD
  71 %token <string> T_WORD_QUOTE
  72 %token T_UNEQUAL
  73 %token T_LESS
  74 %token T_LESS_EQUAL
  75 %token T_GREATER
  76 %token T_GREATER_EQUAL
  77 %token T_CLOSE_PAREN
  78 %token T_OPEN_PAREN
  79 %token T_EOL
  80
  81 %left T_OR
  82 %left T_AND
  83 %left T_EQUAL T_UNEQUAL
  84 %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  85 %nonassoc T_NOT
  86
  87 %type <string> prompt
  88 %type <symbol> nonconst_symbol
  89 %type <symbol> symbol
  90 %type <expr> expr
  91 %type <expr> if_expr
  92 %type <id> end
  93 %type <id> option_name
  94 %type <menu> if_entry menu_entry choice_entry
  95 %type <string> symbol_option_arg word_opt
  96
  97 %destructor {
  98         fprintf(stderr, "%s:%d: missing end statement for this entry\n",
  99                 $$->file->name, $$->lineno);
 100         if (current_menu == $$)
 101                 menu_end_menu();
 102 } if_entry menu_entry choice_entry
 103
 104 %{
 105 /* Include kconf_id.c here so it can see the token constants. */
 106 #include "kconf_id.c"
 107 %}
 108
 109 %%
 110 input: nl start | start;
 111
 112 start: mainmenu_stmt stmt_list | stmt_list;
 113
 114 stmt_list:
 115           /* empty */
 116         | stmt_list common_stmt
 117         | stmt_list choice_stmt
 118         | stmt_list menu_stmt
 119         | stmt_list end                 { zconf_error("unexpected end statement"); }
 120         | stmt_list T_WORD error T_EOL  { zconf_error("unknown statement \"%s\"", $2); }
 121         | stmt_list option_name error T_EOL
 122 {
 123         zconf_error("unexpected option \"%s\"", $2->name);
 124 }
 125         | stmt_list error T_EOL         { zconf_error("invalid statement"); }
 126 ;
 127
 128 option_name:
 129         T_DEPENDS | T_PROMPT | T_TYPE | T_SELECT | T_IMPLY | T_OPTIONAL | T_RANGE | T_DEFAULT | T_VISIBLE
 130 ;
 131
 132 common_stmt:
 133           T_EOL
 134         | if_stmt
 135         | comment_stmt
 136         | config_stmt
 137         | menuconfig_stmt
 138         | source_stmt
 139 ;
 140
 141 option_error:
 142           T_WORD error T_EOL            { zconf_error("unknown option \"%s\"", $1); }
 143         | error T_EOL                   { zconf_error("invalid option"); }
 144 ;
 145
 146
 147 /* config/menuconfig entry */
 148
 149 config_entry_start: T_CONFIG nonconst_symbol T_EOL
 150 {
 151         $2->flags |= SYMBOL_OPTIONAL;
 152         menu_add_entry($2);
 153         printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2->name);
 154 };
 155
 156 config_stmt: config_entry_start config_option_list
 157 {
 158         menu_end_entry();
 159         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 160 };
 161
 162 menuconfig_entry_start: T_MENUCONFIG nonconst_symbol T_EOL
 163 {
 164         $2->flags |= SYMBOL_OPTIONAL;
 165         menu_add_entry($2);
 166         printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2->name);
 167 };
 168
 169 menuconfig_stmt: menuconfig_entry_start config_option_list
 170 {
 171         if (current_entry->prompt)
 172                 current_entry->prompt->type = P_MENU;
 173         else
 174                 zconfprint("warning: menuconfig statement without prompt");
 175         menu_end_entry();
 176         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 177 };
 178
 179 config_option_list:
 180           /* empty */
 181         | config_option_list config_option
 182         | config_option_list symbol_option
 183         | config_option_list depends
 184         | config_option_list help
 185         | config_option_list option_error
 186         | config_option_list T_EOL
 187 ;
 188
 189 config_option: T_TYPE prompt_stmt_opt T_EOL
 190 {
 191         menu_set_type($1->stype);
 192         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 193                 zconf_curname(), zconf_lineno(),
 194                 $1->stype);
 195 };
 196
 197 config_option: T_PROMPT prompt if_expr T_EOL
 198 {
 199         menu_add_prompt(P_PROMPT, $2, $3);
 200         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 201 };
 202
 203 config_option: T_DEFAULT expr if_expr T_EOL
 204 {
 205         menu_add_expr(P_DEFAULT, $2, $3);
 206         if ($1->stype != S_UNKNOWN)
 207                 menu_set_type($1->stype);
 208         printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
 209                 zconf_curname(), zconf_lineno(),
 210                 $1->stype);
 211 };
 212
 213 config_option: T_SELECT nonconst_symbol if_expr T_EOL
 214 {
 215         menu_add_symbol(P_SELECT, $2, $3);
 216         printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
 217 };
 218
 219 config_option: T_IMPLY nonconst_symbol if_expr T_EOL
 220 {
 221         menu_add_symbol(P_IMPLY, $2, $3);
 222         printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
 223 };
 224
 225 config_option: T_RANGE symbol symbol if_expr T_EOL
 226 {
 227         menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
 228         printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
 229 };
 230
 231 symbol_option: T_OPTION symbol_option_list T_EOL
 232 ;
 233
 234 symbol_option_list:
 235           /* empty */
 236         | symbol_option_list T_WORD symbol_option_arg
 237 {
 238         const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
 239         if (id && id->flags & TF_OPTION) {
 240                 menu_add_option(id->token, $3);
 241                 free($3);
 242         }
 243         else
 244                 zconfprint("warning: ignoring unknown option %s", $2);
 245         free($2);
 246 };
 247
 248 symbol_option_arg:
 249           /* empty */           { $$ = NULL; }
 250         | T_EQUAL prompt        { $$ = $2; }
 251 ;
 252
 253 /* choice entry */
 254
 255 choice: T_CHOICE word_opt T_EOL
 256 {
 257         struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
 258         sym->flags |= SYMBOL_AUTO;
 259         menu_add_entry(sym);
 260         menu_add_expr(P_CHOICE, NULL, NULL);
 261         printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
 262 };
 263
 264 choice_entry: choice choice_option_list
 265 {
 266         $$ = menu_add_menu();
 267 };
 268
 269 choice_end: end
 270 {
 271         if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
 272                 menu_end_menu();
 273                 printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
 274         }
 275 };
 276
 277 choice_stmt: choice_entry choice_block choice_end
 278 ;
 279
 280 choice_option_list:
 281           /* empty */
 282         | choice_option_list choice_option
 283         | choice_option_list depends
 284         | choice_option_list help
 285         | choice_option_list T_EOL
 286         | choice_option_list option_error
 287 ;
 288
 289 choice_option: T_PROMPT prompt if_expr T_EOL
 290 {
 291         menu_add_prompt(P_PROMPT, $2, $3);
 292         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 293 };
 294
 295 choice_option: T_TYPE prompt_stmt_opt T_EOL
 296 {
 297         if ($1->stype == S_BOOLEAN || $1->stype == S_TRISTATE) {
 298                 menu_set_type($1->stype);
 299                 printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 300                         zconf_curname(), zconf_lineno(),
 301                         $1->stype);
 302         } else
 303                 YYERROR;
 304 };
 305
 306 choice_option: T_OPTIONAL T_EOL
 307 {
 308         current_entry->sym->flags |= SYMBOL_OPTIONAL;
 309         printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
 310 };
 311
 312 choice_option: T_DEFAULT nonconst_symbol if_expr T_EOL
 313 {
 314         if ($1->stype == S_UNKNOWN) {
 315                 menu_add_symbol(P_DEFAULT, $2, $3);
 316                 printd(DEBUG_PARSE, "%s:%d:default\n",
 317                         zconf_curname(), zconf_lineno());
 318         } else
 319                 YYERROR;
 320 };
 321
 322 choice_block:
 323           /* empty */
 324         | choice_block common_stmt
 325 ;
 326
 327 /* if entry */
 328
 329 if_entry: T_IF expr nl
 330 {
 331         printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
 332         menu_add_entry(NULL);
 333         menu_add_dep($2);
 334         $$ = menu_add_menu();
 335 };
 336
 337 if_end: end
 338 {
 339         if (zconf_endtoken($1, T_IF, T_ENDIF)) {
 340                 menu_end_menu();
 341                 printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
 342         }
 343 };
 344
 345 if_stmt: if_entry if_block if_end
 346 ;
 347
 348 if_block:
 349           /* empty */
 350         | if_block common_stmt
 351         | if_block menu_stmt
 352         | if_block choice_stmt
 353 ;
 354
 355 /* mainmenu entry */
 356
 357 mainmenu_stmt: T_MAINMENU prompt nl
 358 {
 359         menu_add_prompt(P_MENU, $2, NULL);
 360 };
 361
 362 /* menu entry */
 363
 364 menu: T_MENU prompt T_EOL
 365 {
 366         menu_add_entry(NULL);
 367         menu_add_prompt(P_MENU, $2, NULL);
 368         printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
 369 };
 370
 371 menu_entry: menu visibility_list depends_list
 372 {
 373         $$ = menu_add_menu();
 374 };
 375
 376 menu_end: end
 377 {
 378         if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
 379                 menu_end_menu();
 380                 printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
 381         }
 382 };
 383
 384 menu_stmt: menu_entry menu_block menu_end
 385 ;
 386
 387 menu_block:
 388           /* empty */
 389         | menu_block common_stmt
 390         | menu_block menu_stmt
 391         | menu_block choice_stmt
 392 ;
 393
 394 source_stmt: T_SOURCE prompt T_EOL
 395 {
 396         printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
 397         zconf_nextfile($2);
 398         free($2);
 399 };
 400
 401 /* comment entry */
 402
 403 comment: T_COMMENT prompt T_EOL
 404 {
 405         menu_add_entry(NULL);
 406         menu_add_prompt(P_COMMENT, $2, NULL);
 407         printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
 408 };
 409
 410 comment_stmt: comment depends_list
 411 {
 412         menu_end_entry();
 413 };
 414
 415 /* help option */
 416
 417 help_start: T_HELP T_EOL
 418 {
 419         printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
 420         zconf_starthelp();
 421 };
 422
 423 help: help_start T_HELPTEXT
 424 {
 425         current_entry->help = $2;
 426 };
 427
 428 /* depends option */
 429
 430 depends_list:
 431           /* empty */
 432         | depends_list depends
 433         | depends_list T_EOL
 434         | depends_list option_error
 435 ;
 436
 437 depends: T_DEPENDS T_ON expr T_EOL
 438 {
 439         menu_add_dep($3);
 440         printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
 441 };
 442
 443 /* visibility option */
 444
 445 visibility_list:
 446           /* empty */
 447         | visibility_list visible
 448         | visibility_list T_EOL
 449 ;
 450
 451 visible: T_VISIBLE if_expr
 452 {
 453         menu_add_visibility($2);
 454 };
 455
 456 /* prompt statement */
 457
 458 prompt_stmt_opt:
 459           /* empty */
 460         | prompt if_expr
 461 {
 462         menu_add_prompt(P_PROMPT, $1, $2);
 463 };
 464
 465 prompt:   T_WORD
 466         | T_WORD_QUOTE
 467 ;
 468
 469 end:      T_ENDMENU T_EOL       { $$ = $1; }
 470         | T_ENDCHOICE T_EOL     { $$ = $1; }
 471         | T_ENDIF T_EOL         { $$ = $1; }
 472 ;
 473
 474 nl:
 475           T_EOL
 476         | nl T_EOL
 477 ;
 478
 479 if_expr:  /* empty */                   { $$ = NULL; }
 480         | T_IF expr                     { $$ = $2; }
 481 ;
 482
 483 expr:     symbol                                { $$ = expr_alloc_symbol($1); }
 484         | symbol T_LESS symbol                  { $$ = expr_alloc_comp(E_LTH, $1, $3); }
 485         | symbol T_LESS_EQUAL symbol            { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
 486         | symbol T_GREATER symbol               { $$ = expr_alloc_comp(E_GTH, $1, $3); }
 487         | symbol T_GREATER_EQUAL symbol         { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
 488         | symbol T_EQUAL symbol                 { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
 489         | symbol T_UNEQUAL symbol               { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
 490         | T_OPEN_PAREN expr T_CLOSE_PAREN       { $$ = $2; }
 491         | T_NOT expr                            { $$ = expr_alloc_one(E_NOT, $2); }
 492         | expr T_OR expr                        { $$ = expr_alloc_two(E_OR, $1, $3); }
 493         | expr T_AND expr                       { $$ = expr_alloc_two(E_AND, $1, $3); }
 494 ;
 495
 496 /* For symbol definitions, selects, etc., where quotes are not accepted */
 497 nonconst_symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); };
 498
 499 symbol:   nonconst_symbol
 500         | T_WORD_QUOTE  { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
 501 ;
 502
 503 word_opt: /* empty */                   { $$ = NULL; }
 504         | T_WORD
 505
 506 %%
 507
 508 void conf_parse(const char *name)
 509 {
 510         struct symbol *sym;
 511         int i;
 512
 513         zconf_initscan(name);
 514
 515         sym_init();
 516         _menu_init();
 517         rootmenu.prompt = menu_add_prompt(P_MENU, "CARL9170 Firmware Configuration", NULL);
 518
 519         if (getenv("ZCONF_DEBUG"))
 520                 zconfdebug = 1;
 521         zconfparse();
 522         if (zconfnerrs)
 523                 exit(1);
 524         if (!modules_sym)
 525                 modules_sym = sym_find( "n" );
 526
 527         rootmenu.prompt->text = _(rootmenu.prompt->text);
 528         rootmenu.prompt->text = sym_expand_string_value(rootmenu.prompt->text);
 529
 530         menu_finalize(&rootmenu);
 531         for_all_symbols(i, sym) {
 532                 if (sym_check_deps(sym))
 533                         zconfnerrs++;
 534         }
 535         if (zconfnerrs)
 536                 exit(1);
 537         sym_set_change_count(1);
 538 }
 539
 540 static const char *zconf_tokenname(int token)
 541 {
 542         switch (token) {
 543         case T_MENU:            return "menu";
 544         case T_ENDMENU:         return "endmenu";
 545         case T_CHOICE:          return "choice";
 546         case T_ENDCHOICE:       return "endchoice";
 547         case T_IF:              return "if";
 548         case T_ENDIF:           return "endif";
 549         case T_DEPENDS:         return "depends";
 550         case T_VISIBLE:         return "visible";
 551         }
 552         return "<token>";
 553 }
 554
 555 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
 556 {
 557         if (id->token != endtoken) {
 558                 zconf_error("unexpected '%s' within %s block",
 559                         id->name, zconf_tokenname(starttoken));
 560                 zconfnerrs++;
 561                 return false;
 562         }
 563         if (current_menu->file != current_file) {
 564                 zconf_error("'%s' in different file than '%s'",
 565                         id->name, zconf_tokenname(starttoken));
 566                 fprintf(stderr, "%s:%d: location of the '%s'\n",
 567                         current_menu->file->name, current_menu->lineno,
 568                         zconf_tokenname(starttoken));
 569                 zconfnerrs++;
 570                 return false;
 571         }
 572         return true;
 573 }
 574
 575 static void zconfprint(const char *err, ...)
 576 {
 577         va_list ap;
 578
 579         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 580         va_start(ap, err);
 581         vfprintf(stderr, err, ap);
 582         va_end(ap);
 583         fprintf(stderr, "\n");
 584 }
 585
 586 static void zconf_error(const char *err, ...)
 587 {
 588         va_list ap;
 589
 590         zconfnerrs++;
 591         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 592         va_start(ap, err);
 593         vfprintf(stderr, err, ap);
 594         va_end(ap);
 595         fprintf(stderr, "\n");
 596 }
 597
 598 static void zconferror(const char *err)
 599 {
 600         fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
 601 }
 602
 603 static void print_quoted_string(FILE *out, const char *str)
 604 {
 605         const char *p;
 606         int len;
 607
 608         putc('"', out);
 609         while ((p = strchr(str, '"'))) {
 610                 len = p - str;
 611                 if (len)
 612                         fprintf(out, "%.*s", len, str);
 613                 fputs("\\\"", out);
 614                 str = p + 1;
 615         }
 616         fputs(str, out);
 617         putc('"', out);
 618 }
 619
 620 static void print_symbol(FILE *out, struct menu *menu)
 621 {
 622         struct symbol *sym = menu->sym;
 623         struct property *prop;
 624
 625         if (sym_is_choice(sym))
 626                 fprintf(out, "\nchoice\n");
 627         else
 628                 fprintf(out, "\nconfig %s\n", sym->name);
 629         switch (sym->type) {
 630         case S_BOOLEAN:
 631                 fputs("  boolean\n", out);
 632                 break;
 633         case S_TRISTATE:
 634                 fputs("  tristate\n", out);
 635                 break;
 636         case S_STRING:
 637                 fputs("  string\n", out);
 638                 break;
 639         case S_INT:
 640                 fputs("  integer\n", out);
 641                 break;
 642         case S_HEX:
 643                 fputs("  hex\n", out);
 644                 break;
 645         default:
 646                 fputs("  ???\n", out);
 647                 break;
 648         }
 649         for (prop = sym->prop; prop; prop = prop->next) {
 650                 if (prop->menu != menu)
 651                         continue;
 652                 switch (prop->type) {
 653                 case P_PROMPT:
 654                         fputs("  prompt ", out);
 655                         print_quoted_string(out, prop->text);
 656                         if (!expr_is_yes(prop->visible.expr)) {
 657                                 fputs(" if ", out);
 658                                 expr_fprint(prop->visible.expr, out);
 659                         }
 660                         fputc('\n', out);
 661                         break;
 662                 case P_DEFAULT:
 663                         fputs( "  default ", out);
 664                         expr_fprint(prop->expr, out);
 665                         if (!expr_is_yes(prop->visible.expr)) {
 666                                 fputs(" if ", out);
 667                                 expr_fprint(prop->visible.expr, out);
 668                         }
 669                         fputc('\n', out);
 670                         break;
 671                 case P_CHOICE:
 672                         fputs("  #choice value\n", out);
 673                         break;
 674                 case P_SELECT:
 675                         fputs( "  select ", out);
 676                         expr_fprint(prop->expr, out);
 677                         fputc('\n', out);
 678                         break;
 679                 case P_IMPLY:
 680                         fputs( "  imply ", out);
 681                         expr_fprint(prop->expr, out);
 682                         fputc('\n', out);
 683                         break;
 684                 case P_RANGE:
 685                         fputs( "  range ", out);
 686                         expr_fprint(prop->expr, out);
 687                         fputc('\n', out);
 688                         break;
 689                 case P_MENU:
 690                         fputs( "  menu ", out);
 691                         print_quoted_string(out, prop->text);
 692                         fputc('\n', out);
 693                         break;
 694                 default:
 695                         fprintf(out, "  unknown prop %d!\n", prop->type);
 696                         break;
 697                 }
 698         }
 699         if (menu->help) {
 700                 int len = strlen(menu->help);
 701                 while (menu->help[--len] == '\n')
 702                         menu->help[len] = 0;
 703                 fprintf(out, "  help\n%s\n", menu->help);
 704         }
 705 }
 706
 707 void zconfdump(FILE *out)
 708 {
 709         struct property *prop;
 710         struct symbol *sym;
 711         struct menu *menu;
 712
 713         menu = rootmenu.list;
 714         while (menu) {
 715                 if ((sym = menu->sym))
 716                         print_symbol(out, menu);
 717                 else if ((prop = menu->prompt)) {
 718                         switch (prop->type) {
 719                         case P_COMMENT:
 720                                 fputs("\ncomment ", out);
 721                                 print_quoted_string(out, prop->text);
 722                                 fputs("\n", out);
 723                                 break;
 724                         case P_MENU:
 725                                 fputs("\nmenu ", out);
 726                                 print_quoted_string(out, prop->text);
 727                                 fputs("\n", out);
 728                                 break;
 729                         default:
 730                                 ;
 731                         }
 732                         if (!expr_is_yes(prop->visible.expr)) {
 733                                 fputs("  depends ", out);
 734                                 expr_fprint(prop->visible.expr, out);
 735                                 fputc('\n', out);
 736                         }
 737                 }
 738
 739                 if (menu->list)
 740                         menu = menu->list;
 741                 else if (menu->next)
 742                         menu = menu->next;
 743                 else while ((menu = menu->parent)) {
 744                         if (menu->prompt && menu->prompt->type == P_MENU)
 745                                 fputs("\nendmenu\n", out);
 746                         if (menu->next) {
 747                                 menu = menu->next;
 748                                 break;
 749                         }
 750                 }
 751         }
 752 }
 753
 754 #include "zconf.lex.c"
 755 #include "util.c"
 756 #include "confdata.c"
 757 #include "expr.c"
 758 #include "symbol.c"
 759 #include "menu.c"