config/zconf.y

   1 %{
   2 /*
   3  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   4  * Released under the terms of the GNU GPL v2.0.
   5  */
   6
   7 #include <ctype.h>
   8 #include <stdarg.h>
   9 #include <stdio.h>
  10 #include <stdlib.h>
  11 #include <string.h>
  12 #include <stdbool.h>
  13
  14 #include "lkc.h"
  15
  16 #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  17
  18 #define PRINTD          0x0001
  19 #define DEBUG_PARSE     0x0002
  20
  21 int cdebug = PRINTD;
  22
  23 int yylex(void);
  24 static void yyerror(const char *err);
  25 static void zconfprint(const char *err, ...);
  26 static void zconf_error(const char *err, ...);
  27 static bool zconf_endtoken(const char *tokenname,
  28                            const char *expected_tokenname);
  29
  30 struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  31
  32 static struct menu *current_menu, *current_entry;
  33
  34 %}
  35
  36 %union
  37 {
  38         char *string;
  39         struct file *file;
  40         struct symbol *symbol;
  41         struct expr *expr;
  42         struct menu *menu;
  43         const struct kconf_id *id;
  44         enum symbol_type type;
  45         enum variable_flavor flavor;
  46 }
  47
  48 %token <id>T_MAINMENU
  49 %token <id>T_MENU
  50 %token <id>T_ENDMENU
  51 %token <id>T_SOURCE
  52 %token <id>T_CHOICE
  53 %token <id>T_ENDCHOICE
  54 %token <id>T_COMMENT
  55 %token <id>T_CONFIG
  56 %token <id>T_MENUCONFIG
  57 %token <id>T_HELP
  58 %token <string> T_HELPTEXT
  59 %token <id>T_IF
  60 %token <id>T_ENDIF
  61 %token <id>T_DEPENDS
  62 %token <id>T_OPTIONAL
  63 %token <id>T_PROMPT
  64 %token <id>T_SELECT
  65 %token <id>T_IMPLY
  66 %token <id>T_RANGE
  67 %token <id>T_VISIBLE
  68 %token <id>T_ON
  69 %token <string> T_WORD
  70 %token <string> T_WORD_QUOTE
  71 %token T_ALLNOCONFIG_Y
  72 %token T_BOOL
  73 %token T_CLOSE_PAREN
  74 %token T_COLON_EQUAL
  75 %token T_DEFAULT
  76 %token T_DEFCONFIG_LIST
  77 %token T_DEF_BOOL
  78 %token T_DEF_TRISTATE
  79 %token T_HEX
  80 %token T_INT
  81 %token T_MODULES
  82 %token T_OPEN_PAREN
  83 %token T_OPTION
  84 %token T_PLUS_EQUAL
  85 %token T_STRING
  86 %token T_TRISTATE
  87 %token T_EOL
  88 %token <string> T_ASSIGN_VAL
  89
  90 %left T_OR
  91 %left T_AND
  92 %left T_EQUAL T_UNEQUAL
  93 %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  94 %nonassoc T_NOT
  95
  96 %type <string> prompt
  97 %type <symbol> nonconst_symbol
  98 %type <symbol> symbol
  99 %type <type> type logic_type default
 100 %type <expr> expr
 101 %type <expr> if_expr
 102 %type <string> end
 103 %type <menu> if_entry menu_entry choice_entry
 104 %type <string> word_opt assign_val
 105 %type <flavor> assign_op
 106
 107 %destructor {
 108         fprintf(stderr, "%s:%d: missing end statement for this entry\n",
 109                 $$->file->name, $$->lineno);
 110         if (current_menu == $$)
 111                 menu_end_menu();
 112 } if_entry menu_entry choice_entry
 113
 114 %{
 115 /* Include kconf_id.c here so it can see the token constants. */
 116 #include "kconf_id.c"
 117 %}
 118
 119 %%
 120 input: mainmenu_stmt stmt_list | stmt_list;
 121
 122 /* mainmenu entry */
 123
 124 mainmenu_stmt: T_MAINMENU prompt T_EOL
 125 {
 126         menu_add_prompt(P_MENU, $2, NULL);
 127 };
 128
 129 stmt_list:
 130           /* empty */
 131         | stmt_list common_stmt
 132         | stmt_list choice_stmt
 133         | stmt_list menu_stmt
 134         | stmt_list T_WORD error T_EOL  { zconf_error("unknown statement \"%s\"", $2); }
 135         | stmt_list error T_EOL         { zconf_error("invalid statement"); }
 136 ;
 137
 138 common_stmt:
 139           if_stmt
 140         | comment_stmt
 141         | config_stmt
 142         | menuconfig_stmt
 143         | source_stmt
 144         | assignment_stmt
 145 ;
 146
 147 /* config/menuconfig entry */
 148
 149 config_entry_start: T_CONFIG nonconst_symbol T_EOL
 150 {
 151         $2->flags |= SYMBOL_OPTIONAL;
 152         menu_add_entry($2);
 153         printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2->name);
 154 };
 155
 156 config_stmt: config_entry_start config_option_list
 157 {
 158         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 159 };
 160
 161 menuconfig_entry_start: T_MENUCONFIG nonconst_symbol T_EOL
 162 {
 163         $2->flags |= SYMBOL_OPTIONAL;
 164         menu_add_entry($2);
 165         printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2->name);
 166 };
 167
 168 menuconfig_stmt: menuconfig_entry_start config_option_list
 169 {
 170         if (current_entry->prompt)
 171                 current_entry->prompt->type = P_MENU;
 172         else
 173                 zconfprint("warning: menuconfig statement without prompt");
 174         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 175 };
 176
 177 config_option_list:
 178           /* empty */
 179         | config_option_list config_option
 180         | config_option_list depends
 181         | config_option_list help
 182 ;
 183
 184 config_option: type prompt_stmt_opt T_EOL
 185 {
 186         menu_set_type($1);
 187         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 188                 zconf_curname(), zconf_lineno(),
 189                 $1);
 190 };
 191
 192 config_option: T_PROMPT prompt if_expr T_EOL
 193 {
 194         menu_add_prompt(P_PROMPT, $2, $3);
 195         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 196 };
 197
 198 config_option: default expr if_expr T_EOL
 199 {
 200         menu_add_expr(P_DEFAULT, $2, $3);
 201         if ($1 != S_UNKNOWN)
 202                 menu_set_type($1);
 203         printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
 204                 zconf_curname(), zconf_lineno(),
 205                 $1);
 206 };
 207
 208 config_option: T_SELECT nonconst_symbol if_expr T_EOL
 209 {
 210         menu_add_symbol(P_SELECT, $2, $3);
 211         printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
 212 };
 213
 214 config_option: T_IMPLY nonconst_symbol if_expr T_EOL
 215 {
 216         menu_add_symbol(P_IMPLY, $2, $3);
 217         printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
 218 };
 219
 220 config_option: T_RANGE symbol symbol if_expr T_EOL
 221 {
 222         menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
 223         printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
 224 };
 225
 226 config_option: T_OPTION T_MODULES T_EOL
 227 {
 228         menu_add_option_modules();
 229 };
 230
 231 config_option: T_OPTION T_DEFCONFIG_LIST T_EOL
 232 {
 233         menu_add_option_defconfig_list();
 234 };
 235
 236 config_option: T_OPTION T_ALLNOCONFIG_Y T_EOL
 237 {
 238         menu_add_option_allnoconfig_y();
 239 };
 240
 241 /* choice entry */
 242
 243 choice: T_CHOICE word_opt T_EOL
 244 {
 245         struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
 246         sym->flags |= SYMBOL_NO_WRITE;
 247         menu_add_entry(sym);
 248         menu_add_expr(P_CHOICE, NULL, NULL);
 249         free($2);
 250         printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
 251 };
 252
 253 choice_entry: choice choice_option_list
 254 {
 255         $$ = menu_add_menu();
 256 };
 257
 258 choice_end: end
 259 {
 260         if (zconf_endtoken($1, "choice")) {
 261                 menu_end_menu();
 262                 printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
 263         }
 264 };
 265
 266 choice_stmt: choice_entry choice_block choice_end
 267 ;
 268
 269 choice_option_list:
 270           /* empty */
 271         | choice_option_list choice_option
 272         | choice_option_list depends
 273         | choice_option_list help
 274 ;
 275
 276 choice_option: T_PROMPT prompt if_expr T_EOL
 277 {
 278         menu_add_prompt(P_PROMPT, $2, $3);
 279         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 280 };
 281
 282 choice_option: logic_type prompt_stmt_opt T_EOL
 283 {
 284         menu_set_type($1);
 285         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 286                zconf_curname(), zconf_lineno(), $1);
 287 };
 288
 289 choice_option: T_OPTIONAL T_EOL
 290 {
 291         current_entry->sym->flags |= SYMBOL_OPTIONAL;
 292         printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
 293 };
 294
 295 choice_option: T_DEFAULT nonconst_symbol if_expr T_EOL
 296 {
 297         menu_add_symbol(P_DEFAULT, $2, $3);
 298         printd(DEBUG_PARSE, "%s:%d:default\n",
 299                zconf_curname(), zconf_lineno());
 300 };
 301
 302 type:
 303           logic_type
 304         | T_INT                 { $$ = S_INT; }
 305         | T_HEX                 { $$ = S_HEX; }
 306         | T_STRING              { $$ = S_STRING; }
 307
 308 logic_type:
 309           T_BOOL                { $$ = S_BOOLEAN; }
 310         | T_TRISTATE            { $$ = S_TRISTATE; }
 311
 312 default:
 313           T_DEFAULT             { $$ = S_UNKNOWN; }
 314         | T_DEF_BOOL            { $$ = S_BOOLEAN; }
 315         | T_DEF_TRISTATE        { $$ = S_TRISTATE; }
 316
 317 choice_block:
 318           /* empty */
 319         | choice_block common_stmt
 320 ;
 321
 322 /* if entry */
 323
 324 if_entry: T_IF expr T_EOL
 325 {
 326         printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
 327         menu_add_entry(NULL);
 328         menu_add_dep($2);
 329         $$ = menu_add_menu();
 330 };
 331
 332 if_end: end
 333 {
 334         if (zconf_endtoken($1, "if")) {
 335                 menu_end_menu();
 336                 printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
 337         }
 338 };
 339
 340 if_stmt: if_entry stmt_list if_end
 341 ;
 342
 343 /* menu entry */
 344
 345 menu: T_MENU prompt T_EOL
 346 {
 347         menu_add_entry(NULL);
 348         menu_add_prompt(P_MENU, $2, NULL);
 349         printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
 350 };
 351
 352 menu_entry: menu menu_option_list
 353 {
 354         $$ = menu_add_menu();
 355 };
 356
 357 menu_end: end
 358 {
 359         if (zconf_endtoken($1, "menu")) {
 360                 menu_end_menu();
 361                 printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
 362         }
 363 };
 364
 365 menu_stmt: menu_entry stmt_list menu_end
 366 ;
 367
 368 menu_option_list:
 369           /* empty */
 370         | menu_option_list visible
 371         | menu_option_list depends
 372 ;
 373
 374 source_stmt: T_SOURCE prompt T_EOL
 375 {
 376         printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
 377         zconf_nextfile($2);
 378         free($2);
 379 };
 380
 381 /* comment entry */
 382
 383 comment: T_COMMENT prompt T_EOL
 384 {
 385         menu_add_entry(NULL);
 386         menu_add_prompt(P_COMMENT, $2, NULL);
 387         printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
 388 };
 389
 390 comment_stmt: comment comment_option_list
 391 ;
 392
 393 comment_option_list:
 394           /* empty */
 395         | comment_option_list depends
 396 ;
 397
 398 /* help option */
 399
 400 help_start: T_HELP T_EOL
 401 {
 402         printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
 403         zconf_starthelp();
 404 };
 405
 406 help: help_start T_HELPTEXT
 407 {
 408         if (current_entry->help) {
 409                 free(current_entry->help);
 410                 zconfprint("warning: '%s' defined with more than one help text -- only the last one will be used",
 411                            current_entry->sym->name ?: "<choice>");
 412         }
 413
 414         /* Is the help text empty or all whitespace? */
 415         if ($2[strspn($2, " \f\n\r\t\v")] == '\0')
 416                 zconfprint("warning: '%s' defined with blank help text",
 417                            current_entry->sym->name ?: "<choice>");
 418
 419         current_entry->help = $2;
 420 };
 421
 422 /* depends option */
 423
 424 depends: T_DEPENDS T_ON expr T_EOL
 425 {
 426         menu_add_dep($3);
 427         printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
 428 };
 429
 430 /* visibility option */
 431 visible: T_VISIBLE if_expr T_EOL
 432 {
 433         menu_add_visibility($2);
 434 };
 435
 436 /* prompt statement */
 437
 438 prompt_stmt_opt:
 439           /* empty */
 440         | prompt if_expr
 441 {
 442         menu_add_prompt(P_PROMPT, $1, $2);
 443 };
 444
 445 prompt:   T_WORD
 446         | T_WORD_QUOTE
 447 ;
 448
 449 end:      T_ENDMENU T_EOL       { $$ = "menu"; }
 450         | T_ENDCHOICE T_EOL     { $$ = "choice"; }
 451         | T_ENDIF T_EOL         { $$ = "if"; }
 452 ;
 453
 454 if_expr:  /* empty */                   { $$ = NULL; }
 455         | T_IF expr                     { $$ = $2; }
 456 ;
 457
 458 expr:     symbol                                { $$ = expr_alloc_symbol($1); }
 459         | symbol T_LESS symbol                  { $$ = expr_alloc_comp(E_LTH, $1, $3); }
 460         | symbol T_LESS_EQUAL symbol            { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
 461         | symbol T_GREATER symbol               { $$ = expr_alloc_comp(E_GTH, $1, $3); }
 462         | symbol T_GREATER_EQUAL symbol         { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
 463         | symbol T_EQUAL symbol                 { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
 464         | symbol T_UNEQUAL symbol               { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
 465         | T_OPEN_PAREN expr T_CLOSE_PAREN       { $$ = $2; }
 466         | T_NOT expr                            { $$ = expr_alloc_one(E_NOT, $2); }
 467         | expr T_OR expr                        { $$ = expr_alloc_two(E_OR, $1, $3); }
 468         | expr T_AND expr                       { $$ = expr_alloc_two(E_AND, $1, $3); }
 469 ;
 470
 471 /* For symbol definitions, selects, etc., where quotes are not accepted */
 472 nonconst_symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); };
 473
 474 symbol:   nonconst_symbol
 475         | T_WORD_QUOTE  { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
 476 ;
 477
 478 word_opt: /* empty */                   { $$ = NULL; }
 479         | T_WORD
 480
 481 /* assignment statement */
 482
 483 assignment_stmt:  T_WORD assign_op assign_val T_EOL     { variable_add($1, $3, $2); free($1); free($3); }
 484
 485 assign_op:
 486           T_EQUAL       { $$ = VAR_RECURSIVE; }
 487         | T_COLON_EQUAL { $$ = VAR_SIMPLE; }
 488         | T_PLUS_EQUAL  { $$ = VAR_APPEND; }
 489 ;
 490
 491 assign_val:
 492         /* empty */             { $$ = xstrdup(""); };
 493         | T_ASSIGN_VAL
 494 ;
 495
 496 %%
 497
 498 void conf_parse(const char *name)
 499 {
 500         struct symbol *sym;
 501         int i;
 502
 503         zconf_initscan(name);
 504
 505         _menu_init();
 506         rootmenu.prompt = menu_add_prompt(P_MENU, "CARL9170 Firmware Configuration", NULL);
 507
 508         if (getenv("ZCONF_DEBUG"))
 509                 yydebug = 1;
 510         yyparse();
 511
 512         /* Variables are expanded in the parse phase. We can free them here. */
 513         variable_all_del();
 514
 515         if (yynerrs)
 516                 exit(1);
 517         if (!modules_sym)
 518                 modules_sym = sym_find( "n" );
 519
 520         if (!menu_has_prompt(&rootmenu)) {
 521                 current_entry = &rootmenu;
 522                 menu_add_prompt(P_MENU, "Main menu", NULL);
 523         }
 524
 525         menu_finalize(&rootmenu);
 526         for_all_symbols(i, sym) {
 527                 if (sym_check_deps(sym))
 528                         yynerrs++;
 529         }
 530         if (yynerrs)
 531                 exit(1);
 532         sym_set_change_count(1);
 533 }
 534
 535 static bool zconf_endtoken(const char *tokenname,
 536                            const char *expected_tokenname)
 537 {
 538         if (strcmp(tokenname, expected_tokenname)) {
 539                 zconf_error("unexpected '%s' within %s block",
 540                             tokenname, expected_tokenname);
 541                 yynerrs++;
 542                 return false;
 543         }
 544         if (current_menu->file != current_file) {
 545                 zconf_error("'%s' in different file than '%s'",
 546                             tokenname, expected_tokenname);
 547                 fprintf(stderr, "%s:%d: location of the '%s'\n",
 548                         current_menu->file->name, current_menu->lineno,
 549                         expected_tokenname);
 550                 yynerrs++;
 551                 return false;
 552         }
 553         return true;
 554 }
 555
 556 static void zconfprint(const char *err, ...)
 557 {
 558         va_list ap;
 559
 560         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 561         va_start(ap, err);
 562         vfprintf(stderr, err, ap);
 563         va_end(ap);
 564         fprintf(stderr, "\n");
 565 }
 566
 567 static void zconf_error(const char *err, ...)
 568 {
 569         va_list ap;
 570
 571         yynerrs++;
 572         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 573         va_start(ap, err);
 574         vfprintf(stderr, err, ap);
 575         va_end(ap);
 576         fprintf(stderr, "\n");
 577 }
 578
 579 static void yyerror(const char *err)
 580 {
 581         fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
 582 }
 583
 584 static void print_quoted_string(FILE *out, const char *str)
 585 {
 586         const char *p;
 587         int len;
 588
 589         putc('"', out);
 590         while ((p = strchr(str, '"'))) {
 591                 len = p - str;
 592                 if (len)
 593                         fprintf(out, "%.*s", len, str);
 594                 fputs("\\\"", out);
 595                 str = p + 1;
 596         }
 597         fputs(str, out);
 598         putc('"', out);
 599 }
 600
 601 static void print_symbol(FILE *out, struct menu *menu)
 602 {
 603         struct symbol *sym = menu->sym;
 604         struct property *prop;
 605
 606         if (sym_is_choice(sym))
 607                 fprintf(out, "\nchoice\n");
 608         else
 609                 fprintf(out, "\nconfig %s\n", sym->name);
 610         switch (sym->type) {
 611         case S_BOOLEAN:
 612                 fputs("  bool\n", out);
 613                 break;
 614         case S_TRISTATE:
 615                 fputs("  tristate\n", out);
 616                 break;
 617         case S_STRING:
 618                 fputs("  string\n", out);
 619                 break;
 620         case S_INT:
 621                 fputs("  integer\n", out);
 622                 break;
 623         case S_HEX:
 624                 fputs("  hex\n", out);
 625                 break;
 626         default:
 627                 fputs("  ???\n", out);
 628                 break;
 629         }
 630         for (prop = sym->prop; prop; prop = prop->next) {
 631                 if (prop->menu != menu)
 632                         continue;
 633                 switch (prop->type) {
 634                 case P_PROMPT:
 635                         fputs("  prompt ", out);
 636                         print_quoted_string(out, prop->text);
 637                         if (!expr_is_yes(prop->visible.expr)) {
 638                                 fputs(" if ", out);
 639                                 expr_fprint(prop->visible.expr, out);
 640                         }
 641                         fputc('\n', out);
 642                         break;
 643                 case P_DEFAULT:
 644                         fputs( "  default ", out);
 645                         expr_fprint(prop->expr, out);
 646                         if (!expr_is_yes(prop->visible.expr)) {
 647                                 fputs(" if ", out);
 648                                 expr_fprint(prop->visible.expr, out);
 649                         }
 650                         fputc('\n', out);
 651                         break;
 652                 case P_CHOICE:
 653                         fputs("  #choice value\n", out);
 654                         break;
 655                 case P_SELECT:
 656                         fputs( "  select ", out);
 657                         expr_fprint(prop->expr, out);
 658                         fputc('\n', out);
 659                         break;
 660                 case P_IMPLY:
 661                         fputs( "  imply ", out);
 662                         expr_fprint(prop->expr, out);
 663                         fputc('\n', out);
 664                         break;
 665                 case P_RANGE:
 666                         fputs( "  range ", out);
 667                         expr_fprint(prop->expr, out);
 668                         fputc('\n', out);
 669                         break;
 670                 case P_MENU:
 671                         fputs( "  menu ", out);
 672                         print_quoted_string(out, prop->text);
 673                         fputc('\n', out);
 674                         break;
 675                 case P_SYMBOL:
 676                         fputs( "  symbol ", out);
 677                         fprintf(out, "%s\n", prop->sym->name);
 678                         break;
 679                 default:
 680                         fprintf(out, "  unknown prop %d!\n", prop->type);
 681                         break;
 682                 }
 683         }
 684         if (menu->help) {
 685                 int len = strlen(menu->help);
 686                 while (menu->help[--len] == '\n')
 687                         menu->help[len] = 0;
 688                 fprintf(out, "  help\n%s\n", menu->help);
 689         }
 690 }
 691
 692 void zconfdump(FILE *out)
 693 {
 694         struct property *prop;
 695         struct symbol *sym;
 696         struct menu *menu;
 697
 698         menu = rootmenu.list;
 699         while (menu) {
 700                 if ((sym = menu->sym))
 701                         print_symbol(out, menu);
 702                 else if ((prop = menu->prompt)) {
 703                         switch (prop->type) {
 704                         case P_COMMENT:
 705                                 fputs("\ncomment ", out);
 706                                 print_quoted_string(out, prop->text);
 707                                 fputs("\n", out);
 708                                 break;
 709                         case P_MENU:
 710                                 fputs("\nmenu ", out);
 711                                 print_quoted_string(out, prop->text);
 712                                 fputs("\n", out);
 713                                 break;
 714                         default:
 715                                 ;
 716                         }
 717                         if (!expr_is_yes(prop->visible.expr)) {
 718                                 fputs("  depends ", out);
 719                                 expr_fprint(prop->visible.expr, out);
 720                                 fputc('\n', out);
 721                         }
 722                 }
 723
 724                 if (menu->list)
 725                         menu = menu->list;
 726                 else if (menu->next)
 727                         menu = menu->next;
 728                 else while ((menu = menu->parent)) {
 729                         if (menu->prompt && menu->prompt->type == P_MENU)
 730                                 fputs("\nendmenu\n", out);
 731                         if (menu->next) {
 732                                 menu = menu->next;
 733                                 break;
 734                         }
 735                 }
 736         }
 737 }
 738
 739 #include "zconf.lex.c"
 740 #include "util.c"
 741 #include "confdata.c"
 742 #include "expr.c"
 743 #include "symbol.c"
 744 #include "menu.c"
 745 #include "preprocess.c"