config/zconf.y

   1 %{
   2 /*
   3  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   4  * Released under the terms of the GNU GPL v2.0.
   5  */
   6
   7 #include <ctype.h>
   8 #include <stdarg.h>
   9 #include <stdio.h>
  10 #include <stdlib.h>
  11 #include <string.h>
  12 #include <stdbool.h>
  13
  14 #include "lkc.h"
  15
  16 #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  17
  18 #define PRINTD          0x0001
  19 #define DEBUG_PARSE     0x0002
  20
  21 int cdebug = PRINTD;
  22
  23 extern int zconflex(void);
  24 static void zconfprint(const char *err, ...);
  25 static void zconf_error(const char *err, ...);
  26 static void zconferror(const char *err);
  27 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);
  28
  29 struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  30
  31 static struct menu *current_menu, *current_entry;
  32
  33 %}
  34 %expect 32
  35
  36 %union
  37 {
  38         char *string;
  39         struct file *file;
  40         struct symbol *symbol;
  41         struct expr *expr;
  42         struct menu *menu;
  43         const struct kconf_id *id;
  44 }
  45
  46 %token <id>T_MAINMENU
  47 %token <id>T_MENU
  48 %token <id>T_ENDMENU
  49 %token <id>T_SOURCE
  50 %token <id>T_CHOICE
  51 %token <id>T_ENDCHOICE
  52 %token <id>T_COMMENT
  53 %token <id>T_CONFIG
  54 %token <id>T_MENUCONFIG
  55 %token <id>T_HELP
  56 %token <string> T_HELPTEXT
  57 %token <id>T_IF
  58 %token <id>T_ENDIF
  59 %token <id>T_DEPENDS
  60 %token <id>T_OPTIONAL
  61 %token <id>T_PROMPT
  62 %token <id>T_TYPE
  63 %token <id>T_DEFAULT
  64 %token <id>T_SELECT
  65 %token <id>T_IMPLY
  66 %token <id>T_RANGE
  67 %token <id>T_VISIBLE
  68 %token <id>T_OPTION
  69 %token <id>T_ON
  70 %token <string> T_WORD
  71 %token <string> T_WORD_QUOTE
  72 %token T_UNEQUAL
  73 %token T_LESS
  74 %token T_LESS_EQUAL
  75 %token T_GREATER
  76 %token T_GREATER_EQUAL
  77 %token T_CLOSE_PAREN
  78 %token T_OPEN_PAREN
  79 %token T_EOL
  80
  81 %left T_OR
  82 %left T_AND
  83 %left T_EQUAL T_UNEQUAL
  84 %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  85 %nonassoc T_NOT
  86
  87 %type <string> prompt
  88 %type <symbol> nonconst_symbol
  89 %type <symbol> symbol
  90 %type <expr> expr
  91 %type <expr> if_expr
  92 %type <id> end
  93 %type <id> option_name
  94 %type <menu> if_entry menu_entry choice_entry
  95 %type <string> symbol_option_arg word_opt
  96
  97 %destructor {
  98         fprintf(stderr, "%s:%d: missing end statement for this entry\n",
  99                 $$->file->name, $$->lineno);
 100         if (current_menu == $$)
 101                 menu_end_menu();
 102 } if_entry menu_entry choice_entry
 103
 104 %{
 105 /* Include kconf_id.c here so it can see the token constants. */
 106 #include "kconf_id.c"
 107 %}
 108
 109 %%
 110 input: nl start | start;
 111
 112 start: mainmenu_stmt stmt_list | stmt_list;
 113
 114 stmt_list:
 115           /* empty */
 116         | stmt_list common_stmt
 117         | stmt_list choice_stmt
 118         | stmt_list menu_stmt
 119         | stmt_list end                 { zconf_error("unexpected end statement"); }
 120         | stmt_list T_WORD error T_EOL  { zconf_error("unknown statement \"%s\"", $2); }
 121         | stmt_list option_name error T_EOL
 122 {
 123         zconf_error("unexpected option \"%s\"", $2->name);
 124 }
 125         | stmt_list error T_EOL         { zconf_error("invalid statement"); }
 126 ;
 127
 128 option_name:
 129         T_DEPENDS | T_PROMPT | T_TYPE | T_SELECT | T_IMPLY | T_OPTIONAL | T_RANGE | T_DEFAULT | T_VISIBLE
 130 ;
 131
 132 common_stmt:
 133           T_EOL
 134         | if_stmt
 135         | comment_stmt
 136         | config_stmt
 137         | menuconfig_stmt
 138         | source_stmt
 139 ;
 140
 141 option_error:
 142           T_WORD error T_EOL            { zconf_error("unknown option \"%s\"", $1); }
 143         | error T_EOL                   { zconf_error("invalid option"); }
 144 ;
 145
 146
 147 /* config/menuconfig entry */
 148
 149 config_entry_start: T_CONFIG nonconst_symbol T_EOL
 150 {
 151         $2->flags |= SYMBOL_OPTIONAL;
 152         menu_add_entry($2);
 153         printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2->name);
 154 };
 155
 156 config_stmt: config_entry_start config_option_list
 157 {
 158         menu_end_entry();
 159         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 160 };
 161
 162 menuconfig_entry_start: T_MENUCONFIG nonconst_symbol T_EOL
 163 {
 164         $2->flags |= SYMBOL_OPTIONAL;
 165         menu_add_entry($2);
 166         printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2->name);
 167 };
 168
 169 menuconfig_stmt: menuconfig_entry_start config_option_list
 170 {
 171         if (current_entry->prompt)
 172                 current_entry->prompt->type = P_MENU;
 173         else
 174                 zconfprint("warning: menuconfig statement without prompt");
 175         menu_end_entry();
 176         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 177 };
 178
 179 config_option_list:
 180           /* empty */
 181         | config_option_list config_option
 182         | config_option_list symbol_option
 183         | config_option_list depends
 184         | config_option_list help
 185         | config_option_list option_error
 186         | config_option_list T_EOL
 187 ;
 188
 189 config_option: T_TYPE prompt_stmt_opt T_EOL
 190 {
 191         menu_set_type($1->stype);
 192         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 193                 zconf_curname(), zconf_lineno(),
 194                 $1->stype);
 195 };
 196
 197 config_option: T_PROMPT prompt if_expr T_EOL
 198 {
 199         menu_add_prompt(P_PROMPT, $2, $3);
 200         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 201 };
 202
 203 config_option: T_DEFAULT expr if_expr T_EOL
 204 {
 205         menu_add_expr(P_DEFAULT, $2, $3);
 206         if ($1->stype != S_UNKNOWN)
 207                 menu_set_type($1->stype);
 208         printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
 209                 zconf_curname(), zconf_lineno(),
 210                 $1->stype);
 211 };
 212
 213 config_option: T_SELECT nonconst_symbol if_expr T_EOL
 214 {
 215         menu_add_symbol(P_SELECT, $2, $3);
 216         printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
 217 };
 218
 219 config_option: T_IMPLY nonconst_symbol if_expr T_EOL
 220 {
 221         menu_add_symbol(P_IMPLY, $2, $3);
 222         printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
 223 };
 224
 225 config_option: T_RANGE symbol symbol if_expr T_EOL
 226 {
 227         menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
 228         printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
 229 };
 230
 231 symbol_option: T_OPTION symbol_option_list T_EOL
 232 ;
 233
 234 symbol_option_list:
 235           /* empty */
 236         | symbol_option_list T_WORD symbol_option_arg
 237 {
 238         const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
 239         if (id && id->flags & TF_OPTION)
 240                 menu_add_option(id->token, $3);
 241         else
 242                 zconfprint("warning: ignoring unknown option %s", $2);
 243         free($2);
 244 };
 245
 246 symbol_option_arg:
 247           /* empty */           { $$ = NULL; }
 248         | T_EQUAL prompt        { $$ = $2; }
 249 ;
 250
 251 /* choice entry */
 252
 253 choice: T_CHOICE word_opt T_EOL
 254 {
 255         struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
 256         sym->flags |= SYMBOL_AUTO;
 257         menu_add_entry(sym);
 258         menu_add_expr(P_CHOICE, NULL, NULL);
 259         printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
 260 };
 261
 262 choice_entry: choice choice_option_list
 263 {
 264         $$ = menu_add_menu();
 265 };
 266
 267 choice_end: end
 268 {
 269         if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
 270                 menu_end_menu();
 271                 printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
 272         }
 273 };
 274
 275 choice_stmt: choice_entry choice_block choice_end
 276 ;
 277
 278 choice_option_list:
 279           /* empty */
 280         | choice_option_list choice_option
 281         | choice_option_list depends
 282         | choice_option_list help
 283         | choice_option_list T_EOL
 284         | choice_option_list option_error
 285 ;
 286
 287 choice_option: T_PROMPT prompt if_expr T_EOL
 288 {
 289         menu_add_prompt(P_PROMPT, $2, $3);
 290         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 291 };
 292
 293 choice_option: T_TYPE prompt_stmt_opt T_EOL
 294 {
 295         if ($1->stype == S_BOOLEAN || $1->stype == S_TRISTATE) {
 296                 menu_set_type($1->stype);
 297                 printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 298                         zconf_curname(), zconf_lineno(),
 299                         $1->stype);
 300         } else
 301                 YYERROR;
 302 };
 303
 304 choice_option: T_OPTIONAL T_EOL
 305 {
 306         current_entry->sym->flags |= SYMBOL_OPTIONAL;
 307         printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
 308 };
 309
 310 choice_option: T_DEFAULT nonconst_symbol if_expr T_EOL
 311 {
 312         if ($1->stype == S_UNKNOWN) {
 313                 menu_add_symbol(P_DEFAULT, $2, $3);
 314                 printd(DEBUG_PARSE, "%s:%d:default\n",
 315                         zconf_curname(), zconf_lineno());
 316         } else
 317                 YYERROR;
 318 };
 319
 320 choice_block:
 321           /* empty */
 322         | choice_block common_stmt
 323 ;
 324
 325 /* if entry */
 326
 327 if_entry: T_IF expr nl
 328 {
 329         printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
 330         menu_add_entry(NULL);
 331         menu_add_dep($2);
 332         $$ = menu_add_menu();
 333 };
 334
 335 if_end: end
 336 {
 337         if (zconf_endtoken($1, T_IF, T_ENDIF)) {
 338                 menu_end_menu();
 339                 printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
 340         }
 341 };
 342
 343 if_stmt: if_entry if_block if_end
 344 ;
 345
 346 if_block:
 347           /* empty */
 348         | if_block common_stmt
 349         | if_block menu_stmt
 350         | if_block choice_stmt
 351 ;
 352
 353 /* mainmenu entry */
 354
 355 mainmenu_stmt: T_MAINMENU prompt nl
 356 {
 357         menu_add_prompt(P_MENU, $2, NULL);
 358 };
 359
 360 /* menu entry */
 361
 362 menu: T_MENU prompt T_EOL
 363 {
 364         menu_add_entry(NULL);
 365         menu_add_prompt(P_MENU, $2, NULL);
 366         printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
 367 };
 368
 369 menu_entry: menu visibility_list depends_list
 370 {
 371         $$ = menu_add_menu();
 372 };
 373
 374 menu_end: end
 375 {
 376         if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
 377                 menu_end_menu();
 378                 printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
 379         }
 380 };
 381
 382 menu_stmt: menu_entry menu_block menu_end
 383 ;
 384
 385 menu_block:
 386           /* empty */
 387         | menu_block common_stmt
 388         | menu_block menu_stmt
 389         | menu_block choice_stmt
 390 ;
 391
 392 source_stmt: T_SOURCE prompt T_EOL
 393 {
 394         printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
 395         zconf_nextfile($2);
 396         free($2);
 397 };
 398
 399 /* comment entry */
 400
 401 comment: T_COMMENT prompt T_EOL
 402 {
 403         menu_add_entry(NULL);
 404         menu_add_prompt(P_COMMENT, $2, NULL);
 405         printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
 406 };
 407
 408 comment_stmt: comment depends_list
 409 {
 410         menu_end_entry();
 411 };
 412
 413 /* help option */
 414
 415 help_start: T_HELP T_EOL
 416 {
 417         printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
 418         zconf_starthelp();
 419 };
 420
 421 help: help_start T_HELPTEXT
 422 {
 423         current_entry->help = $2;
 424 };
 425
 426 /* depends option */
 427
 428 depends_list:
 429           /* empty */
 430         | depends_list depends
 431         | depends_list T_EOL
 432         | depends_list option_error
 433 ;
 434
 435 depends: T_DEPENDS T_ON expr T_EOL
 436 {
 437         menu_add_dep($3);
 438         printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
 439 };
 440
 441 /* visibility option */
 442
 443 visibility_list:
 444           /* empty */
 445         | visibility_list visible
 446         | visibility_list T_EOL
 447 ;
 448
 449 visible: T_VISIBLE if_expr
 450 {
 451         menu_add_visibility($2);
 452 };
 453
 454 /* prompt statement */
 455
 456 prompt_stmt_opt:
 457           /* empty */
 458         | prompt if_expr
 459 {
 460         menu_add_prompt(P_PROMPT, $1, $2);
 461 };
 462
 463 prompt:   T_WORD
 464         | T_WORD_QUOTE
 465 ;
 466
 467 end:      T_ENDMENU T_EOL       { $$ = $1; }
 468         | T_ENDCHOICE T_EOL     { $$ = $1; }
 469         | T_ENDIF T_EOL         { $$ = $1; }
 470 ;
 471
 472 nl:
 473           T_EOL
 474         | nl T_EOL
 475 ;
 476
 477 if_expr:  /* empty */                   { $$ = NULL; }
 478         | T_IF expr                     { $$ = $2; }
 479 ;
 480
 481 expr:     symbol                                { $$ = expr_alloc_symbol($1); }
 482         | symbol T_LESS symbol                  { $$ = expr_alloc_comp(E_LTH, $1, $3); }
 483         | symbol T_LESS_EQUAL symbol            { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
 484         | symbol T_GREATER symbol               { $$ = expr_alloc_comp(E_GTH, $1, $3); }
 485         | symbol T_GREATER_EQUAL symbol         { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
 486         | symbol T_EQUAL symbol                 { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
 487         | symbol T_UNEQUAL symbol               { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
 488         | T_OPEN_PAREN expr T_CLOSE_PAREN       { $$ = $2; }
 489         | T_NOT expr                            { $$ = expr_alloc_one(E_NOT, $2); }
 490         | expr T_OR expr                        { $$ = expr_alloc_two(E_OR, $1, $3); }
 491         | expr T_AND expr                       { $$ = expr_alloc_two(E_AND, $1, $3); }
 492 ;
 493
 494 /* For symbol definitions, selects, etc., where quotes are not accepted */
 495 nonconst_symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); };
 496
 497 symbol:   nonconst_symbol
 498         | T_WORD_QUOTE  { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
 499 ;
 500
 501 word_opt: /* empty */                   { $$ = NULL; }
 502         | T_WORD
 503
 504 %%
 505
 506 void conf_parse(const char *name)
 507 {
 508         struct symbol *sym;
 509         int i;
 510
 511         zconf_initscan(name);
 512
 513         sym_init();
 514         _menu_init();
 515         rootmenu.prompt = menu_add_prompt(P_MENU, "CARL9170 Firmware Configuration", NULL);
 516
 517         if (getenv("ZCONF_DEBUG"))
 518                 zconfdebug = 1;
 519         zconfparse();
 520         if (zconfnerrs)
 521                 exit(1);
 522         if (!modules_sym)
 523                 modules_sym = sym_find( "n" );
 524
 525         rootmenu.prompt->text = _(rootmenu.prompt->text);
 526         rootmenu.prompt->text = sym_expand_string_value(rootmenu.prompt->text);
 527
 528         menu_finalize(&rootmenu);
 529         for_all_symbols(i, sym) {
 530                 if (sym_check_deps(sym))
 531                         zconfnerrs++;
 532         }
 533         if (zconfnerrs)
 534                 exit(1);
 535         sym_set_change_count(1);
 536 }
 537
 538 static const char *zconf_tokenname(int token)
 539 {
 540         switch (token) {
 541         case T_MENU:            return "menu";
 542         case T_ENDMENU:         return "endmenu";
 543         case T_CHOICE:          return "choice";
 544         case T_ENDCHOICE:       return "endchoice";
 545         case T_IF:              return "if";
 546         case T_ENDIF:           return "endif";
 547         case T_DEPENDS:         return "depends";
 548         case T_VISIBLE:         return "visible";
 549         }
 550         return "<token>";
 551 }
 552
 553 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
 554 {
 555         if (id->token != endtoken) {
 556                 zconf_error("unexpected '%s' within %s block",
 557                         id->name, zconf_tokenname(starttoken));
 558                 zconfnerrs++;
 559                 return false;
 560         }
 561         if (current_menu->file != current_file) {
 562                 zconf_error("'%s' in different file than '%s'",
 563                         id->name, zconf_tokenname(starttoken));
 564                 fprintf(stderr, "%s:%d: location of the '%s'\n",
 565                         current_menu->file->name, current_menu->lineno,
 566                         zconf_tokenname(starttoken));
 567                 zconfnerrs++;
 568                 return false;
 569         }
 570         return true;
 571 }
 572
 573 static void zconfprint(const char *err, ...)
 574 {
 575         va_list ap;
 576
 577         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 578         va_start(ap, err);
 579         vfprintf(stderr, err, ap);
 580         va_end(ap);
 581         fprintf(stderr, "\n");
 582 }
 583
 584 static void zconf_error(const char *err, ...)
 585 {
 586         va_list ap;
 587
 588         zconfnerrs++;
 589         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 590         va_start(ap, err);
 591         vfprintf(stderr, err, ap);
 592         va_end(ap);
 593         fprintf(stderr, "\n");
 594 }
 595
 596 static void zconferror(const char *err)
 597 {
 598         fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
 599 }
 600
 601 static void print_quoted_string(FILE *out, const char *str)
 602 {
 603         const char *p;
 604         int len;
 605
 606         putc('"', out);
 607         while ((p = strchr(str, '"'))) {
 608                 len = p - str;
 609                 if (len)
 610                         fprintf(out, "%.*s", len, str);
 611                 fputs("\\\"", out);
 612                 str = p + 1;
 613         }
 614         fputs(str, out);
 615         putc('"', out);
 616 }
 617
 618 static void print_symbol(FILE *out, struct menu *menu)
 619 {
 620         struct symbol *sym = menu->sym;
 621         struct property *prop;
 622
 623         if (sym_is_choice(sym))
 624                 fprintf(out, "\nchoice\n");
 625         else
 626                 fprintf(out, "\nconfig %s\n", sym->name);
 627         switch (sym->type) {
 628         case S_BOOLEAN:
 629                 fputs("  boolean\n", out);
 630                 break;
 631         case S_TRISTATE:
 632                 fputs("  tristate\n", out);
 633                 break;
 634         case S_STRING:
 635                 fputs("  string\n", out);
 636                 break;
 637         case S_INT:
 638                 fputs("  integer\n", out);
 639                 break;
 640         case S_HEX:
 641                 fputs("  hex\n", out);
 642                 break;
 643         default:
 644                 fputs("  ???\n", out);
 645                 break;
 646         }
 647         for (prop = sym->prop; prop; prop = prop->next) {
 648                 if (prop->menu != menu)
 649                         continue;
 650                 switch (prop->type) {
 651                 case P_PROMPT:
 652                         fputs("  prompt ", out);
 653                         print_quoted_string(out, prop->text);
 654                         if (!expr_is_yes(prop->visible.expr)) {
 655                                 fputs(" if ", out);
 656                                 expr_fprint(prop->visible.expr, out);
 657                         }
 658                         fputc('\n', out);
 659                         break;
 660                 case P_DEFAULT:
 661                         fputs( "  default ", out);
 662                         expr_fprint(prop->expr, out);
 663                         if (!expr_is_yes(prop->visible.expr)) {
 664                                 fputs(" if ", out);
 665                                 expr_fprint(prop->visible.expr, out);
 666                         }
 667                         fputc('\n', out);
 668                         break;
 669                 case P_CHOICE:
 670                         fputs("  #choice value\n", out);
 671                         break;
 672                 case P_SELECT:
 673                         fputs( "  select ", out);
 674                         expr_fprint(prop->expr, out);
 675                         fputc('\n', out);
 676                         break;
 677                 case P_IMPLY:
 678                         fputs( "  imply ", out);
 679                         expr_fprint(prop->expr, out);
 680                         fputc('\n', out);
 681                         break;
 682                 case P_RANGE:
 683                         fputs( "  range ", out);
 684                         expr_fprint(prop->expr, out);
 685                         fputc('\n', out);
 686                         break;
 687                 case P_MENU:
 688                         fputs( "  menu ", out);
 689                         print_quoted_string(out, prop->text);
 690                         fputc('\n', out);
 691                         break;
 692                 default:
 693                         fprintf(out, "  unknown prop %d!\n", prop->type);
 694                         break;
 695                 }
 696         }
 697         if (menu->help) {
 698                 int len = strlen(menu->help);
 699                 while (menu->help[--len] == '\n')
 700                         menu->help[len] = 0;
 701                 fprintf(out, "  help\n%s\n", menu->help);
 702         }
 703 }
 704
 705 void zconfdump(FILE *out)
 706 {
 707         struct property *prop;
 708         struct symbol *sym;
 709         struct menu *menu;
 710
 711         menu = rootmenu.list;
 712         while (menu) {
 713                 if ((sym = menu->sym))
 714                         print_symbol(out, menu);
 715                 else if ((prop = menu->prompt)) {
 716                         switch (prop->type) {
 717                         case P_COMMENT:
 718                                 fputs("\ncomment ", out);
 719                                 print_quoted_string(out, prop->text);
 720                                 fputs("\n", out);
 721                                 break;
 722                         case P_MENU:
 723                                 fputs("\nmenu ", out);
 724                                 print_quoted_string(out, prop->text);
 725                                 fputs("\n", out);
 726                                 break;
 727                         default:
 728                                 ;
 729                         }
 730                         if (!expr_is_yes(prop->visible.expr)) {
 731                                 fputs("  depends ", out);
 732                                 expr_fprint(prop->visible.expr, out);
 733                                 fputc('\n', out);
 734                         }
 735                 }
 736
 737                 if (menu->list)
 738                         menu = menu->list;
 739                 else if (menu->next)
 740                         menu = menu->next;
 741                 else while ((menu = menu->parent)) {
 742                         if (menu->prompt && menu->prompt->type == P_MENU)
 743                                 fputs("\nendmenu\n", out);
 744                         if (menu->next) {
 745                                 menu = menu->next;
 746                                 break;
 747                         }
 748                 }
 749         }
 750 }
 751
 752 #include "zconf.lex.c"
 753 #include "util.c"
 754 #include "confdata.c"
 755 #include "expr.c"
 756 #include "symbol.c"
 757 #include "menu.c"