config/zconf.y

   1 %{
   2 /*
   3  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   4  * Released under the terms of the GNU GPL v2.0.
   5  */
   6
   7 #include <ctype.h>
   8 #include <stdarg.h>
   9 #include <stdio.h>
  10 #include <stdlib.h>
  11 #include <string.h>
  12 #include <stdbool.h>
  13
  14 #include "lkc.h"
  15
  16 #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  17
  18 #define PRINTD          0x0001
  19 #define DEBUG_PARSE     0x0002
  20
  21 int cdebug = PRINTD;
  22
  23 int yylex(void);
  24 static void yyerror(const char *err);
  25 static void zconfprint(const char *err, ...);
  26 static void zconf_error(const char *err, ...);
  27 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);
  28
  29 struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  30
  31 static struct menu *current_menu, *current_entry;
  32
  33 %}
  34
  35 %union
  36 {
  37         char *string;
  38         struct file *file;
  39         struct symbol *symbol;
  40         struct expr *expr;
  41         struct menu *menu;
  42         const struct kconf_id *id;
  43         enum variable_flavor flavor;
  44 }
  45
  46 %token <id>T_MAINMENU
  47 %token <id>T_MENU
  48 %token <id>T_ENDMENU
  49 %token <id>T_SOURCE
  50 %token <id>T_CHOICE
  51 %token <id>T_ENDCHOICE
  52 %token <id>T_COMMENT
  53 %token <id>T_CONFIG
  54 %token <id>T_MENUCONFIG
  55 %token <id>T_HELP
  56 %token <string> T_HELPTEXT
  57 %token <id>T_IF
  58 %token <id>T_ENDIF
  59 %token <id>T_DEPENDS
  60 %token <id>T_OPTIONAL
  61 %token <id>T_PROMPT
  62 %token <id>T_TYPE
  63 %token <id>T_DEFAULT
  64 %token <id>T_SELECT
  65 %token <id>T_IMPLY
  66 %token <id>T_RANGE
  67 %token <id>T_VISIBLE
  68 %token <id>T_OPTION
  69 %token <id>T_ON
  70 %token <string> T_WORD
  71 %token <string> T_WORD_QUOTE
  72 %token T_UNEQUAL
  73 %token T_LESS
  74 %token T_LESS_EQUAL
  75 %token T_GREATER
  76 %token T_GREATER_EQUAL
  77 %token T_CLOSE_PAREN
  78 %token T_OPEN_PAREN
  79 %token T_EOL
  80 %token <string> T_VARIABLE
  81 %token <flavor> T_ASSIGN
  82 %token <string> T_ASSIGN_VAL
  83
  84 %left T_OR
  85 %left T_AND
  86 %left T_EQUAL T_UNEQUAL
  87 %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  88 %nonassoc T_NOT
  89
  90 %type <string> prompt
  91 %type <symbol> nonconst_symbol
  92 %type <symbol> symbol
  93 %type <expr> expr
  94 %type <expr> if_expr
  95 %type <id> end
  96 %type <menu> if_entry menu_entry choice_entry
  97 %type <string> symbol_option_arg word_opt assign_val
  98
  99 %destructor {
 100         fprintf(stderr, "%s:%d: missing end statement for this entry\n",
 101                 $$->file->name, $$->lineno);
 102         if (current_menu == $$)
 103                 menu_end_menu();
 104 } if_entry menu_entry choice_entry
 105
 106 %{
 107 /* Include kconf_id.c here so it can see the token constants. */
 108 #include "kconf_id.c"
 109 %}
 110
 111 %%
 112 input: mainmenu_stmt stmt_list | stmt_list;
 113
 114 /* mainmenu entry */
 115
 116 mainmenu_stmt: T_MAINMENU prompt T_EOL
 117 {
 118         menu_add_prompt(P_MENU, $2, NULL);
 119 };
 120
 121 stmt_list:
 122           /* empty */
 123         | stmt_list common_stmt
 124         | stmt_list choice_stmt
 125         | stmt_list menu_stmt
 126         | stmt_list T_WORD error T_EOL  { zconf_error("unknown statement \"%s\"", $2); }
 127         | stmt_list error T_EOL         { zconf_error("invalid statement"); }
 128 ;
 129
 130 common_stmt:
 131           if_stmt
 132         | comment_stmt
 133         | config_stmt
 134         | menuconfig_stmt
 135         | source_stmt
 136         | assignment_stmt
 137 ;
 138
 139 /* config/menuconfig entry */
 140
 141 config_entry_start: T_CONFIG nonconst_symbol T_EOL
 142 {
 143         $2->flags |= SYMBOL_OPTIONAL;
 144         menu_add_entry($2);
 145         printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2->name);
 146 };
 147
 148 config_stmt: config_entry_start config_option_list
 149 {
 150         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 151 };
 152
 153 menuconfig_entry_start: T_MENUCONFIG nonconst_symbol T_EOL
 154 {
 155         $2->flags |= SYMBOL_OPTIONAL;
 156         menu_add_entry($2);
 157         printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2->name);
 158 };
 159
 160 menuconfig_stmt: menuconfig_entry_start config_option_list
 161 {
 162         if (current_entry->prompt)
 163                 current_entry->prompt->type = P_MENU;
 164         else
 165                 zconfprint("warning: menuconfig statement without prompt");
 166         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 167 };
 168
 169 config_option_list:
 170           /* empty */
 171         | config_option_list config_option
 172         | config_option_list symbol_option
 173         | config_option_list depends
 174         | config_option_list help
 175 ;
 176
 177 config_option: T_TYPE prompt_stmt_opt T_EOL
 178 {
 179         menu_set_type($1->stype);
 180         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 181                 zconf_curname(), zconf_lineno(),
 182                 $1->stype);
 183 };
 184
 185 config_option: T_PROMPT prompt if_expr T_EOL
 186 {
 187         menu_add_prompt(P_PROMPT, $2, $3);
 188         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 189 };
 190
 191 config_option: T_DEFAULT expr if_expr T_EOL
 192 {
 193         menu_add_expr(P_DEFAULT, $2, $3);
 194         if ($1->stype != S_UNKNOWN)
 195                 menu_set_type($1->stype);
 196         printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
 197                 zconf_curname(), zconf_lineno(),
 198                 $1->stype);
 199 };
 200
 201 config_option: T_SELECT nonconst_symbol if_expr T_EOL
 202 {
 203         menu_add_symbol(P_SELECT, $2, $3);
 204         printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
 205 };
 206
 207 config_option: T_IMPLY nonconst_symbol if_expr T_EOL
 208 {
 209         menu_add_symbol(P_IMPLY, $2, $3);
 210         printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
 211 };
 212
 213 config_option: T_RANGE symbol symbol if_expr T_EOL
 214 {
 215         menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
 216         printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
 217 };
 218
 219 symbol_option: T_OPTION symbol_option_list T_EOL
 220 ;
 221
 222 symbol_option_list:
 223           /* empty */
 224         | symbol_option_list T_WORD symbol_option_arg
 225 {
 226         const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
 227         if (id && id->flags & TF_OPTION) {
 228                 menu_add_option(id->token, $3);
 229                 free($3);
 230         }
 231         else
 232                 zconfprint("warning: ignoring unknown option %s", $2);
 233         free($2);
 234 };
 235
 236 symbol_option_arg:
 237           /* empty */           { $$ = NULL; }
 238         | T_EQUAL prompt        { $$ = $2; }
 239 ;
 240
 241 /* choice entry */
 242
 243 choice: T_CHOICE word_opt T_EOL
 244 {
 245         struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
 246         sym->flags |= SYMBOL_NO_WRITE;
 247         menu_add_entry(sym);
 248         menu_add_expr(P_CHOICE, NULL, NULL);
 249         free($2);
 250         printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
 251 };
 252
 253 choice_entry: choice choice_option_list
 254 {
 255         $$ = menu_add_menu();
 256 };
 257
 258 choice_end: end
 259 {
 260         if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
 261                 menu_end_menu();
 262                 printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
 263         }
 264 };
 265
 266 choice_stmt: choice_entry choice_block choice_end
 267 ;
 268
 269 choice_option_list:
 270           /* empty */
 271         | choice_option_list choice_option
 272         | choice_option_list depends
 273         | choice_option_list help
 274 ;
 275
 276 choice_option: T_PROMPT prompt if_expr T_EOL
 277 {
 278         menu_add_prompt(P_PROMPT, $2, $3);
 279         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 280 };
 281
 282 choice_option: T_TYPE prompt_stmt_opt T_EOL
 283 {
 284         if ($1->stype == S_BOOLEAN || $1->stype == S_TRISTATE) {
 285                 menu_set_type($1->stype);
 286                 printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 287                         zconf_curname(), zconf_lineno(),
 288                         $1->stype);
 289         } else
 290                 YYERROR;
 291 };
 292
 293 choice_option: T_OPTIONAL T_EOL
 294 {
 295         current_entry->sym->flags |= SYMBOL_OPTIONAL;
 296         printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
 297 };
 298
 299 choice_option: T_DEFAULT nonconst_symbol if_expr T_EOL
 300 {
 301         if ($1->stype == S_UNKNOWN) {
 302                 menu_add_symbol(P_DEFAULT, $2, $3);
 303                 printd(DEBUG_PARSE, "%s:%d:default\n",
 304                         zconf_curname(), zconf_lineno());
 305         } else
 306                 YYERROR;
 307 };
 308
 309 choice_block:
 310           /* empty */
 311         | choice_block common_stmt
 312 ;
 313
 314 /* if entry */
 315
 316 if_entry: T_IF expr T_EOL
 317 {
 318         printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
 319         menu_add_entry(NULL);
 320         menu_add_dep($2);
 321         $$ = menu_add_menu();
 322 };
 323
 324 if_end: end
 325 {
 326         if (zconf_endtoken($1, T_IF, T_ENDIF)) {
 327                 menu_end_menu();
 328                 printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
 329         }
 330 };
 331
 332 if_stmt: if_entry stmt_list if_end
 333 ;
 334
 335 /* menu entry */
 336
 337 menu: T_MENU prompt T_EOL
 338 {
 339         menu_add_entry(NULL);
 340         menu_add_prompt(P_MENU, $2, NULL);
 341         printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
 342 };
 343
 344 menu_entry: menu menu_option_list
 345 {
 346         $$ = menu_add_menu();
 347 };
 348
 349 menu_end: end
 350 {
 351         if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
 352                 menu_end_menu();
 353                 printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
 354         }
 355 };
 356
 357 menu_stmt: menu_entry stmt_list menu_end
 358 ;
 359
 360 menu_option_list:
 361           /* empty */
 362         | menu_option_list visible
 363         | menu_option_list depends
 364 ;
 365
 366 source_stmt: T_SOURCE prompt T_EOL
 367 {
 368         printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
 369         zconf_nextfile($2);
 370         free($2);
 371 };
 372
 373 /* comment entry */
 374
 375 comment: T_COMMENT prompt T_EOL
 376 {
 377         menu_add_entry(NULL);
 378         menu_add_prompt(P_COMMENT, $2, NULL);
 379         printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
 380 };
 381
 382 comment_stmt: comment comment_option_list
 383 ;
 384
 385 comment_option_list:
 386           /* empty */
 387         | comment_option_list depends
 388 ;
 389
 390 /* help option */
 391
 392 help_start: T_HELP T_EOL
 393 {
 394         printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
 395         zconf_starthelp();
 396 };
 397
 398 help: help_start T_HELPTEXT
 399 {
 400         if (current_entry->help) {
 401                 free(current_entry->help);
 402                 zconfprint("warning: '%s' defined with more than one help text -- only the last one will be used",
 403                            current_entry->sym->name ?: "<choice>");
 404         }
 405
 406         /* Is the help text empty or all whitespace? */
 407         if ($2[strspn($2, " \f\n\r\t\v")] == '\0')
 408                 zconfprint("warning: '%s' defined with blank help text",
 409                            current_entry->sym->name ?: "<choice>");
 410
 411         current_entry->help = $2;
 412 };
 413
 414 /* depends option */
 415
 416 depends: T_DEPENDS T_ON expr T_EOL
 417 {
 418         menu_add_dep($3);
 419         printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
 420 };
 421
 422 /* visibility option */
 423 visible: T_VISIBLE if_expr T_EOL
 424 {
 425         menu_add_visibility($2);
 426 };
 427
 428 /* prompt statement */
 429
 430 prompt_stmt_opt:
 431           /* empty */
 432         | prompt if_expr
 433 {
 434         menu_add_prompt(P_PROMPT, $1, $2);
 435 };
 436
 437 prompt:   T_WORD
 438         | T_WORD_QUOTE
 439 ;
 440
 441 end:      T_ENDMENU T_EOL       { $$ = $1; }
 442         | T_ENDCHOICE T_EOL     { $$ = $1; }
 443         | T_ENDIF T_EOL         { $$ = $1; }
 444 ;
 445
 446 if_expr:  /* empty */                   { $$ = NULL; }
 447         | T_IF expr                     { $$ = $2; }
 448 ;
 449
 450 expr:     symbol                                { $$ = expr_alloc_symbol($1); }
 451         | symbol T_LESS symbol                  { $$ = expr_alloc_comp(E_LTH, $1, $3); }
 452         | symbol T_LESS_EQUAL symbol            { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
 453         | symbol T_GREATER symbol               { $$ = expr_alloc_comp(E_GTH, $1, $3); }
 454         | symbol T_GREATER_EQUAL symbol         { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
 455         | symbol T_EQUAL symbol                 { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
 456         | symbol T_UNEQUAL symbol               { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
 457         | T_OPEN_PAREN expr T_CLOSE_PAREN       { $$ = $2; }
 458         | T_NOT expr                            { $$ = expr_alloc_one(E_NOT, $2); }
 459         | expr T_OR expr                        { $$ = expr_alloc_two(E_OR, $1, $3); }
 460         | expr T_AND expr                       { $$ = expr_alloc_two(E_AND, $1, $3); }
 461 ;
 462
 463 /* For symbol definitions, selects, etc., where quotes are not accepted */
 464 nonconst_symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); };
 465
 466 symbol:   nonconst_symbol
 467         | T_WORD_QUOTE  { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
 468 ;
 469
 470 word_opt: /* empty */                   { $$ = NULL; }
 471         | T_WORD
 472
 473 /* assignment statement */
 474
 475 assignment_stmt:  T_VARIABLE T_ASSIGN assign_val T_EOL  { variable_add($1, $3, $2); free($1); free($3); }
 476
 477 assign_val:
 478         /* empty */             { $$ = xstrdup(""); };
 479         | T_ASSIGN_VAL
 480 ;
 481
 482 %%
 483
 484 void conf_parse(const char *name)
 485 {
 486         struct symbol *sym;
 487         int i;
 488
 489         zconf_initscan(name);
 490
 491         _menu_init();
 492         rootmenu.prompt = menu_add_prompt(P_MENU, "CARL9170 Firmware Configuration", NULL);
 493
 494         if (getenv("ZCONF_DEBUG"))
 495                 yydebug = 1;
 496         yyparse();
 497
 498         /* Variables are expanded in the parse phase. We can free them here. */
 499         variable_all_del();
 500
 501         if (yynerrs)
 502                 exit(1);
 503         if (!modules_sym)
 504                 modules_sym = sym_find( "n" );
 505
 506         if (!menu_has_prompt(&rootmenu)) {
 507                 current_entry = &rootmenu;
 508                 menu_add_prompt(P_MENU, "Main menu", NULL);
 509         }
 510
 511         menu_finalize(&rootmenu);
 512         for_all_symbols(i, sym) {
 513                 if (sym_check_deps(sym))
 514                         yynerrs++;
 515         }
 516         if (yynerrs)
 517                 exit(1);
 518         sym_set_change_count(1);
 519 }
 520
 521 static const char *zconf_tokenname(int token)
 522 {
 523         switch (token) {
 524         case T_MENU:            return "menu";
 525         case T_ENDMENU:         return "endmenu";
 526         case T_CHOICE:          return "choice";
 527         case T_ENDCHOICE:       return "endchoice";
 528         case T_IF:              return "if";
 529         case T_ENDIF:           return "endif";
 530         case T_DEPENDS:         return "depends";
 531         case T_VISIBLE:         return "visible";
 532         }
 533         return "<token>";
 534 }
 535
 536 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
 537 {
 538         if (id->token != endtoken) {
 539                 zconf_error("unexpected '%s' within %s block",
 540                         id->name, zconf_tokenname(starttoken));
 541                 yynerrs++;
 542                 return false;
 543         }
 544         if (current_menu->file != current_file) {
 545                 zconf_error("'%s' in different file than '%s'",
 546                         id->name, zconf_tokenname(starttoken));
 547                 fprintf(stderr, "%s:%d: location of the '%s'\n",
 548                         current_menu->file->name, current_menu->lineno,
 549                         zconf_tokenname(starttoken));
 550                 yynerrs++;
 551                 return false;
 552         }
 553         return true;
 554 }
 555
 556 static void zconfprint(const char *err, ...)
 557 {
 558         va_list ap;
 559
 560         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 561         va_start(ap, err);
 562         vfprintf(stderr, err, ap);
 563         va_end(ap);
 564         fprintf(stderr, "\n");
 565 }
 566
 567 static void zconf_error(const char *err, ...)
 568 {
 569         va_list ap;
 570
 571         yynerrs++;
 572         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 573         va_start(ap, err);
 574         vfprintf(stderr, err, ap);
 575         va_end(ap);
 576         fprintf(stderr, "\n");
 577 }
 578
 579 static void yyerror(const char *err)
 580 {
 581         fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
 582 }
 583
 584 static void print_quoted_string(FILE *out, const char *str)
 585 {
 586         const char *p;
 587         int len;
 588
 589         putc('"', out);
 590         while ((p = strchr(str, '"'))) {
 591                 len = p - str;
 592                 if (len)
 593                         fprintf(out, "%.*s", len, str);
 594                 fputs("\\\"", out);
 595                 str = p + 1;
 596         }
 597         fputs(str, out);
 598         putc('"', out);
 599 }
 600
 601 static void print_symbol(FILE *out, struct menu *menu)
 602 {
 603         struct symbol *sym = menu->sym;
 604         struct property *prop;
 605
 606         if (sym_is_choice(sym))
 607                 fprintf(out, "\nchoice\n");
 608         else
 609                 fprintf(out, "\nconfig %s\n", sym->name);
 610         switch (sym->type) {
 611         case S_BOOLEAN:
 612                 fputs("  bool\n", out);
 613                 break;
 614         case S_TRISTATE:
 615                 fputs("  tristate\n", out);
 616                 break;
 617         case S_STRING:
 618                 fputs("  string\n", out);
 619                 break;
 620         case S_INT:
 621                 fputs("  integer\n", out);
 622                 break;
 623         case S_HEX:
 624                 fputs("  hex\n", out);
 625                 break;
 626         default:
 627                 fputs("  ???\n", out);
 628                 break;
 629         }
 630         for (prop = sym->prop; prop; prop = prop->next) {
 631                 if (prop->menu != menu)
 632                         continue;
 633                 switch (prop->type) {
 634                 case P_PROMPT:
 635                         fputs("  prompt ", out);
 636                         print_quoted_string(out, prop->text);
 637                         if (!expr_is_yes(prop->visible.expr)) {
 638                                 fputs(" if ", out);
 639                                 expr_fprint(prop->visible.expr, out);
 640                         }
 641                         fputc('\n', out);
 642                         break;
 643                 case P_DEFAULT:
 644                         fputs( "  default ", out);
 645                         expr_fprint(prop->expr, out);
 646                         if (!expr_is_yes(prop->visible.expr)) {
 647                                 fputs(" if ", out);
 648                                 expr_fprint(prop->visible.expr, out);
 649                         }
 650                         fputc('\n', out);
 651                         break;
 652                 case P_CHOICE:
 653                         fputs("  #choice value\n", out);
 654                         break;
 655                 case P_SELECT:
 656                         fputs( "  select ", out);
 657                         expr_fprint(prop->expr, out);
 658                         fputc('\n', out);
 659                         break;
 660                 case P_IMPLY:
 661                         fputs( "  imply ", out);
 662                         expr_fprint(prop->expr, out);
 663                         fputc('\n', out);
 664                         break;
 665                 case P_RANGE:
 666                         fputs( "  range ", out);
 667                         expr_fprint(prop->expr, out);
 668                         fputc('\n', out);
 669                         break;
 670                 case P_MENU:
 671                         fputs( "  menu ", out);
 672                         print_quoted_string(out, prop->text);
 673                         fputc('\n', out);
 674                         break;
 675                 case P_SYMBOL:
 676                         fputs( "  symbol ", out);
 677                         fprintf(out, "%s\n", prop->sym->name);
 678                         break;
 679                 default:
 680                         fprintf(out, "  unknown prop %d!\n", prop->type);
 681                         break;
 682                 }
 683         }
 684         if (menu->help) {
 685                 int len = strlen(menu->help);
 686                 while (menu->help[--len] == '\n')
 687                         menu->help[len] = 0;
 688                 fprintf(out, "  help\n%s\n", menu->help);
 689         }
 690 }
 691
 692 void zconfdump(FILE *out)
 693 {
 694         struct property *prop;
 695         struct symbol *sym;
 696         struct menu *menu;
 697
 698         menu = rootmenu.list;
 699         while (menu) {
 700                 if ((sym = menu->sym))
 701                         print_symbol(out, menu);
 702                 else if ((prop = menu->prompt)) {
 703                         switch (prop->type) {
 704                         case P_COMMENT:
 705                                 fputs("\ncomment ", out);
 706                                 print_quoted_string(out, prop->text);
 707                                 fputs("\n", out);
 708                                 break;
 709                         case P_MENU:
 710                                 fputs("\nmenu ", out);
 711                                 print_quoted_string(out, prop->text);
 712                                 fputs("\n", out);
 713                                 break;
 714                         default:
 715                                 ;
 716                         }
 717                         if (!expr_is_yes(prop->visible.expr)) {
 718                                 fputs("  depends ", out);
 719                                 expr_fprint(prop->visible.expr, out);
 720                                 fputc('\n', out);
 721                         }
 722                 }
 723
 724                 if (menu->list)
 725                         menu = menu->list;
 726                 else if (menu->next)
 727                         menu = menu->next;
 728                 else while ((menu = menu->parent)) {
 729                         if (menu->prompt && menu->prompt->type == P_MENU)
 730                                 fputs("\nendmenu\n", out);
 731                         if (menu->next) {
 732                                 menu = menu->next;
 733                                 break;
 734                         }
 735                 }
 736         }
 737 }
 738
 739 #include "zconf.lex.c"
 740 #include "util.c"
 741 #include "confdata.c"
 742 #include "expr.c"
 743 #include "symbol.c"
 744 #include "menu.c"
 745 #include "preprocess.c"