config/zconf.y

   1 %{
   2 /*
   3  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   4  * Released under the terms of the GNU GPL v2.0.
   5  */
   6
   7 #include <ctype.h>
   8 #include <stdarg.h>
   9 #include <stdio.h>
  10 #include <stdlib.h>
  11 #include <string.h>
  12 #include <stdbool.h>
  13
  14 #include "lkc.h"
  15
  16 #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  17
  18 #define PRINTD          0x0001
  19 #define DEBUG_PARSE     0x0002
  20
  21 int cdebug = PRINTD;
  22
  23 int yylex(void);
  24 static void yyerror(const char *err);
  25 static void zconfprint(const char *err, ...);
  26 static void zconf_error(const char *err, ...);
  27 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);
  28
  29 struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  30
  31 static struct menu *current_menu, *current_entry;
  32
  33 %}
  34 %expect 21
  35
  36 %union
  37 {
  38         char *string;
  39         struct file *file;
  40         struct symbol *symbol;
  41         struct expr *expr;
  42         struct menu *menu;
  43         const struct kconf_id *id;
  44         enum variable_flavor flavor;
  45 }
  46
  47 %token <id>T_MAINMENU
  48 %token <id>T_MENU
  49 %token <id>T_ENDMENU
  50 %token <id>T_SOURCE
  51 %token <id>T_CHOICE
  52 %token <id>T_ENDCHOICE
  53 %token <id>T_COMMENT
  54 %token <id>T_CONFIG
  55 %token <id>T_MENUCONFIG
  56 %token <id>T_HELP
  57 %token <string> T_HELPTEXT
  58 %token <id>T_IF
  59 %token <id>T_ENDIF
  60 %token <id>T_DEPENDS
  61 %token <id>T_OPTIONAL
  62 %token <id>T_PROMPT
  63 %token <id>T_TYPE
  64 %token <id>T_DEFAULT
  65 %token <id>T_SELECT
  66 %token <id>T_IMPLY
  67 %token <id>T_RANGE
  68 %token <id>T_VISIBLE
  69 %token <id>T_OPTION
  70 %token <id>T_ON
  71 %token <string> T_WORD
  72 %token <string> T_WORD_QUOTE
  73 %token T_UNEQUAL
  74 %token T_LESS
  75 %token T_LESS_EQUAL
  76 %token T_GREATER
  77 %token T_GREATER_EQUAL
  78 %token T_CLOSE_PAREN
  79 %token T_OPEN_PAREN
  80 %token T_EOL
  81 %token <string> T_VARIABLE
  82 %token <flavor> T_ASSIGN
  83 %token <string> T_ASSIGN_VAL
  84
  85 %left T_OR
  86 %left T_AND
  87 %left T_EQUAL T_UNEQUAL
  88 %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  89 %nonassoc T_NOT
  90
  91 %type <string> prompt
  92 %type <symbol> nonconst_symbol
  93 %type <symbol> symbol
  94 %type <expr> expr
  95 %type <expr> if_expr
  96 %type <id> end
  97 %type <id> option_name
  98 %type <menu> if_entry menu_entry choice_entry
  99 %type <string> symbol_option_arg word_opt assign_val
 100
 101 %destructor {
 102         fprintf(stderr, "%s:%d: missing end statement for this entry\n",
 103                 $$->file->name, $$->lineno);
 104         if (current_menu == $$)
 105                 menu_end_menu();
 106 } if_entry menu_entry choice_entry
 107
 108 %{
 109 /* Include kconf_id.c here so it can see the token constants. */
 110 #include "kconf_id.c"
 111 %}
 112
 113 %%
 114 input: mainmenu_stmt stmt_list | stmt_list;
 115
 116 /* mainmenu entry */
 117
 118 mainmenu_stmt: T_MAINMENU prompt T_EOL
 119 {
 120         menu_add_prompt(P_MENU, $2, NULL);
 121 };
 122
 123 stmt_list:
 124           /* empty */
 125         | stmt_list common_stmt
 126         | stmt_list choice_stmt
 127         | stmt_list menu_stmt
 128         | stmt_list end                 { zconf_error("unexpected end statement"); }
 129         | stmt_list T_WORD error T_EOL  { zconf_error("unknown statement \"%s\"", $2); }
 130         | stmt_list option_name error T_EOL
 131 {
 132         zconf_error("unexpected option \"%s\"", $2->name);
 133 }
 134         | stmt_list error T_EOL         { zconf_error("invalid statement"); }
 135 ;
 136
 137 option_name:
 138         T_DEPENDS | T_PROMPT | T_TYPE | T_SELECT | T_IMPLY | T_OPTIONAL | T_RANGE | T_DEFAULT | T_VISIBLE
 139 ;
 140
 141 common_stmt:
 142           if_stmt
 143         | comment_stmt
 144         | config_stmt
 145         | menuconfig_stmt
 146         | source_stmt
 147         | assignment_stmt
 148 ;
 149
 150 option_error:
 151           T_WORD error T_EOL            { zconf_error("unknown option \"%s\"", $1); }
 152         | error T_EOL                   { zconf_error("invalid option"); }
 153 ;
 154
 155
 156 /* config/menuconfig entry */
 157
 158 config_entry_start: T_CONFIG nonconst_symbol T_EOL
 159 {
 160         $2->flags |= SYMBOL_OPTIONAL;
 161         menu_add_entry($2);
 162         printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2->name);
 163 };
 164
 165 config_stmt: config_entry_start config_option_list
 166 {
 167         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 168 };
 169
 170 menuconfig_entry_start: T_MENUCONFIG nonconst_symbol T_EOL
 171 {
 172         $2->flags |= SYMBOL_OPTIONAL;
 173         menu_add_entry($2);
 174         printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2->name);
 175 };
 176
 177 menuconfig_stmt: menuconfig_entry_start config_option_list
 178 {
 179         if (current_entry->prompt)
 180                 current_entry->prompt->type = P_MENU;
 181         else
 182                 zconfprint("warning: menuconfig statement without prompt");
 183         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 184 };
 185
 186 config_option_list:
 187           /* empty */
 188         | config_option_list config_option
 189         | config_option_list symbol_option
 190         | config_option_list depends
 191         | config_option_list help
 192         | config_option_list option_error
 193 ;
 194
 195 config_option: T_TYPE prompt_stmt_opt T_EOL
 196 {
 197         menu_set_type($1->stype);
 198         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 199                 zconf_curname(), zconf_lineno(),
 200                 $1->stype);
 201 };
 202
 203 config_option: T_PROMPT prompt if_expr T_EOL
 204 {
 205         menu_add_prompt(P_PROMPT, $2, $3);
 206         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 207 };
 208
 209 config_option: T_DEFAULT expr if_expr T_EOL
 210 {
 211         menu_add_expr(P_DEFAULT, $2, $3);
 212         if ($1->stype != S_UNKNOWN)
 213                 menu_set_type($1->stype);
 214         printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
 215                 zconf_curname(), zconf_lineno(),
 216                 $1->stype);
 217 };
 218
 219 config_option: T_SELECT nonconst_symbol if_expr T_EOL
 220 {
 221         menu_add_symbol(P_SELECT, $2, $3);
 222         printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
 223 };
 224
 225 config_option: T_IMPLY nonconst_symbol if_expr T_EOL
 226 {
 227         menu_add_symbol(P_IMPLY, $2, $3);
 228         printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
 229 };
 230
 231 config_option: T_RANGE symbol symbol if_expr T_EOL
 232 {
 233         menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
 234         printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
 235 };
 236
 237 symbol_option: T_OPTION symbol_option_list T_EOL
 238 ;
 239
 240 symbol_option_list:
 241           /* empty */
 242         | symbol_option_list T_WORD symbol_option_arg
 243 {
 244         const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
 245         if (id && id->flags & TF_OPTION) {
 246                 menu_add_option(id->token, $3);
 247                 free($3);
 248         }
 249         else
 250                 zconfprint("warning: ignoring unknown option %s", $2);
 251         free($2);
 252 };
 253
 254 symbol_option_arg:
 255           /* empty */           { $$ = NULL; }
 256         | T_EQUAL prompt        { $$ = $2; }
 257 ;
 258
 259 /* choice entry */
 260
 261 choice: T_CHOICE word_opt T_EOL
 262 {
 263         struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
 264         sym->flags |= SYMBOL_NO_WRITE;
 265         menu_add_entry(sym);
 266         menu_add_expr(P_CHOICE, NULL, NULL);
 267         free($2);
 268         printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
 269 };
 270
 271 choice_entry: choice choice_option_list
 272 {
 273         $$ = menu_add_menu();
 274 };
 275
 276 choice_end: end
 277 {
 278         if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
 279                 menu_end_menu();
 280                 printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
 281         }
 282 };
 283
 284 choice_stmt: choice_entry choice_block choice_end
 285 ;
 286
 287 choice_option_list:
 288           /* empty */
 289         | choice_option_list choice_option
 290         | choice_option_list depends
 291         | choice_option_list help
 292         | choice_option_list option_error
 293 ;
 294
 295 choice_option: T_PROMPT prompt if_expr T_EOL
 296 {
 297         menu_add_prompt(P_PROMPT, $2, $3);
 298         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 299 };
 300
 301 choice_option: T_TYPE prompt_stmt_opt T_EOL
 302 {
 303         if ($1->stype == S_BOOLEAN || $1->stype == S_TRISTATE) {
 304                 menu_set_type($1->stype);
 305                 printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 306                         zconf_curname(), zconf_lineno(),
 307                         $1->stype);
 308         } else
 309                 YYERROR;
 310 };
 311
 312 choice_option: T_OPTIONAL T_EOL
 313 {
 314         current_entry->sym->flags |= SYMBOL_OPTIONAL;
 315         printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
 316 };
 317
 318 choice_option: T_DEFAULT nonconst_symbol if_expr T_EOL
 319 {
 320         if ($1->stype == S_UNKNOWN) {
 321                 menu_add_symbol(P_DEFAULT, $2, $3);
 322                 printd(DEBUG_PARSE, "%s:%d:default\n",
 323                         zconf_curname(), zconf_lineno());
 324         } else
 325                 YYERROR;
 326 };
 327
 328 choice_block:
 329           /* empty */
 330         | choice_block common_stmt
 331 ;
 332
 333 /* if entry */
 334
 335 if_entry: T_IF expr T_EOL
 336 {
 337         printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
 338         menu_add_entry(NULL);
 339         menu_add_dep($2);
 340         $$ = menu_add_menu();
 341 };
 342
 343 if_end: end
 344 {
 345         if (zconf_endtoken($1, T_IF, T_ENDIF)) {
 346                 menu_end_menu();
 347                 printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
 348         }
 349 };
 350
 351 if_stmt: if_entry if_block if_end
 352 ;
 353
 354 if_block:
 355           /* empty */
 356         | if_block common_stmt
 357         | if_block menu_stmt
 358         | if_block choice_stmt
 359 ;
 360
 361 /* menu entry */
 362
 363 menu: T_MENU prompt T_EOL
 364 {
 365         menu_add_entry(NULL);
 366         menu_add_prompt(P_MENU, $2, NULL);
 367         printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
 368 };
 369
 370 menu_entry: menu visibility_list depends_list
 371 {
 372         $$ = menu_add_menu();
 373 };
 374
 375 menu_end: end
 376 {
 377         if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
 378                 menu_end_menu();
 379                 printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
 380         }
 381 };
 382
 383 menu_stmt: menu_entry menu_block menu_end
 384 ;
 385
 386 menu_block:
 387           /* empty */
 388         | menu_block common_stmt
 389         | menu_block menu_stmt
 390         | menu_block choice_stmt
 391 ;
 392
 393 source_stmt: T_SOURCE prompt T_EOL
 394 {
 395         printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
 396         zconf_nextfile($2);
 397         free($2);
 398 };
 399
 400 /* comment entry */
 401
 402 comment: T_COMMENT prompt T_EOL
 403 {
 404         menu_add_entry(NULL);
 405         menu_add_prompt(P_COMMENT, $2, NULL);
 406         printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
 407 };
 408
 409 comment_stmt: comment depends_list
 410 ;
 411
 412 /* help option */
 413
 414 help_start: T_HELP T_EOL
 415 {
 416         printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
 417         zconf_starthelp();
 418 };
 419
 420 help: help_start T_HELPTEXT
 421 {
 422         if (current_entry->help) {
 423                 free(current_entry->help);
 424                 zconfprint("warning: '%s' defined with more than one help text -- only the last one will be used",
 425                            current_entry->sym->name ?: "<choice>");
 426         }
 427
 428         /* Is the help text empty or all whitespace? */
 429         if ($2[strspn($2, " \f\n\r\t\v")] == '\0')
 430                 zconfprint("warning: '%s' defined with blank help text",
 431                            current_entry->sym->name ?: "<choice>");
 432
 433         current_entry->help = $2;
 434 };
 435
 436 /* depends option */
 437
 438 depends_list:
 439           /* empty */
 440         | depends_list depends
 441         | depends_list option_error
 442 ;
 443
 444 depends: T_DEPENDS T_ON expr T_EOL
 445 {
 446         menu_add_dep($3);
 447         printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
 448 };
 449
 450 /* visibility option */
 451
 452 visibility_list:
 453           /* empty */
 454         | visibility_list visible
 455 ;
 456
 457 visible: T_VISIBLE if_expr T_EOL
 458 {
 459         menu_add_visibility($2);
 460 };
 461
 462 /* prompt statement */
 463
 464 prompt_stmt_opt:
 465           /* empty */
 466         | prompt if_expr
 467 {
 468         menu_add_prompt(P_PROMPT, $1, $2);
 469 };
 470
 471 prompt:   T_WORD
 472         | T_WORD_QUOTE
 473 ;
 474
 475 end:      T_ENDMENU T_EOL       { $$ = $1; }
 476         | T_ENDCHOICE T_EOL     { $$ = $1; }
 477         | T_ENDIF T_EOL         { $$ = $1; }
 478 ;
 479
 480 if_expr:  /* empty */                   { $$ = NULL; }
 481         | T_IF expr                     { $$ = $2; }
 482 ;
 483
 484 expr:     symbol                                { $$ = expr_alloc_symbol($1); }
 485         | symbol T_LESS symbol                  { $$ = expr_alloc_comp(E_LTH, $1, $3); }
 486         | symbol T_LESS_EQUAL symbol            { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
 487         | symbol T_GREATER symbol               { $$ = expr_alloc_comp(E_GTH, $1, $3); }
 488         | symbol T_GREATER_EQUAL symbol         { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
 489         | symbol T_EQUAL symbol                 { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
 490         | symbol T_UNEQUAL symbol               { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
 491         | T_OPEN_PAREN expr T_CLOSE_PAREN       { $$ = $2; }
 492         | T_NOT expr                            { $$ = expr_alloc_one(E_NOT, $2); }
 493         | expr T_OR expr                        { $$ = expr_alloc_two(E_OR, $1, $3); }
 494         | expr T_AND expr                       { $$ = expr_alloc_two(E_AND, $1, $3); }
 495 ;
 496
 497 /* For symbol definitions, selects, etc., where quotes are not accepted */
 498 nonconst_symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); };
 499
 500 symbol:   nonconst_symbol
 501         | T_WORD_QUOTE  { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
 502 ;
 503
 504 word_opt: /* empty */                   { $$ = NULL; }
 505         | T_WORD
 506
 507 /* assignment statement */
 508
 509 assignment_stmt:  T_VARIABLE T_ASSIGN assign_val T_EOL  { variable_add($1, $3, $2); free($1); free($3); }
 510
 511 assign_val:
 512         /* empty */             { $$ = xstrdup(""); };
 513         | T_ASSIGN_VAL
 514 ;
 515
 516 %%
 517
 518 void conf_parse(const char *name)
 519 {
 520         struct symbol *sym;
 521         int i;
 522
 523         zconf_initscan(name);
 524
 525         _menu_init();
 526         rootmenu.prompt = menu_add_prompt(P_MENU, "CARL9170 Firmware Configuration", NULL);
 527
 528         if (getenv("ZCONF_DEBUG"))
 529                 yydebug = 1;
 530         yyparse();
 531
 532         /* Variables are expanded in the parse phase. We can free them here. */
 533         variable_all_del();
 534
 535         if (yynerrs)
 536                 exit(1);
 537         if (!modules_sym)
 538                 modules_sym = sym_find( "n" );
 539
 540         if (!menu_has_prompt(&rootmenu)) {
 541                 current_entry = &rootmenu;
 542                 menu_add_prompt(P_MENU, "Main menu", NULL);
 543         }
 544
 545         menu_finalize(&rootmenu);
 546         for_all_symbols(i, sym) {
 547                 if (sym_check_deps(sym))
 548                         yynerrs++;
 549         }
 550         if (yynerrs)
 551                 exit(1);
 552         sym_set_change_count(1);
 553 }
 554
 555 static const char *zconf_tokenname(int token)
 556 {
 557         switch (token) {
 558         case T_MENU:            return "menu";
 559         case T_ENDMENU:         return "endmenu";
 560         case T_CHOICE:          return "choice";
 561         case T_ENDCHOICE:       return "endchoice";
 562         case T_IF:              return "if";
 563         case T_ENDIF:           return "endif";
 564         case T_DEPENDS:         return "depends";
 565         case T_VISIBLE:         return "visible";
 566         }
 567         return "<token>";
 568 }
 569
 570 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
 571 {
 572         if (id->token != endtoken) {
 573                 zconf_error("unexpected '%s' within %s block",
 574                         id->name, zconf_tokenname(starttoken));
 575                 yynerrs++;
 576                 return false;
 577         }
 578         if (current_menu->file != current_file) {
 579                 zconf_error("'%s' in different file than '%s'",
 580                         id->name, zconf_tokenname(starttoken));
 581                 fprintf(stderr, "%s:%d: location of the '%s'\n",
 582                         current_menu->file->name, current_menu->lineno,
 583                         zconf_tokenname(starttoken));
 584                 yynerrs++;
 585                 return false;
 586         }
 587         return true;
 588 }
 589
 590 static void zconfprint(const char *err, ...)
 591 {
 592         va_list ap;
 593
 594         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 595         va_start(ap, err);
 596         vfprintf(stderr, err, ap);
 597         va_end(ap);
 598         fprintf(stderr, "\n");
 599 }
 600
 601 static void zconf_error(const char *err, ...)
 602 {
 603         va_list ap;
 604
 605         yynerrs++;
 606         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 607         va_start(ap, err);
 608         vfprintf(stderr, err, ap);
 609         va_end(ap);
 610         fprintf(stderr, "\n");
 611 }
 612
 613 static void yyerror(const char *err)
 614 {
 615         fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
 616 }
 617
 618 static void print_quoted_string(FILE *out, const char *str)
 619 {
 620         const char *p;
 621         int len;
 622
 623         putc('"', out);
 624         while ((p = strchr(str, '"'))) {
 625                 len = p - str;
 626                 if (len)
 627                         fprintf(out, "%.*s", len, str);
 628                 fputs("\\\"", out);
 629                 str = p + 1;
 630         }
 631         fputs(str, out);
 632         putc('"', out);
 633 }
 634
 635 static void print_symbol(FILE *out, struct menu *menu)
 636 {
 637         struct symbol *sym = menu->sym;
 638         struct property *prop;
 639
 640         if (sym_is_choice(sym))
 641                 fprintf(out, "\nchoice\n");
 642         else
 643                 fprintf(out, "\nconfig %s\n", sym->name);
 644         switch (sym->type) {
 645         case S_BOOLEAN:
 646                 fputs("  bool\n", out);
 647                 break;
 648         case S_TRISTATE:
 649                 fputs("  tristate\n", out);
 650                 break;
 651         case S_STRING:
 652                 fputs("  string\n", out);
 653                 break;
 654         case S_INT:
 655                 fputs("  integer\n", out);
 656                 break;
 657         case S_HEX:
 658                 fputs("  hex\n", out);
 659                 break;
 660         default:
 661                 fputs("  ???\n", out);
 662                 break;
 663         }
 664         for (prop = sym->prop; prop; prop = prop->next) {
 665                 if (prop->menu != menu)
 666                         continue;
 667                 switch (prop->type) {
 668                 case P_PROMPT:
 669                         fputs("  prompt ", out);
 670                         print_quoted_string(out, prop->text);
 671                         if (!expr_is_yes(prop->visible.expr)) {
 672                                 fputs(" if ", out);
 673                                 expr_fprint(prop->visible.expr, out);
 674                         }
 675                         fputc('\n', out);
 676                         break;
 677                 case P_DEFAULT:
 678                         fputs( "  default ", out);
 679                         expr_fprint(prop->expr, out);
 680                         if (!expr_is_yes(prop->visible.expr)) {
 681                                 fputs(" if ", out);
 682                                 expr_fprint(prop->visible.expr, out);
 683                         }
 684                         fputc('\n', out);
 685                         break;
 686                 case P_CHOICE:
 687                         fputs("  #choice value\n", out);
 688                         break;
 689                 case P_SELECT:
 690                         fputs( "  select ", out);
 691                         expr_fprint(prop->expr, out);
 692                         fputc('\n', out);
 693                         break;
 694                 case P_IMPLY:
 695                         fputs( "  imply ", out);
 696                         expr_fprint(prop->expr, out);
 697                         fputc('\n', out);
 698                         break;
 699                 case P_RANGE:
 700                         fputs( "  range ", out);
 701                         expr_fprint(prop->expr, out);
 702                         fputc('\n', out);
 703                         break;
 704                 case P_MENU:
 705                         fputs( "  menu ", out);
 706                         print_quoted_string(out, prop->text);
 707                         fputc('\n', out);
 708                         break;
 709                 case P_SYMBOL:
 710                         fputs( "  symbol ", out);
 711                         fprintf(out, "%s\n", prop->sym->name);
 712                         break;
 713                 default:
 714                         fprintf(out, "  unknown prop %d!\n", prop->type);
 715                         break;
 716                 }
 717         }
 718         if (menu->help) {
 719                 int len = strlen(menu->help);
 720                 while (menu->help[--len] == '\n')
 721                         menu->help[len] = 0;
 722                 fprintf(out, "  help\n%s\n", menu->help);
 723         }
 724 }
 725
 726 void zconfdump(FILE *out)
 727 {
 728         struct property *prop;
 729         struct symbol *sym;
 730         struct menu *menu;
 731
 732         menu = rootmenu.list;
 733         while (menu) {
 734                 if ((sym = menu->sym))
 735                         print_symbol(out, menu);
 736                 else if ((prop = menu->prompt)) {
 737                         switch (prop->type) {
 738                         case P_COMMENT:
 739                                 fputs("\ncomment ", out);
 740                                 print_quoted_string(out, prop->text);
 741                                 fputs("\n", out);
 742                                 break;
 743                         case P_MENU:
 744                                 fputs("\nmenu ", out);
 745                                 print_quoted_string(out, prop->text);
 746                                 fputs("\n", out);
 747                                 break;
 748                         default:
 749                                 ;
 750                         }
 751                         if (!expr_is_yes(prop->visible.expr)) {
 752                                 fputs("  depends ", out);
 753                                 expr_fprint(prop->visible.expr, out);
 754                                 fputc('\n', out);
 755                         }
 756                 }
 757
 758                 if (menu->list)
 759                         menu = menu->list;
 760                 else if (menu->next)
 761                         menu = menu->next;
 762                 else while ((menu = menu->parent)) {
 763                         if (menu->prompt && menu->prompt->type == P_MENU)
 764                                 fputs("\nendmenu\n", out);
 765                         if (menu->next) {
 766                                 menu = menu->next;
 767                                 break;
 768                         }
 769                 }
 770         }
 771 }
 772
 773 #include "zconf.lex.c"
 774 #include "util.c"
 775 #include "confdata.c"
 776 #include "expr.c"
 777 #include "symbol.c"
 778 #include "menu.c"
 779 #include "preprocess.c"