config/zconf.y

   1 %{
   2 /*
   3  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   4  * Released under the terms of the GNU GPL v2.0.
   5  */
   6
   7 #include <ctype.h>
   8 #include <stdarg.h>
   9 #include <stdio.h>
  10 #include <stdlib.h>
  11 #include <string.h>
  12 #include <stdbool.h>
  13
  14 #include "lkc.h"
  15
  16 #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  17
  18 #define PRINTD          0x0001
  19 #define DEBUG_PARSE     0x0002
  20
  21 int cdebug = PRINTD;
  22
  23 int yylex(void);
  24 static void yyerror(const char *err);
  25 static void zconfprint(const char *err, ...);
  26 static void zconf_error(const char *err, ...);
  27 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);
  28
  29 struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  30
  31 static struct menu *current_menu, *current_entry;
  32
  33 %}
  34
  35 %union
  36 {
  37         char *string;
  38         struct file *file;
  39         struct symbol *symbol;
  40         struct expr *expr;
  41         struct menu *menu;
  42         const struct kconf_id *id;
  43         enum variable_flavor flavor;
  44 }
  45
  46 %token <id>T_MAINMENU
  47 %token <id>T_MENU
  48 %token <id>T_ENDMENU
  49 %token <id>T_SOURCE
  50 %token <id>T_CHOICE
  51 %token <id>T_ENDCHOICE
  52 %token <id>T_COMMENT
  53 %token <id>T_CONFIG
  54 %token <id>T_MENUCONFIG
  55 %token <id>T_HELP
  56 %token <string> T_HELPTEXT
  57 %token <id>T_IF
  58 %token <id>T_ENDIF
  59 %token <id>T_DEPENDS
  60 %token <id>T_OPTIONAL
  61 %token <id>T_PROMPT
  62 %token <id>T_TYPE
  63 %token <id>T_DEFAULT
  64 %token <id>T_SELECT
  65 %token <id>T_IMPLY
  66 %token <id>T_RANGE
  67 %token <id>T_VISIBLE
  68 %token <id>T_OPTION
  69 %token <id>T_ON
  70 %token <string> T_WORD
  71 %token <string> T_WORD_QUOTE
  72 %token T_UNEQUAL
  73 %token T_LESS
  74 %token T_LESS_EQUAL
  75 %token T_GREATER
  76 %token T_GREATER_EQUAL
  77 %token T_CLOSE_PAREN
  78 %token T_OPEN_PAREN
  79 %token T_EOL
  80 %token <string> T_VARIABLE
  81 %token <flavor> T_ASSIGN
  82 %token <string> T_ASSIGN_VAL
  83
  84 %left T_OR
  85 %left T_AND
  86 %left T_EQUAL T_UNEQUAL
  87 %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  88 %nonassoc T_NOT
  89
  90 %type <string> prompt
  91 %type <symbol> nonconst_symbol
  92 %type <symbol> symbol
  93 %type <expr> expr
  94 %type <expr> if_expr
  95 %type <id> end
  96 %type <menu> if_entry menu_entry choice_entry
  97 %type <string> symbol_option_arg word_opt assign_val
  98
  99 %destructor {
 100         fprintf(stderr, "%s:%d: missing end statement for this entry\n",
 101                 $$->file->name, $$->lineno);
 102         if (current_menu == $$)
 103                 menu_end_menu();
 104 } if_entry menu_entry choice_entry
 105
 106 %{
 107 /* Include kconf_id.c here so it can see the token constants. */
 108 #include "kconf_id.c"
 109 %}
 110
 111 %%
 112 input: mainmenu_stmt stmt_list | stmt_list;
 113
 114 /* mainmenu entry */
 115
 116 mainmenu_stmt: T_MAINMENU prompt T_EOL
 117 {
 118         menu_add_prompt(P_MENU, $2, NULL);
 119 };
 120
 121 stmt_list:
 122           /* empty */
 123         | stmt_list common_stmt
 124         | stmt_list choice_stmt
 125         | stmt_list menu_stmt
 126         | stmt_list end                 { zconf_error("unexpected end statement"); }
 127         | stmt_list T_WORD error T_EOL  { zconf_error("unknown statement \"%s\"", $2); }
 128         | stmt_list error T_EOL         { zconf_error("invalid statement"); }
 129 ;
 130
 131 common_stmt:
 132           if_stmt
 133         | comment_stmt
 134         | config_stmt
 135         | menuconfig_stmt
 136         | source_stmt
 137         | assignment_stmt
 138 ;
 139
 140 /* config/menuconfig entry */
 141
 142 config_entry_start: T_CONFIG nonconst_symbol T_EOL
 143 {
 144         $2->flags |= SYMBOL_OPTIONAL;
 145         menu_add_entry($2);
 146         printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2->name);
 147 };
 148
 149 config_stmt: config_entry_start config_option_list
 150 {
 151         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 152 };
 153
 154 menuconfig_entry_start: T_MENUCONFIG nonconst_symbol T_EOL
 155 {
 156         $2->flags |= SYMBOL_OPTIONAL;
 157         menu_add_entry($2);
 158         printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2->name);
 159 };
 160
 161 menuconfig_stmt: menuconfig_entry_start config_option_list
 162 {
 163         if (current_entry->prompt)
 164                 current_entry->prompt->type = P_MENU;
 165         else
 166                 zconfprint("warning: menuconfig statement without prompt");
 167         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 168 };
 169
 170 config_option_list:
 171           /* empty */
 172         | config_option_list config_option
 173         | config_option_list symbol_option
 174         | config_option_list depends
 175         | config_option_list help
 176 ;
 177
 178 config_option: T_TYPE prompt_stmt_opt T_EOL
 179 {
 180         menu_set_type($1->stype);
 181         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 182                 zconf_curname(), zconf_lineno(),
 183                 $1->stype);
 184 };
 185
 186 config_option: T_PROMPT prompt if_expr T_EOL
 187 {
 188         menu_add_prompt(P_PROMPT, $2, $3);
 189         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 190 };
 191
 192 config_option: T_DEFAULT expr if_expr T_EOL
 193 {
 194         menu_add_expr(P_DEFAULT, $2, $3);
 195         if ($1->stype != S_UNKNOWN)
 196                 menu_set_type($1->stype);
 197         printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
 198                 zconf_curname(), zconf_lineno(),
 199                 $1->stype);
 200 };
 201
 202 config_option: T_SELECT nonconst_symbol if_expr T_EOL
 203 {
 204         menu_add_symbol(P_SELECT, $2, $3);
 205         printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
 206 };
 207
 208 config_option: T_IMPLY nonconst_symbol if_expr T_EOL
 209 {
 210         menu_add_symbol(P_IMPLY, $2, $3);
 211         printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
 212 };
 213
 214 config_option: T_RANGE symbol symbol if_expr T_EOL
 215 {
 216         menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
 217         printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
 218 };
 219
 220 symbol_option: T_OPTION symbol_option_list T_EOL
 221 ;
 222
 223 symbol_option_list:
 224           /* empty */
 225         | symbol_option_list T_WORD symbol_option_arg
 226 {
 227         const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
 228         if (id && id->flags & TF_OPTION) {
 229                 menu_add_option(id->token, $3);
 230                 free($3);
 231         }
 232         else
 233                 zconfprint("warning: ignoring unknown option %s", $2);
 234         free($2);
 235 };
 236
 237 symbol_option_arg:
 238           /* empty */           { $$ = NULL; }
 239         | T_EQUAL prompt        { $$ = $2; }
 240 ;
 241
 242 /* choice entry */
 243
 244 choice: T_CHOICE word_opt T_EOL
 245 {
 246         struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
 247         sym->flags |= SYMBOL_NO_WRITE;
 248         menu_add_entry(sym);
 249         menu_add_expr(P_CHOICE, NULL, NULL);
 250         free($2);
 251         printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
 252 };
 253
 254 choice_entry: choice choice_option_list
 255 {
 256         $$ = menu_add_menu();
 257 };
 258
 259 choice_end: end
 260 {
 261         if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
 262                 menu_end_menu();
 263                 printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
 264         }
 265 };
 266
 267 choice_stmt: choice_entry choice_block choice_end
 268 ;
 269
 270 choice_option_list:
 271           /* empty */
 272         | choice_option_list choice_option
 273         | choice_option_list depends
 274         | choice_option_list help
 275 ;
 276
 277 choice_option: T_PROMPT prompt if_expr T_EOL
 278 {
 279         menu_add_prompt(P_PROMPT, $2, $3);
 280         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 281 };
 282
 283 choice_option: T_TYPE prompt_stmt_opt T_EOL
 284 {
 285         if ($1->stype == S_BOOLEAN || $1->stype == S_TRISTATE) {
 286                 menu_set_type($1->stype);
 287                 printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 288                         zconf_curname(), zconf_lineno(),
 289                         $1->stype);
 290         } else
 291                 YYERROR;
 292 };
 293
 294 choice_option: T_OPTIONAL T_EOL
 295 {
 296         current_entry->sym->flags |= SYMBOL_OPTIONAL;
 297         printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
 298 };
 299
 300 choice_option: T_DEFAULT nonconst_symbol if_expr T_EOL
 301 {
 302         if ($1->stype == S_UNKNOWN) {
 303                 menu_add_symbol(P_DEFAULT, $2, $3);
 304                 printd(DEBUG_PARSE, "%s:%d:default\n",
 305                         zconf_curname(), zconf_lineno());
 306         } else
 307                 YYERROR;
 308 };
 309
 310 choice_block:
 311           /* empty */
 312         | choice_block common_stmt
 313 ;
 314
 315 /* if entry */
 316
 317 if_entry: T_IF expr T_EOL
 318 {
 319         printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
 320         menu_add_entry(NULL);
 321         menu_add_dep($2);
 322         $$ = menu_add_menu();
 323 };
 324
 325 if_end: end
 326 {
 327         if (zconf_endtoken($1, T_IF, T_ENDIF)) {
 328                 menu_end_menu();
 329                 printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
 330         }
 331 };
 332
 333 if_stmt: if_entry if_block if_end
 334 ;
 335
 336 if_block:
 337           /* empty */
 338         | if_block common_stmt
 339         | if_block menu_stmt
 340         | if_block choice_stmt
 341 ;
 342
 343 /* menu entry */
 344
 345 menu: T_MENU prompt T_EOL
 346 {
 347         menu_add_entry(NULL);
 348         menu_add_prompt(P_MENU, $2, NULL);
 349         printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
 350 };
 351
 352 menu_entry: menu visibility_list depends_list
 353 {
 354         $$ = menu_add_menu();
 355 };
 356
 357 menu_end: end
 358 {
 359         if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
 360                 menu_end_menu();
 361                 printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
 362         }
 363 };
 364
 365 menu_stmt: menu_entry menu_block menu_end
 366 ;
 367
 368 menu_block:
 369           /* empty */
 370         | menu_block common_stmt
 371         | menu_block menu_stmt
 372         | menu_block choice_stmt
 373 ;
 374
 375 source_stmt: T_SOURCE prompt T_EOL
 376 {
 377         printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
 378         zconf_nextfile($2);
 379         free($2);
 380 };
 381
 382 /* comment entry */
 383
 384 comment: T_COMMENT prompt T_EOL
 385 {
 386         menu_add_entry(NULL);
 387         menu_add_prompt(P_COMMENT, $2, NULL);
 388         printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
 389 };
 390
 391 comment_stmt: comment depends_list
 392 ;
 393
 394 /* help option */
 395
 396 help_start: T_HELP T_EOL
 397 {
 398         printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
 399         zconf_starthelp();
 400 };
 401
 402 help: help_start T_HELPTEXT
 403 {
 404         if (current_entry->help) {
 405                 free(current_entry->help);
 406                 zconfprint("warning: '%s' defined with more than one help text -- only the last one will be used",
 407                            current_entry->sym->name ?: "<choice>");
 408         }
 409
 410         /* Is the help text empty or all whitespace? */
 411         if ($2[strspn($2, " \f\n\r\t\v")] == '\0')
 412                 zconfprint("warning: '%s' defined with blank help text",
 413                            current_entry->sym->name ?: "<choice>");
 414
 415         current_entry->help = $2;
 416 };
 417
 418 /* depends option */
 419
 420 depends_list:
 421           /* empty */
 422         | depends_list depends
 423 ;
 424
 425 depends: T_DEPENDS T_ON expr T_EOL
 426 {
 427         menu_add_dep($3);
 428         printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
 429 };
 430
 431 /* visibility option */
 432
 433 visibility_list:
 434           /* empty */
 435         | visibility_list visible
 436 ;
 437
 438 visible: T_VISIBLE if_expr T_EOL
 439 {
 440         menu_add_visibility($2);
 441 };
 442
 443 /* prompt statement */
 444
 445 prompt_stmt_opt:
 446           /* empty */
 447         | prompt if_expr
 448 {
 449         menu_add_prompt(P_PROMPT, $1, $2);
 450 };
 451
 452 prompt:   T_WORD
 453         | T_WORD_QUOTE
 454 ;
 455
 456 end:      T_ENDMENU T_EOL       { $$ = $1; }
 457         | T_ENDCHOICE T_EOL     { $$ = $1; }
 458         | T_ENDIF T_EOL         { $$ = $1; }
 459 ;
 460
 461 if_expr:  /* empty */                   { $$ = NULL; }
 462         | T_IF expr                     { $$ = $2; }
 463 ;
 464
 465 expr:     symbol                                { $$ = expr_alloc_symbol($1); }
 466         | symbol T_LESS symbol                  { $$ = expr_alloc_comp(E_LTH, $1, $3); }
 467         | symbol T_LESS_EQUAL symbol            { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
 468         | symbol T_GREATER symbol               { $$ = expr_alloc_comp(E_GTH, $1, $3); }
 469         | symbol T_GREATER_EQUAL symbol         { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
 470         | symbol T_EQUAL symbol                 { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
 471         | symbol T_UNEQUAL symbol               { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
 472         | T_OPEN_PAREN expr T_CLOSE_PAREN       { $$ = $2; }
 473         | T_NOT expr                            { $$ = expr_alloc_one(E_NOT, $2); }
 474         | expr T_OR expr                        { $$ = expr_alloc_two(E_OR, $1, $3); }
 475         | expr T_AND expr                       { $$ = expr_alloc_two(E_AND, $1, $3); }
 476 ;
 477
 478 /* For symbol definitions, selects, etc., where quotes are not accepted */
 479 nonconst_symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); };
 480
 481 symbol:   nonconst_symbol
 482         | T_WORD_QUOTE  { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
 483 ;
 484
 485 word_opt: /* empty */                   { $$ = NULL; }
 486         | T_WORD
 487
 488 /* assignment statement */
 489
 490 assignment_stmt:  T_VARIABLE T_ASSIGN assign_val T_EOL  { variable_add($1, $3, $2); free($1); free($3); }
 491
 492 assign_val:
 493         /* empty */             { $$ = xstrdup(""); };
 494         | T_ASSIGN_VAL
 495 ;
 496
 497 %%
 498
 499 void conf_parse(const char *name)
 500 {
 501         struct symbol *sym;
 502         int i;
 503
 504         zconf_initscan(name);
 505
 506         _menu_init();
 507         rootmenu.prompt = menu_add_prompt(P_MENU, "CARL9170 Firmware Configuration", NULL);
 508
 509         if (getenv("ZCONF_DEBUG"))
 510                 yydebug = 1;
 511         yyparse();
 512
 513         /* Variables are expanded in the parse phase. We can free them here. */
 514         variable_all_del();
 515
 516         if (yynerrs)
 517                 exit(1);
 518         if (!modules_sym)
 519                 modules_sym = sym_find( "n" );
 520
 521         if (!menu_has_prompt(&rootmenu)) {
 522                 current_entry = &rootmenu;
 523                 menu_add_prompt(P_MENU, "Main menu", NULL);
 524         }
 525
 526         menu_finalize(&rootmenu);
 527         for_all_symbols(i, sym) {
 528                 if (sym_check_deps(sym))
 529                         yynerrs++;
 530         }
 531         if (yynerrs)
 532                 exit(1);
 533         sym_set_change_count(1);
 534 }
 535
 536 static const char *zconf_tokenname(int token)
 537 {
 538         switch (token) {
 539         case T_MENU:            return "menu";
 540         case T_ENDMENU:         return "endmenu";
 541         case T_CHOICE:          return "choice";
 542         case T_ENDCHOICE:       return "endchoice";
 543         case T_IF:              return "if";
 544         case T_ENDIF:           return "endif";
 545         case T_DEPENDS:         return "depends";
 546         case T_VISIBLE:         return "visible";
 547         }
 548         return "<token>";
 549 }
 550
 551 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
 552 {
 553         if (id->token != endtoken) {
 554                 zconf_error("unexpected '%s' within %s block",
 555                         id->name, zconf_tokenname(starttoken));
 556                 yynerrs++;
 557                 return false;
 558         }
 559         if (current_menu->file != current_file) {
 560                 zconf_error("'%s' in different file than '%s'",
 561                         id->name, zconf_tokenname(starttoken));
 562                 fprintf(stderr, "%s:%d: location of the '%s'\n",
 563                         current_menu->file->name, current_menu->lineno,
 564                         zconf_tokenname(starttoken));
 565                 yynerrs++;
 566                 return false;
 567         }
 568         return true;
 569 }
 570
 571 static void zconfprint(const char *err, ...)
 572 {
 573         va_list ap;
 574
 575         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 576         va_start(ap, err);
 577         vfprintf(stderr, err, ap);
 578         va_end(ap);
 579         fprintf(stderr, "\n");
 580 }
 581
 582 static void zconf_error(const char *err, ...)
 583 {
 584         va_list ap;
 585
 586         yynerrs++;
 587         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 588         va_start(ap, err);
 589         vfprintf(stderr, err, ap);
 590         va_end(ap);
 591         fprintf(stderr, "\n");
 592 }
 593
 594 static void yyerror(const char *err)
 595 {
 596         fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
 597 }
 598
 599 static void print_quoted_string(FILE *out, const char *str)
 600 {
 601         const char *p;
 602         int len;
 603
 604         putc('"', out);
 605         while ((p = strchr(str, '"'))) {
 606                 len = p - str;
 607                 if (len)
 608                         fprintf(out, "%.*s", len, str);
 609                 fputs("\\\"", out);
 610                 str = p + 1;
 611         }
 612         fputs(str, out);
 613         putc('"', out);
 614 }
 615
 616 static void print_symbol(FILE *out, struct menu *menu)
 617 {
 618         struct symbol *sym = menu->sym;
 619         struct property *prop;
 620
 621         if (sym_is_choice(sym))
 622                 fprintf(out, "\nchoice\n");
 623         else
 624                 fprintf(out, "\nconfig %s\n", sym->name);
 625         switch (sym->type) {
 626         case S_BOOLEAN:
 627                 fputs("  bool\n", out);
 628                 break;
 629         case S_TRISTATE:
 630                 fputs("  tristate\n", out);
 631                 break;
 632         case S_STRING:
 633                 fputs("  string\n", out);
 634                 break;
 635         case S_INT:
 636                 fputs("  integer\n", out);
 637                 break;
 638         case S_HEX:
 639                 fputs("  hex\n", out);
 640                 break;
 641         default:
 642                 fputs("  ???\n", out);
 643                 break;
 644         }
 645         for (prop = sym->prop; prop; prop = prop->next) {
 646                 if (prop->menu != menu)
 647                         continue;
 648                 switch (prop->type) {
 649                 case P_PROMPT:
 650                         fputs("  prompt ", out);
 651                         print_quoted_string(out, prop->text);
 652                         if (!expr_is_yes(prop->visible.expr)) {
 653                                 fputs(" if ", out);
 654                                 expr_fprint(prop->visible.expr, out);
 655                         }
 656                         fputc('\n', out);
 657                         break;
 658                 case P_DEFAULT:
 659                         fputs( "  default ", out);
 660                         expr_fprint(prop->expr, out);
 661                         if (!expr_is_yes(prop->visible.expr)) {
 662                                 fputs(" if ", out);
 663                                 expr_fprint(prop->visible.expr, out);
 664                         }
 665                         fputc('\n', out);
 666                         break;
 667                 case P_CHOICE:
 668                         fputs("  #choice value\n", out);
 669                         break;
 670                 case P_SELECT:
 671                         fputs( "  select ", out);
 672                         expr_fprint(prop->expr, out);
 673                         fputc('\n', out);
 674                         break;
 675                 case P_IMPLY:
 676                         fputs( "  imply ", out);
 677                         expr_fprint(prop->expr, out);
 678                         fputc('\n', out);
 679                         break;
 680                 case P_RANGE:
 681                         fputs( "  range ", out);
 682                         expr_fprint(prop->expr, out);
 683                         fputc('\n', out);
 684                         break;
 685                 case P_MENU:
 686                         fputs( "  menu ", out);
 687                         print_quoted_string(out, prop->text);
 688                         fputc('\n', out);
 689                         break;
 690                 case P_SYMBOL:
 691                         fputs( "  symbol ", out);
 692                         fprintf(out, "%s\n", prop->sym->name);
 693                         break;
 694                 default:
 695                         fprintf(out, "  unknown prop %d!\n", prop->type);
 696                         break;
 697                 }
 698         }
 699         if (menu->help) {
 700                 int len = strlen(menu->help);
 701                 while (menu->help[--len] == '\n')
 702                         menu->help[len] = 0;
 703                 fprintf(out, "  help\n%s\n", menu->help);
 704         }
 705 }
 706
 707 void zconfdump(FILE *out)
 708 {
 709         struct property *prop;
 710         struct symbol *sym;
 711         struct menu *menu;
 712
 713         menu = rootmenu.list;
 714         while (menu) {
 715                 if ((sym = menu->sym))
 716                         print_symbol(out, menu);
 717                 else if ((prop = menu->prompt)) {
 718                         switch (prop->type) {
 719                         case P_COMMENT:
 720                                 fputs("\ncomment ", out);
 721                                 print_quoted_string(out, prop->text);
 722                                 fputs("\n", out);
 723                                 break;
 724                         case P_MENU:
 725                                 fputs("\nmenu ", out);
 726                                 print_quoted_string(out, prop->text);
 727                                 fputs("\n", out);
 728                                 break;
 729                         default:
 730                                 ;
 731                         }
 732                         if (!expr_is_yes(prop->visible.expr)) {
 733                                 fputs("  depends ", out);
 734                                 expr_fprint(prop->visible.expr, out);
 735                                 fputc('\n', out);
 736                         }
 737                 }
 738
 739                 if (menu->list)
 740                         menu = menu->list;
 741                 else if (menu->next)
 742                         menu = menu->next;
 743                 else while ((menu = menu->parent)) {
 744                         if (menu->prompt && menu->prompt->type == P_MENU)
 745                                 fputs("\nendmenu\n", out);
 746                         if (menu->next) {
 747                                 menu = menu->next;
 748                                 break;
 749                         }
 750                 }
 751         }
 752 }
 753
 754 #include "zconf.lex.c"
 755 #include "util.c"
 756 #include "confdata.c"
 757 #include "expr.c"
 758 #include "symbol.c"
 759 #include "menu.c"
 760 #include "preprocess.c"