config/zconf.y

   1 %{
   2 /*
   3  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   4  * Released under the terms of the GNU GPL v2.0.
   5  */
   6
   7 #include <ctype.h>
   8 #include <stdarg.h>
   9 #include <stdio.h>
  10 #include <stdlib.h>
  11 #include <string.h>
  12 #include <stdbool.h>
  13
  14 #include "lkc.h"
  15
  16 #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  17
  18 #define PRINTD          0x0001
  19 #define DEBUG_PARSE     0x0002
  20
  21 int cdebug = PRINTD;
  22
  23 extern int zconflex(void);
  24 static void zconfprint(const char *err, ...);
  25 static void zconf_error(const char *err, ...);
  26 static void zconferror(const char *err);
  27 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);
  28
  29 struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  30
  31 static struct menu *current_menu, *current_entry;
  32
  33 %}
  34 %expect 32
  35
  36 %union
  37 {
  38         char *string;
  39         struct file *file;
  40         struct symbol *symbol;
  41         struct expr *expr;
  42         struct menu *menu;
  43         const struct kconf_id *id;
  44 }
  45
  46 %token <id>T_MAINMENU
  47 %token <id>T_MENU
  48 %token <id>T_ENDMENU
  49 %token <id>T_SOURCE
  50 %token <id>T_CHOICE
  51 %token <id>T_ENDCHOICE
  52 %token <id>T_COMMENT
  53 %token <id>T_CONFIG
  54 %token <id>T_MENUCONFIG
  55 %token <id>T_HELP
  56 %token <string> T_HELPTEXT
  57 %token <id>T_IF
  58 %token <id>T_ENDIF
  59 %token <id>T_DEPENDS
  60 %token <id>T_OPTIONAL
  61 %token <id>T_PROMPT
  62 %token <id>T_TYPE
  63 %token <id>T_DEFAULT
  64 %token <id>T_SELECT
  65 %token <id>T_IMPLY
  66 %token <id>T_RANGE
  67 %token <id>T_VISIBLE
  68 %token <id>T_OPTION
  69 %token <id>T_ON
  70 %token <string> T_WORD
  71 %token <string> T_WORD_QUOTE
  72 %token T_UNEQUAL
  73 %token T_LESS
  74 %token T_LESS_EQUAL
  75 %token T_GREATER
  76 %token T_GREATER_EQUAL
  77 %token T_CLOSE_PAREN
  78 %token T_OPEN_PAREN
  79 %token T_EOL
  80
  81 %left T_OR
  82 %left T_AND
  83 %left T_EQUAL T_UNEQUAL
  84 %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  85 %nonassoc T_NOT
  86
  87 %type <string> prompt
  88 %type <symbol> nonconst_symbol
  89 %type <symbol> symbol
  90 %type <expr> expr
  91 %type <expr> if_expr
  92 %type <id> end
  93 %type <id> option_name
  94 %type <menu> if_entry menu_entry choice_entry
  95 %type <string> symbol_option_arg word_opt
  96
  97 %destructor {
  98         fprintf(stderr, "%s:%d: missing end statement for this entry\n",
  99                 $$->file->name, $$->lineno);
 100         if (current_menu == $$)
 101                 menu_end_menu();
 102 } if_entry menu_entry choice_entry
 103
 104 %{
 105 /* Include kconf_id.c here so it can see the token constants. */
 106 #include "kconf_id.c"
 107 %}
 108
 109 %%
 110 input: nl start | start;
 111
 112 start: mainmenu_stmt stmt_list | no_mainmenu_stmt stmt_list;
 113
 114 /* mainmenu entry */
 115
 116 mainmenu_stmt: T_MAINMENU prompt nl
 117 {
 118         menu_add_prompt(P_MENU, $2, NULL);
 119 };
 120
 121 /* Default main menu, if there's no mainmenu entry */
 122
 123 no_mainmenu_stmt: /* empty */
 124 {
 125         /*
 126          * Hack: Keep the main menu title on the heap so we can safely free it
 127          * later regardless of whether it comes from the 'prompt' in
 128          * mainmenu_stmt or here
 129          */
 130         menu_add_prompt(P_MENU, strdup("Linux Kernel Configuration"), NULL);
 131 };
 132
 133
 134 stmt_list:
 135           /* empty */
 136         | stmt_list common_stmt
 137         | stmt_list choice_stmt
 138         | stmt_list menu_stmt
 139         | stmt_list end                 { zconf_error("unexpected end statement"); }
 140         | stmt_list T_WORD error T_EOL  { zconf_error("unknown statement \"%s\"", $2); }
 141         | stmt_list option_name error T_EOL
 142 {
 143         zconf_error("unexpected option \"%s\"", $2->name);
 144 }
 145         | stmt_list error T_EOL         { zconf_error("invalid statement"); }
 146 ;
 147
 148 option_name:
 149         T_DEPENDS | T_PROMPT | T_TYPE | T_SELECT | T_IMPLY | T_OPTIONAL | T_RANGE | T_DEFAULT | T_VISIBLE
 150 ;
 151
 152 common_stmt:
 153           T_EOL
 154         | if_stmt
 155         | comment_stmt
 156         | config_stmt
 157         | menuconfig_stmt
 158         | source_stmt
 159 ;
 160
 161 option_error:
 162           T_WORD error T_EOL            { zconf_error("unknown option \"%s\"", $1); }
 163         | error T_EOL                   { zconf_error("invalid option"); }
 164 ;
 165
 166
 167 /* config/menuconfig entry */
 168
 169 config_entry_start: T_CONFIG nonconst_symbol T_EOL
 170 {
 171         $2->flags |= SYMBOL_OPTIONAL;
 172         menu_add_entry($2);
 173         printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2->name);
 174 };
 175
 176 config_stmt: config_entry_start config_option_list
 177 {
 178         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 179 };
 180
 181 menuconfig_entry_start: T_MENUCONFIG nonconst_symbol T_EOL
 182 {
 183         $2->flags |= SYMBOL_OPTIONAL;
 184         menu_add_entry($2);
 185         printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2->name);
 186 };
 187
 188 menuconfig_stmt: menuconfig_entry_start config_option_list
 189 {
 190         if (current_entry->prompt)
 191                 current_entry->prompt->type = P_MENU;
 192         else
 193                 zconfprint("warning: menuconfig statement without prompt");
 194         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 195 };
 196
 197 config_option_list:
 198           /* empty */
 199         | config_option_list config_option
 200         | config_option_list symbol_option
 201         | config_option_list depends
 202         | config_option_list help
 203         | config_option_list option_error
 204         | config_option_list T_EOL
 205 ;
 206
 207 config_option: T_TYPE prompt_stmt_opt T_EOL
 208 {
 209         menu_set_type($1->stype);
 210         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 211                 zconf_curname(), zconf_lineno(),
 212                 $1->stype);
 213 };
 214
 215 config_option: T_PROMPT prompt if_expr T_EOL
 216 {
 217         menu_add_prompt(P_PROMPT, $2, $3);
 218         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 219 };
 220
 221 config_option: T_DEFAULT expr if_expr T_EOL
 222 {
 223         menu_add_expr(P_DEFAULT, $2, $3);
 224         if ($1->stype != S_UNKNOWN)
 225                 menu_set_type($1->stype);
 226         printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
 227                 zconf_curname(), zconf_lineno(),
 228                 $1->stype);
 229 };
 230
 231 config_option: T_SELECT nonconst_symbol if_expr T_EOL
 232 {
 233         menu_add_symbol(P_SELECT, $2, $3);
 234         printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
 235 };
 236
 237 config_option: T_IMPLY nonconst_symbol if_expr T_EOL
 238 {
 239         menu_add_symbol(P_IMPLY, $2, $3);
 240         printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
 241 };
 242
 243 config_option: T_RANGE symbol symbol if_expr T_EOL
 244 {
 245         menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
 246         printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
 247 };
 248
 249 symbol_option: T_OPTION symbol_option_list T_EOL
 250 ;
 251
 252 symbol_option_list:
 253           /* empty */
 254         | symbol_option_list T_WORD symbol_option_arg
 255 {
 256         const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
 257         if (id && id->flags & TF_OPTION) {
 258                 menu_add_option(id->token, $3);
 259                 free($3);
 260         }
 261         else
 262                 zconfprint("warning: ignoring unknown option %s", $2);
 263         free($2);
 264 };
 265
 266 symbol_option_arg:
 267           /* empty */           { $$ = NULL; }
 268         | T_EQUAL prompt        { $$ = $2; }
 269 ;
 270
 271 /* choice entry */
 272
 273 choice: T_CHOICE word_opt T_EOL
 274 {
 275         struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
 276         sym->flags |= SYMBOL_AUTO;
 277         menu_add_entry(sym);
 278         menu_add_expr(P_CHOICE, NULL, NULL);
 279         printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
 280 };
 281
 282 choice_entry: choice choice_option_list
 283 {
 284         $$ = menu_add_menu();
 285 };
 286
 287 choice_end: end
 288 {
 289         if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
 290                 menu_end_menu();
 291                 printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
 292         }
 293 };
 294
 295 choice_stmt: choice_entry choice_block choice_end
 296 ;
 297
 298 choice_option_list:
 299           /* empty */
 300         | choice_option_list choice_option
 301         | choice_option_list depends
 302         | choice_option_list help
 303         | choice_option_list T_EOL
 304         | choice_option_list option_error
 305 ;
 306
 307 choice_option: T_PROMPT prompt if_expr T_EOL
 308 {
 309         menu_add_prompt(P_PROMPT, $2, $3);
 310         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 311 };
 312
 313 choice_option: T_TYPE prompt_stmt_opt T_EOL
 314 {
 315         if ($1->stype == S_BOOLEAN || $1->stype == S_TRISTATE) {
 316                 menu_set_type($1->stype);
 317                 printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 318                         zconf_curname(), zconf_lineno(),
 319                         $1->stype);
 320         } else
 321                 YYERROR;
 322 };
 323
 324 choice_option: T_OPTIONAL T_EOL
 325 {
 326         current_entry->sym->flags |= SYMBOL_OPTIONAL;
 327         printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
 328 };
 329
 330 choice_option: T_DEFAULT nonconst_symbol if_expr T_EOL
 331 {
 332         if ($1->stype == S_UNKNOWN) {
 333                 menu_add_symbol(P_DEFAULT, $2, $3);
 334                 printd(DEBUG_PARSE, "%s:%d:default\n",
 335                         zconf_curname(), zconf_lineno());
 336         } else
 337                 YYERROR;
 338 };
 339
 340 choice_block:
 341           /* empty */
 342         | choice_block common_stmt
 343 ;
 344
 345 /* if entry */
 346
 347 if_entry: T_IF expr nl
 348 {
 349         printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
 350         menu_add_entry(NULL);
 351         menu_add_dep($2);
 352         $$ = menu_add_menu();
 353 };
 354
 355 if_end: end
 356 {
 357         if (zconf_endtoken($1, T_IF, T_ENDIF)) {
 358                 menu_end_menu();
 359                 printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
 360         }
 361 };
 362
 363 if_stmt: if_entry if_block if_end
 364 ;
 365
 366 if_block:
 367           /* empty */
 368         | if_block common_stmt
 369         | if_block menu_stmt
 370         | if_block choice_stmt
 371 ;
 372
 373 /* menu entry */
 374
 375 menu: T_MENU prompt T_EOL
 376 {
 377         menu_add_entry(NULL);
 378         menu_add_prompt(P_MENU, $2, NULL);
 379         printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
 380 };
 381
 382 menu_entry: menu visibility_list depends_list
 383 {
 384         $$ = menu_add_menu();
 385 };
 386
 387 menu_end: end
 388 {
 389         if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
 390                 menu_end_menu();
 391                 printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
 392         }
 393 };
 394
 395 menu_stmt: menu_entry menu_block menu_end
 396 ;
 397
 398 menu_block:
 399           /* empty */
 400         | menu_block common_stmt
 401         | menu_block menu_stmt
 402         | menu_block choice_stmt
 403 ;
 404
 405 source_stmt: T_SOURCE prompt T_EOL
 406 {
 407         printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
 408         zconf_nextfile($2);
 409         free($2);
 410 };
 411
 412 /* comment entry */
 413
 414 comment: T_COMMENT prompt T_EOL
 415 {
 416         menu_add_entry(NULL);
 417         menu_add_prompt(P_COMMENT, $2, NULL);
 418         printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
 419 };
 420
 421 comment_stmt: comment depends_list
 422 ;
 423
 424 /* help option */
 425
 426 help_start: T_HELP T_EOL
 427 {
 428         printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
 429         zconf_starthelp();
 430 };
 431
 432 help: help_start T_HELPTEXT
 433 {
 434         current_entry->help = $2;
 435 };
 436
 437 /* depends option */
 438
 439 depends_list:
 440           /* empty */
 441         | depends_list depends
 442         | depends_list T_EOL
 443         | depends_list option_error
 444 ;
 445
 446 depends: T_DEPENDS T_ON expr T_EOL
 447 {
 448         menu_add_dep($3);
 449         printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
 450 };
 451
 452 /* visibility option */
 453
 454 visibility_list:
 455           /* empty */
 456         | visibility_list visible
 457         | visibility_list T_EOL
 458 ;
 459
 460 visible: T_VISIBLE if_expr
 461 {
 462         menu_add_visibility($2);
 463 };
 464
 465 /* prompt statement */
 466
 467 prompt_stmt_opt:
 468           /* empty */
 469         | prompt if_expr
 470 {
 471         menu_add_prompt(P_PROMPT, $1, $2);
 472 };
 473
 474 prompt:   T_WORD
 475         | T_WORD_QUOTE
 476 ;
 477
 478 end:      T_ENDMENU T_EOL       { $$ = $1; }
 479         | T_ENDCHOICE T_EOL     { $$ = $1; }
 480         | T_ENDIF T_EOL         { $$ = $1; }
 481 ;
 482
 483 nl:
 484           T_EOL
 485         | nl T_EOL
 486 ;
 487
 488 if_expr:  /* empty */                   { $$ = NULL; }
 489         | T_IF expr                     { $$ = $2; }
 490 ;
 491
 492 expr:     symbol                                { $$ = expr_alloc_symbol($1); }
 493         | symbol T_LESS symbol                  { $$ = expr_alloc_comp(E_LTH, $1, $3); }
 494         | symbol T_LESS_EQUAL symbol            { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
 495         | symbol T_GREATER symbol               { $$ = expr_alloc_comp(E_GTH, $1, $3); }
 496         | symbol T_GREATER_EQUAL symbol         { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
 497         | symbol T_EQUAL symbol                 { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
 498         | symbol T_UNEQUAL symbol               { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
 499         | T_OPEN_PAREN expr T_CLOSE_PAREN       { $$ = $2; }
 500         | T_NOT expr                            { $$ = expr_alloc_one(E_NOT, $2); }
 501         | expr T_OR expr                        { $$ = expr_alloc_two(E_OR, $1, $3); }
 502         | expr T_AND expr                       { $$ = expr_alloc_two(E_AND, $1, $3); }
 503 ;
 504
 505 /* For symbol definitions, selects, etc., where quotes are not accepted */
 506 nonconst_symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); };
 507
 508 symbol:   nonconst_symbol
 509         | T_WORD_QUOTE  { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
 510 ;
 511
 512 word_opt: /* empty */                   { $$ = NULL; }
 513         | T_WORD
 514
 515 %%
 516
 517 void conf_parse(const char *name)
 518 {
 519         const char *tmp;
 520         struct symbol *sym;
 521         int i;
 522
 523         zconf_initscan(name);
 524
 525         sym_init();
 526         _menu_init();
 527         rootmenu.prompt = menu_add_prompt(P_MENU, "CARL9170 Firmware Configuration", NULL);
 528
 529         if (getenv("ZCONF_DEBUG"))
 530                 zconfdebug = 1;
 531         zconfparse();
 532         if (zconfnerrs)
 533                 exit(1);
 534         if (!modules_sym)
 535                 modules_sym = sym_find( "n" );
 536
 537         tmp = rootmenu.prompt->text;
 538         rootmenu.prompt->text = _(rootmenu.prompt->text);
 539         rootmenu.prompt->text = sym_expand_string_value(rootmenu.prompt->text);
 540         free((char*)tmp);
 541
 542         menu_finalize(&rootmenu);
 543         for_all_symbols(i, sym) {
 544                 if (sym_check_deps(sym))
 545                         zconfnerrs++;
 546         }
 547         if (zconfnerrs)
 548                 exit(1);
 549         sym_set_change_count(1);
 550 }
 551
 552 static const char *zconf_tokenname(int token)
 553 {
 554         switch (token) {
 555         case T_MENU:            return "menu";
 556         case T_ENDMENU:         return "endmenu";
 557         case T_CHOICE:          return "choice";
 558         case T_ENDCHOICE:       return "endchoice";
 559         case T_IF:              return "if";
 560         case T_ENDIF:           return "endif";
 561         case T_DEPENDS:         return "depends";
 562         case T_VISIBLE:         return "visible";
 563         }
 564         return "<token>";
 565 }
 566
 567 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
 568 {
 569         if (id->token != endtoken) {
 570                 zconf_error("unexpected '%s' within %s block",
 571                         id->name, zconf_tokenname(starttoken));
 572                 zconfnerrs++;
 573                 return false;
 574         }
 575         if (current_menu->file != current_file) {
 576                 zconf_error("'%s' in different file than '%s'",
 577                         id->name, zconf_tokenname(starttoken));
 578                 fprintf(stderr, "%s:%d: location of the '%s'\n",
 579                         current_menu->file->name, current_menu->lineno,
 580                         zconf_tokenname(starttoken));
 581                 zconfnerrs++;
 582                 return false;
 583         }
 584         return true;
 585 }
 586
 587 static void zconfprint(const char *err, ...)
 588 {
 589         va_list ap;
 590
 591         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 592         va_start(ap, err);
 593         vfprintf(stderr, err, ap);
 594         va_end(ap);
 595         fprintf(stderr, "\n");
 596 }
 597
 598 static void zconf_error(const char *err, ...)
 599 {
 600         va_list ap;
 601
 602         zconfnerrs++;
 603         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 604         va_start(ap, err);
 605         vfprintf(stderr, err, ap);
 606         va_end(ap);
 607         fprintf(stderr, "\n");
 608 }
 609
 610 static void zconferror(const char *err)
 611 {
 612         fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
 613 }
 614
 615 static void print_quoted_string(FILE *out, const char *str)
 616 {
 617         const char *p;
 618         int len;
 619
 620         putc('"', out);
 621         while ((p = strchr(str, '"'))) {
 622                 len = p - str;
 623                 if (len)
 624                         fprintf(out, "%.*s", len, str);
 625                 fputs("\\\"", out);
 626                 str = p + 1;
 627         }
 628         fputs(str, out);
 629         putc('"', out);
 630 }
 631
 632 static void print_symbol(FILE *out, struct menu *menu)
 633 {
 634         struct symbol *sym = menu->sym;
 635         struct property *prop;
 636
 637         if (sym_is_choice(sym))
 638                 fprintf(out, "\nchoice\n");
 639         else
 640                 fprintf(out, "\nconfig %s\n", sym->name);
 641         switch (sym->type) {
 642         case S_BOOLEAN:
 643                 fputs("  boolean\n", out);
 644                 break;
 645         case S_TRISTATE:
 646                 fputs("  tristate\n", out);
 647                 break;
 648         case S_STRING:
 649                 fputs("  string\n", out);
 650                 break;
 651         case S_INT:
 652                 fputs("  integer\n", out);
 653                 break;
 654         case S_HEX:
 655                 fputs("  hex\n", out);
 656                 break;
 657         default:
 658                 fputs("  ???\n", out);
 659                 break;
 660         }
 661         for (prop = sym->prop; prop; prop = prop->next) {
 662                 if (prop->menu != menu)
 663                         continue;
 664                 switch (prop->type) {
 665                 case P_PROMPT:
 666                         fputs("  prompt ", out);
 667                         print_quoted_string(out, prop->text);
 668                         if (!expr_is_yes(prop->visible.expr)) {
 669                                 fputs(" if ", out);
 670                                 expr_fprint(prop->visible.expr, out);
 671                         }
 672                         fputc('\n', out);
 673                         break;
 674                 case P_DEFAULT:
 675                         fputs( "  default ", out);
 676                         expr_fprint(prop->expr, out);
 677                         if (!expr_is_yes(prop->visible.expr)) {
 678                                 fputs(" if ", out);
 679                                 expr_fprint(prop->visible.expr, out);
 680                         }
 681                         fputc('\n', out);
 682                         break;
 683                 case P_CHOICE:
 684                         fputs("  #choice value\n", out);
 685                         break;
 686                 case P_SELECT:
 687                         fputs( "  select ", out);
 688                         expr_fprint(prop->expr, out);
 689                         fputc('\n', out);
 690                         break;
 691                 case P_IMPLY:
 692                         fputs( "  imply ", out);
 693                         expr_fprint(prop->expr, out);
 694                         fputc('\n', out);
 695                         break;
 696                 case P_RANGE:
 697                         fputs( "  range ", out);
 698                         expr_fprint(prop->expr, out);
 699                         fputc('\n', out);
 700                         break;
 701                 case P_MENU:
 702                         fputs( "  menu ", out);
 703                         print_quoted_string(out, prop->text);
 704                         fputc('\n', out);
 705                         break;
 706                 default:
 707                         fprintf(out, "  unknown prop %d!\n", prop->type);
 708                         break;
 709                 }
 710         }
 711         if (menu->help) {
 712                 int len = strlen(menu->help);
 713                 while (menu->help[--len] == '\n')
 714                         menu->help[len] = 0;
 715                 fprintf(out, "  help\n%s\n", menu->help);
 716         }
 717 }
 718
 719 void zconfdump(FILE *out)
 720 {
 721         struct property *prop;
 722         struct symbol *sym;
 723         struct menu *menu;
 724
 725         menu = rootmenu.list;
 726         while (menu) {
 727                 if ((sym = menu->sym))
 728                         print_symbol(out, menu);
 729                 else if ((prop = menu->prompt)) {
 730                         switch (prop->type) {
 731                         case P_COMMENT:
 732                                 fputs("\ncomment ", out);
 733                                 print_quoted_string(out, prop->text);
 734                                 fputs("\n", out);
 735                                 break;
 736                         case P_MENU:
 737                                 fputs("\nmenu ", out);
 738                                 print_quoted_string(out, prop->text);
 739                                 fputs("\n", out);
 740                                 break;
 741                         default:
 742                                 ;
 743                         }
 744                         if (!expr_is_yes(prop->visible.expr)) {
 745                                 fputs("  depends ", out);
 746                                 expr_fprint(prop->visible.expr, out);
 747                                 fputc('\n', out);
 748                         }
 749                 }
 750
 751                 if (menu->list)
 752                         menu = menu->list;
 753                 else if (menu->next)
 754                         menu = menu->next;
 755                 else while ((menu = menu->parent)) {
 756                         if (menu->prompt && menu->prompt->type == P_MENU)
 757                                 fputs("\nendmenu\n", out);
 758                         if (menu->next) {
 759                                 menu = menu->next;
 760                                 break;
 761                         }
 762                 }
 763         }
 764 }
 765
 766 #include "zconf.lex.c"
 767 #include "util.c"
 768 #include "confdata.c"
 769 #include "expr.c"
 770 #include "symbol.c"
 771 #include "menu.c"