config/zconf.y

   1 %{
   2 /*
   3  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   4  * Released under the terms of the GNU GPL v2.0.
   5  */
   6
   7 #include <ctype.h>
   8 #include <stdarg.h>
   9 #include <stdio.h>
  10 #include <stdlib.h>
  11 #include <string.h>
  12 #include <stdbool.h>
  13
  14 #include "lkc.h"
  15
  16 #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  17
  18 #define PRINTD          0x0001
  19 #define DEBUG_PARSE     0x0002
  20
  21 int cdebug = PRINTD;
  22
  23 int yylex(void);
  24 static void yyerror(const char *err);
  25 static void zconfprint(const char *err, ...);
  26 static void zconf_error(const char *err, ...);
  27 static bool zconf_endtoken(const char *tokenname,
  28                            const char *expected_tokenname);
  29
  30 struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  31
  32 static struct menu *current_menu, *current_entry;
  33
  34 %}
  35
  36 %union
  37 {
  38         char *string;
  39         struct file *file;
  40         struct symbol *symbol;
  41         struct expr *expr;
  42         struct menu *menu;
  43         enum symbol_type type;
  44         enum variable_flavor flavor;
  45 }
  46
  47 %token <string> T_HELPTEXT
  48 %token <string> T_WORD
  49 %token <string> T_WORD_QUOTE
  50 %token T_ALLNOCONFIG_Y
  51 %token T_BOOL
  52 %token T_CHOICE
  53 %token T_CLOSE_PAREN
  54 %token T_COLON_EQUAL
  55 %token T_COMMENT
  56 %token T_CONFIG
  57 %token T_DEFAULT
  58 %token T_DEFCONFIG_LIST
  59 %token T_DEF_BOOL
  60 %token T_DEF_TRISTATE
  61 %token T_DEPENDS
  62 %token T_ENDCHOICE
  63 %token T_ENDIF
  64 %token T_ENDMENU
  65 %token T_HELP
  66 %token T_HEX
  67 %token T_IF
  68 %token T_IMPLY
  69 %token T_INT
  70 %token T_MAINMENU
  71 %token T_MENU
  72 %token T_MENUCONFIG
  73 %token T_MODULES
  74 %token T_ON
  75 %token T_OPEN_PAREN
  76 %token T_OPTION
  77 %token T_OPTIONAL
  78 %token T_PLUS_EQUAL
  79 %token T_PROMPT
  80 %token T_RANGE
  81 %token T_SELECT
  82 %token T_SOURCE
  83 %token T_STRING
  84 %token T_TRISTATE
  85 %token T_VISIBLE
  86 %token T_EOL
  87 %token <string> T_ASSIGN_VAL
  88
  89 %left T_OR
  90 %left T_AND
  91 %left T_EQUAL T_UNEQUAL
  92 %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  93 %nonassoc T_NOT
  94
  95 %type <string> prompt
  96 %type <symbol> nonconst_symbol
  97 %type <symbol> symbol
  98 %type <type> type logic_type default
  99 %type <expr> expr
 100 %type <expr> if_expr
 101 %type <string> end
 102 %type <menu> if_entry menu_entry choice_entry
 103 %type <string> word_opt assign_val
 104 %type <flavor> assign_op
 105
 106 %destructor {
 107         fprintf(stderr, "%s:%d: missing end statement for this entry\n",
 108                 $$->file->name, $$->lineno);
 109         if (current_menu == $$)
 110                 menu_end_menu();
 111 } if_entry menu_entry choice_entry
 112
 113 %{
 114 /* Include kconf_id.c here so it can see the token constants. */
 115 #include "kconf_id.c"
 116 %}
 117
 118 %%
 119 input: mainmenu_stmt stmt_list | stmt_list;
 120
 121 /* mainmenu entry */
 122
 123 mainmenu_stmt: T_MAINMENU prompt T_EOL
 124 {
 125         menu_add_prompt(P_MENU, $2, NULL);
 126 };
 127
 128 stmt_list:
 129           /* empty */
 130         | stmt_list common_stmt
 131         | stmt_list choice_stmt
 132         | stmt_list menu_stmt
 133         | stmt_list T_WORD error T_EOL  { zconf_error("unknown statement \"%s\"", $2); }
 134         | stmt_list error T_EOL         { zconf_error("invalid statement"); }
 135 ;
 136
 137 common_stmt:
 138           if_stmt
 139         | comment_stmt
 140         | config_stmt
 141         | menuconfig_stmt
 142         | source_stmt
 143         | assignment_stmt
 144 ;
 145
 146 /* config/menuconfig entry */
 147
 148 config_entry_start: T_CONFIG nonconst_symbol T_EOL
 149 {
 150         $2->flags |= SYMBOL_OPTIONAL;
 151         menu_add_entry($2);
 152         printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2->name);
 153 };
 154
 155 config_stmt: config_entry_start config_option_list
 156 {
 157         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 158 };
 159
 160 menuconfig_entry_start: T_MENUCONFIG nonconst_symbol T_EOL
 161 {
 162         $2->flags |= SYMBOL_OPTIONAL;
 163         menu_add_entry($2);
 164         printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2->name);
 165 };
 166
 167 menuconfig_stmt: menuconfig_entry_start config_option_list
 168 {
 169         if (current_entry->prompt)
 170                 current_entry->prompt->type = P_MENU;
 171         else
 172                 zconfprint("warning: menuconfig statement without prompt");
 173         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 174 };
 175
 176 config_option_list:
 177           /* empty */
 178         | config_option_list config_option
 179         | config_option_list depends
 180         | config_option_list help
 181 ;
 182
 183 config_option: type prompt_stmt_opt T_EOL
 184 {
 185         menu_set_type($1);
 186         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 187                 zconf_curname(), zconf_lineno(),
 188                 $1);
 189 };
 190
 191 config_option: T_PROMPT prompt if_expr T_EOL
 192 {
 193         menu_add_prompt(P_PROMPT, $2, $3);
 194         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 195 };
 196
 197 config_option: default expr if_expr T_EOL
 198 {
 199         menu_add_expr(P_DEFAULT, $2, $3);
 200         if ($1 != S_UNKNOWN)
 201                 menu_set_type($1);
 202         printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
 203                 zconf_curname(), zconf_lineno(),
 204                 $1);
 205 };
 206
 207 config_option: T_SELECT nonconst_symbol if_expr T_EOL
 208 {
 209         menu_add_symbol(P_SELECT, $2, $3);
 210         printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
 211 };
 212
 213 config_option: T_IMPLY nonconst_symbol if_expr T_EOL
 214 {
 215         menu_add_symbol(P_IMPLY, $2, $3);
 216         printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
 217 };
 218
 219 config_option: T_RANGE symbol symbol if_expr T_EOL
 220 {
 221         menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
 222         printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
 223 };
 224
 225 config_option: T_OPTION T_MODULES T_EOL
 226 {
 227         menu_add_option_modules();
 228 };
 229
 230 config_option: T_OPTION T_DEFCONFIG_LIST T_EOL
 231 {
 232         menu_add_option_defconfig_list();
 233 };
 234
 235 config_option: T_OPTION T_ALLNOCONFIG_Y T_EOL
 236 {
 237         menu_add_option_allnoconfig_y();
 238 };
 239
 240 /* choice entry */
 241
 242 choice: T_CHOICE word_opt T_EOL
 243 {
 244         struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
 245         sym->flags |= SYMBOL_NO_WRITE;
 246         menu_add_entry(sym);
 247         menu_add_expr(P_CHOICE, NULL, NULL);
 248         free($2);
 249         printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
 250 };
 251
 252 choice_entry: choice choice_option_list
 253 {
 254         $$ = menu_add_menu();
 255 };
 256
 257 choice_end: end
 258 {
 259         if (zconf_endtoken($1, "choice")) {
 260                 menu_end_menu();
 261                 printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
 262         }
 263 };
 264
 265 choice_stmt: choice_entry choice_block choice_end
 266 ;
 267
 268 choice_option_list:
 269           /* empty */
 270         | choice_option_list choice_option
 271         | choice_option_list depends
 272         | choice_option_list help
 273 ;
 274
 275 choice_option: T_PROMPT prompt if_expr T_EOL
 276 {
 277         menu_add_prompt(P_PROMPT, $2, $3);
 278         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 279 };
 280
 281 choice_option: logic_type prompt_stmt_opt T_EOL
 282 {
 283         menu_set_type($1);
 284         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 285                zconf_curname(), zconf_lineno(), $1);
 286 };
 287
 288 choice_option: T_OPTIONAL T_EOL
 289 {
 290         current_entry->sym->flags |= SYMBOL_OPTIONAL;
 291         printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
 292 };
 293
 294 choice_option: T_DEFAULT nonconst_symbol if_expr T_EOL
 295 {
 296         menu_add_symbol(P_DEFAULT, $2, $3);
 297         printd(DEBUG_PARSE, "%s:%d:default\n",
 298                zconf_curname(), zconf_lineno());
 299 };
 300
 301 type:
 302           logic_type
 303         | T_INT                 { $$ = S_INT; }
 304         | T_HEX                 { $$ = S_HEX; }
 305         | T_STRING              { $$ = S_STRING; }
 306
 307 logic_type:
 308           T_BOOL                { $$ = S_BOOLEAN; }
 309         | T_TRISTATE            { $$ = S_TRISTATE; }
 310
 311 default:
 312           T_DEFAULT             { $$ = S_UNKNOWN; }
 313         | T_DEF_BOOL            { $$ = S_BOOLEAN; }
 314         | T_DEF_TRISTATE        { $$ = S_TRISTATE; }
 315
 316 choice_block:
 317           /* empty */
 318         | choice_block common_stmt
 319 ;
 320
 321 /* if entry */
 322
 323 if_entry: T_IF expr T_EOL
 324 {
 325         printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
 326         menu_add_entry(NULL);
 327         menu_add_dep($2);
 328         $$ = menu_add_menu();
 329 };
 330
 331 if_end: end
 332 {
 333         if (zconf_endtoken($1, "if")) {
 334                 menu_end_menu();
 335                 printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
 336         }
 337 };
 338
 339 if_stmt: if_entry stmt_list if_end
 340 ;
 341
 342 /* menu entry */
 343
 344 menu: T_MENU prompt T_EOL
 345 {
 346         menu_add_entry(NULL);
 347         menu_add_prompt(P_MENU, $2, NULL);
 348         printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
 349 };
 350
 351 menu_entry: menu menu_option_list
 352 {
 353         $$ = menu_add_menu();
 354 };
 355
 356 menu_end: end
 357 {
 358         if (zconf_endtoken($1, "menu")) {
 359                 menu_end_menu();
 360                 printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
 361         }
 362 };
 363
 364 menu_stmt: menu_entry stmt_list menu_end
 365 ;
 366
 367 menu_option_list:
 368           /* empty */
 369         | menu_option_list visible
 370         | menu_option_list depends
 371 ;
 372
 373 source_stmt: T_SOURCE prompt T_EOL
 374 {
 375         printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
 376         zconf_nextfile($2);
 377         free($2);
 378 };
 379
 380 /* comment entry */
 381
 382 comment: T_COMMENT prompt T_EOL
 383 {
 384         menu_add_entry(NULL);
 385         menu_add_prompt(P_COMMENT, $2, NULL);
 386         printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
 387 };
 388
 389 comment_stmt: comment comment_option_list
 390 ;
 391
 392 comment_option_list:
 393           /* empty */
 394         | comment_option_list depends
 395 ;
 396
 397 /* help option */
 398
 399 help_start: T_HELP T_EOL
 400 {
 401         printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
 402         zconf_starthelp();
 403 };
 404
 405 help: help_start T_HELPTEXT
 406 {
 407         if (current_entry->help) {
 408                 free(current_entry->help);
 409                 zconfprint("warning: '%s' defined with more than one help text -- only the last one will be used",
 410                            current_entry->sym->name ?: "<choice>");
 411         }
 412
 413         /* Is the help text empty or all whitespace? */
 414         if ($2[strspn($2, " \f\n\r\t\v")] == '\0')
 415                 zconfprint("warning: '%s' defined with blank help text",
 416                            current_entry->sym->name ?: "<choice>");
 417
 418         current_entry->help = $2;
 419 };
 420
 421 /* depends option */
 422
 423 depends: T_DEPENDS T_ON expr T_EOL
 424 {
 425         menu_add_dep($3);
 426         printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
 427 };
 428
 429 /* visibility option */
 430 visible: T_VISIBLE if_expr T_EOL
 431 {
 432         menu_add_visibility($2);
 433 };
 434
 435 /* prompt statement */
 436
 437 prompt_stmt_opt:
 438           /* empty */
 439         | prompt if_expr
 440 {
 441         menu_add_prompt(P_PROMPT, $1, $2);
 442 };
 443
 444 prompt:   T_WORD
 445         | T_WORD_QUOTE
 446 ;
 447
 448 end:      T_ENDMENU T_EOL       { $$ = "menu"; }
 449         | T_ENDCHOICE T_EOL     { $$ = "choice"; }
 450         | T_ENDIF T_EOL         { $$ = "if"; }
 451 ;
 452
 453 if_expr:  /* empty */                   { $$ = NULL; }
 454         | T_IF expr                     { $$ = $2; }
 455 ;
 456
 457 expr:     symbol                                { $$ = expr_alloc_symbol($1); }
 458         | symbol T_LESS symbol                  { $$ = expr_alloc_comp(E_LTH, $1, $3); }
 459         | symbol T_LESS_EQUAL symbol            { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
 460         | symbol T_GREATER symbol               { $$ = expr_alloc_comp(E_GTH, $1, $3); }
 461         | symbol T_GREATER_EQUAL symbol         { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
 462         | symbol T_EQUAL symbol                 { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
 463         | symbol T_UNEQUAL symbol               { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
 464         | T_OPEN_PAREN expr T_CLOSE_PAREN       { $$ = $2; }
 465         | T_NOT expr                            { $$ = expr_alloc_one(E_NOT, $2); }
 466         | expr T_OR expr                        { $$ = expr_alloc_two(E_OR, $1, $3); }
 467         | expr T_AND expr                       { $$ = expr_alloc_two(E_AND, $1, $3); }
 468 ;
 469
 470 /* For symbol definitions, selects, etc., where quotes are not accepted */
 471 nonconst_symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); };
 472
 473 symbol:   nonconst_symbol
 474         | T_WORD_QUOTE  { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
 475 ;
 476
 477 word_opt: /* empty */                   { $$ = NULL; }
 478         | T_WORD
 479
 480 /* assignment statement */
 481
 482 assignment_stmt:  T_WORD assign_op assign_val T_EOL     { variable_add($1, $3, $2); free($1); free($3); }
 483
 484 assign_op:
 485           T_EQUAL       { $$ = VAR_RECURSIVE; }
 486         | T_COLON_EQUAL { $$ = VAR_SIMPLE; }
 487         | T_PLUS_EQUAL  { $$ = VAR_APPEND; }
 488 ;
 489
 490 assign_val:
 491         /* empty */             { $$ = xstrdup(""); };
 492         | T_ASSIGN_VAL
 493 ;
 494
 495 %%
 496
 497 void conf_parse(const char *name)
 498 {
 499         struct symbol *sym;
 500         int i;
 501
 502         zconf_initscan(name);
 503
 504         _menu_init();
 505         rootmenu.prompt = menu_add_prompt(P_MENU, "CARL9170 Firmware Configuration", NULL);
 506
 507         if (getenv("ZCONF_DEBUG"))
 508                 yydebug = 1;
 509         yyparse();
 510
 511         /* Variables are expanded in the parse phase. We can free them here. */
 512         variable_all_del();
 513
 514         if (yynerrs)
 515                 exit(1);
 516         if (!modules_sym)
 517                 modules_sym = sym_find( "n" );
 518
 519         if (!menu_has_prompt(&rootmenu)) {
 520                 current_entry = &rootmenu;
 521                 menu_add_prompt(P_MENU, "Main menu", NULL);
 522         }
 523
 524         menu_finalize(&rootmenu);
 525         for_all_symbols(i, sym) {
 526                 if (sym_check_deps(sym))
 527                         yynerrs++;
 528         }
 529         if (yynerrs)
 530                 exit(1);
 531         sym_set_change_count(1);
 532 }
 533
 534 static bool zconf_endtoken(const char *tokenname,
 535                            const char *expected_tokenname)
 536 {
 537         if (strcmp(tokenname, expected_tokenname)) {
 538                 zconf_error("unexpected '%s' within %s block",
 539                             tokenname, expected_tokenname);
 540                 yynerrs++;
 541                 return false;
 542         }
 543         if (current_menu->file != current_file) {
 544                 zconf_error("'%s' in different file than '%s'",
 545                             tokenname, expected_tokenname);
 546                 fprintf(stderr, "%s:%d: location of the '%s'\n",
 547                         current_menu->file->name, current_menu->lineno,
 548                         expected_tokenname);
 549                 yynerrs++;
 550                 return false;
 551         }
 552         return true;
 553 }
 554
 555 static void zconfprint(const char *err, ...)
 556 {
 557         va_list ap;
 558
 559         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 560         va_start(ap, err);
 561         vfprintf(stderr, err, ap);
 562         va_end(ap);
 563         fprintf(stderr, "\n");
 564 }
 565
 566 static void zconf_error(const char *err, ...)
 567 {
 568         va_list ap;
 569
 570         yynerrs++;
 571         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 572         va_start(ap, err);
 573         vfprintf(stderr, err, ap);
 574         va_end(ap);
 575         fprintf(stderr, "\n");
 576 }
 577
 578 static void yyerror(const char *err)
 579 {
 580         fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
 581 }
 582
 583 static void print_quoted_string(FILE *out, const char *str)
 584 {
 585         const char *p;
 586         int len;
 587
 588         putc('"', out);
 589         while ((p = strchr(str, '"'))) {
 590                 len = p - str;
 591                 if (len)
 592                         fprintf(out, "%.*s", len, str);
 593                 fputs("\\\"", out);
 594                 str = p + 1;
 595         }
 596         fputs(str, out);
 597         putc('"', out);
 598 }
 599
 600 static void print_symbol(FILE *out, struct menu *menu)
 601 {
 602         struct symbol *sym = menu->sym;
 603         struct property *prop;
 604
 605         if (sym_is_choice(sym))
 606                 fprintf(out, "\nchoice\n");
 607         else
 608                 fprintf(out, "\nconfig %s\n", sym->name);
 609         switch (sym->type) {
 610         case S_BOOLEAN:
 611                 fputs("  bool\n", out);
 612                 break;
 613         case S_TRISTATE:
 614                 fputs("  tristate\n", out);
 615                 break;
 616         case S_STRING:
 617                 fputs("  string\n", out);
 618                 break;
 619         case S_INT:
 620                 fputs("  integer\n", out);
 621                 break;
 622         case S_HEX:
 623                 fputs("  hex\n", out);
 624                 break;
 625         default:
 626                 fputs("  ???\n", out);
 627                 break;
 628         }
 629         for (prop = sym->prop; prop; prop = prop->next) {
 630                 if (prop->menu != menu)
 631                         continue;
 632                 switch (prop->type) {
 633                 case P_PROMPT:
 634                         fputs("  prompt ", out);
 635                         print_quoted_string(out, prop->text);
 636                         if (!expr_is_yes(prop->visible.expr)) {
 637                                 fputs(" if ", out);
 638                                 expr_fprint(prop->visible.expr, out);
 639                         }
 640                         fputc('\n', out);
 641                         break;
 642                 case P_DEFAULT:
 643                         fputs( "  default ", out);
 644                         expr_fprint(prop->expr, out);
 645                         if (!expr_is_yes(prop->visible.expr)) {
 646                                 fputs(" if ", out);
 647                                 expr_fprint(prop->visible.expr, out);
 648                         }
 649                         fputc('\n', out);
 650                         break;
 651                 case P_CHOICE:
 652                         fputs("  #choice value\n", out);
 653                         break;
 654                 case P_SELECT:
 655                         fputs( "  select ", out);
 656                         expr_fprint(prop->expr, out);
 657                         fputc('\n', out);
 658                         break;
 659                 case P_IMPLY:
 660                         fputs( "  imply ", out);
 661                         expr_fprint(prop->expr, out);
 662                         fputc('\n', out);
 663                         break;
 664                 case P_RANGE:
 665                         fputs( "  range ", out);
 666                         expr_fprint(prop->expr, out);
 667                         fputc('\n', out);
 668                         break;
 669                 case P_MENU:
 670                         fputs( "  menu ", out);
 671                         print_quoted_string(out, prop->text);
 672                         fputc('\n', out);
 673                         break;
 674                 case P_SYMBOL:
 675                         fputs( "  symbol ", out);
 676                         fprintf(out, "%s\n", prop->sym->name);
 677                         break;
 678                 default:
 679                         fprintf(out, "  unknown prop %d!\n", prop->type);
 680                         break;
 681                 }
 682         }
 683         if (menu->help) {
 684                 int len = strlen(menu->help);
 685                 while (menu->help[--len] == '\n')
 686                         menu->help[len] = 0;
 687                 fprintf(out, "  help\n%s\n", menu->help);
 688         }
 689 }
 690
 691 void zconfdump(FILE *out)
 692 {
 693         struct property *prop;
 694         struct symbol *sym;
 695         struct menu *menu;
 696
 697         menu = rootmenu.list;
 698         while (menu) {
 699                 if ((sym = menu->sym))
 700                         print_symbol(out, menu);
 701                 else if ((prop = menu->prompt)) {
 702                         switch (prop->type) {
 703                         case P_COMMENT:
 704                                 fputs("\ncomment ", out);
 705                                 print_quoted_string(out, prop->text);
 706                                 fputs("\n", out);
 707                                 break;
 708                         case P_MENU:
 709                                 fputs("\nmenu ", out);
 710                                 print_quoted_string(out, prop->text);
 711                                 fputs("\n", out);
 712                                 break;
 713                         default:
 714                                 ;
 715                         }
 716                         if (!expr_is_yes(prop->visible.expr)) {
 717                                 fputs("  depends ", out);
 718                                 expr_fprint(prop->visible.expr, out);
 719                                 fputc('\n', out);
 720                         }
 721                 }
 722
 723                 if (menu->list)
 724                         menu = menu->list;
 725                 else if (menu->next)
 726                         menu = menu->next;
 727                 else while ((menu = menu->parent)) {
 728                         if (menu->prompt && menu->prompt->type == P_MENU)
 729                                 fputs("\nendmenu\n", out);
 730                         if (menu->next) {
 731                                 menu = menu->next;
 732                                 break;
 733                         }
 734                 }
 735         }
 736 }
 737
 738 #include "zconf.lex.c"
 739 #include "util.c"
 740 #include "confdata.c"
 741 #include "expr.c"
 742 #include "symbol.c"
 743 #include "menu.c"
 744 #include "preprocess.c"