config/zconf.y

   1 %{
   2 /*
   3  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   4  * Released under the terms of the GNU GPL v2.0.
   5  */
   6
   7 #include <ctype.h>
   8 #include <stdarg.h>
   9 #include <stdio.h>
  10 #include <stdlib.h>
  11 #include <string.h>
  12 #include <stdbool.h>
  13
  14 #include "lkc.h"
  15
  16 #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  17
  18 #define PRINTD          0x0001
  19 #define DEBUG_PARSE     0x0002
  20
  21 int cdebug = PRINTD;
  22
  23 int yylex(void);
  24 static void yyerror(const char *err);
  25 static void zconfprint(const char *err, ...);
  26 static void zconf_error(const char *err, ...);
  27 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);
  28
  29 struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  30
  31 static struct menu *current_menu, *current_entry;
  32
  33 %}
  34 %expect 6
  35
  36 %union
  37 {
  38         char *string;
  39         struct file *file;
  40         struct symbol *symbol;
  41         struct expr *expr;
  42         struct menu *menu;
  43         const struct kconf_id *id;
  44         enum variable_flavor flavor;
  45 }
  46
  47 %token <id>T_MAINMENU
  48 %token <id>T_MENU
  49 %token <id>T_ENDMENU
  50 %token <id>T_SOURCE
  51 %token <id>T_CHOICE
  52 %token <id>T_ENDCHOICE
  53 %token <id>T_COMMENT
  54 %token <id>T_CONFIG
  55 %token <id>T_MENUCONFIG
  56 %token <id>T_HELP
  57 %token <string> T_HELPTEXT
  58 %token <id>T_IF
  59 %token <id>T_ENDIF
  60 %token <id>T_DEPENDS
  61 %token <id>T_OPTIONAL
  62 %token <id>T_PROMPT
  63 %token <id>T_TYPE
  64 %token <id>T_DEFAULT
  65 %token <id>T_SELECT
  66 %token <id>T_IMPLY
  67 %token <id>T_RANGE
  68 %token <id>T_VISIBLE
  69 %token <id>T_OPTION
  70 %token <id>T_ON
  71 %token <string> T_WORD
  72 %token <string> T_WORD_QUOTE
  73 %token T_UNEQUAL
  74 %token T_LESS
  75 %token T_LESS_EQUAL
  76 %token T_GREATER
  77 %token T_GREATER_EQUAL
  78 %token T_CLOSE_PAREN
  79 %token T_OPEN_PAREN
  80 %token T_EOL
  81 %token <string> T_VARIABLE
  82 %token <flavor> T_ASSIGN
  83 %token <string> T_ASSIGN_VAL
  84
  85 %left T_OR
  86 %left T_AND
  87 %left T_EQUAL T_UNEQUAL
  88 %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  89 %nonassoc T_NOT
  90
  91 %type <string> prompt
  92 %type <symbol> nonconst_symbol
  93 %type <symbol> symbol
  94 %type <expr> expr
  95 %type <expr> if_expr
  96 %type <id> end
  97 %type <menu> if_entry menu_entry choice_entry
  98 %type <string> symbol_option_arg word_opt assign_val
  99
 100 %destructor {
 101         fprintf(stderr, "%s:%d: missing end statement for this entry\n",
 102                 $$->file->name, $$->lineno);
 103         if (current_menu == $$)
 104                 menu_end_menu();
 105 } if_entry menu_entry choice_entry
 106
 107 %{
 108 /* Include kconf_id.c here so it can see the token constants. */
 109 #include "kconf_id.c"
 110 %}
 111
 112 %%
 113 input: mainmenu_stmt stmt_list | stmt_list;
 114
 115 /* mainmenu entry */
 116
 117 mainmenu_stmt: T_MAINMENU prompt T_EOL
 118 {
 119         menu_add_prompt(P_MENU, $2, NULL);
 120 };
 121
 122 stmt_list:
 123           /* empty */
 124         | stmt_list common_stmt
 125         | stmt_list choice_stmt
 126         | stmt_list menu_stmt
 127         | stmt_list end                 { zconf_error("unexpected end statement"); }
 128         | stmt_list T_WORD error T_EOL  { zconf_error("unknown statement \"%s\"", $2); }
 129         | stmt_list error T_EOL         { zconf_error("invalid statement"); }
 130 ;
 131
 132 common_stmt:
 133           if_stmt
 134         | comment_stmt
 135         | config_stmt
 136         | menuconfig_stmt
 137         | source_stmt
 138         | assignment_stmt
 139 ;
 140
 141 option_error:
 142           T_WORD error T_EOL            { zconf_error("unknown option \"%s\"", $1); }
 143         | error T_EOL                   { zconf_error("invalid option"); }
 144 ;
 145
 146
 147 /* config/menuconfig entry */
 148
 149 config_entry_start: T_CONFIG nonconst_symbol T_EOL
 150 {
 151         $2->flags |= SYMBOL_OPTIONAL;
 152         menu_add_entry($2);
 153         printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2->name);
 154 };
 155
 156 config_stmt: config_entry_start config_option_list
 157 {
 158         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 159 };
 160
 161 menuconfig_entry_start: T_MENUCONFIG nonconst_symbol T_EOL
 162 {
 163         $2->flags |= SYMBOL_OPTIONAL;
 164         menu_add_entry($2);
 165         printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2->name);
 166 };
 167
 168 menuconfig_stmt: menuconfig_entry_start config_option_list
 169 {
 170         if (current_entry->prompt)
 171                 current_entry->prompt->type = P_MENU;
 172         else
 173                 zconfprint("warning: menuconfig statement without prompt");
 174         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 175 };
 176
 177 config_option_list:
 178           /* empty */
 179         | config_option_list config_option
 180         | config_option_list symbol_option
 181         | config_option_list depends
 182         | config_option_list help
 183         | config_option_list option_error
 184 ;
 185
 186 config_option: T_TYPE prompt_stmt_opt T_EOL
 187 {
 188         menu_set_type($1->stype);
 189         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 190                 zconf_curname(), zconf_lineno(),
 191                 $1->stype);
 192 };
 193
 194 config_option: T_PROMPT prompt if_expr T_EOL
 195 {
 196         menu_add_prompt(P_PROMPT, $2, $3);
 197         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 198 };
 199
 200 config_option: T_DEFAULT expr if_expr T_EOL
 201 {
 202         menu_add_expr(P_DEFAULT, $2, $3);
 203         if ($1->stype != S_UNKNOWN)
 204                 menu_set_type($1->stype);
 205         printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
 206                 zconf_curname(), zconf_lineno(),
 207                 $1->stype);
 208 };
 209
 210 config_option: T_SELECT nonconst_symbol if_expr T_EOL
 211 {
 212         menu_add_symbol(P_SELECT, $2, $3);
 213         printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
 214 };
 215
 216 config_option: T_IMPLY nonconst_symbol if_expr T_EOL
 217 {
 218         menu_add_symbol(P_IMPLY, $2, $3);
 219         printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
 220 };
 221
 222 config_option: T_RANGE symbol symbol if_expr T_EOL
 223 {
 224         menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
 225         printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
 226 };
 227
 228 symbol_option: T_OPTION symbol_option_list T_EOL
 229 ;
 230
 231 symbol_option_list:
 232           /* empty */
 233         | symbol_option_list T_WORD symbol_option_arg
 234 {
 235         const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
 236         if (id && id->flags & TF_OPTION) {
 237                 menu_add_option(id->token, $3);
 238                 free($3);
 239         }
 240         else
 241                 zconfprint("warning: ignoring unknown option %s", $2);
 242         free($2);
 243 };
 244
 245 symbol_option_arg:
 246           /* empty */           { $$ = NULL; }
 247         | T_EQUAL prompt        { $$ = $2; }
 248 ;
 249
 250 /* choice entry */
 251
 252 choice: T_CHOICE word_opt T_EOL
 253 {
 254         struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
 255         sym->flags |= SYMBOL_NO_WRITE;
 256         menu_add_entry(sym);
 257         menu_add_expr(P_CHOICE, NULL, NULL);
 258         free($2);
 259         printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
 260 };
 261
 262 choice_entry: choice choice_option_list
 263 {
 264         $$ = menu_add_menu();
 265 };
 266
 267 choice_end: end
 268 {
 269         if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
 270                 menu_end_menu();
 271                 printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
 272         }
 273 };
 274
 275 choice_stmt: choice_entry choice_block choice_end
 276 ;
 277
 278 choice_option_list:
 279           /* empty */
 280         | choice_option_list choice_option
 281         | choice_option_list depends
 282         | choice_option_list help
 283         | choice_option_list option_error
 284 ;
 285
 286 choice_option: T_PROMPT prompt if_expr T_EOL
 287 {
 288         menu_add_prompt(P_PROMPT, $2, $3);
 289         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 290 };
 291
 292 choice_option: T_TYPE prompt_stmt_opt T_EOL
 293 {
 294         if ($1->stype == S_BOOLEAN || $1->stype == S_TRISTATE) {
 295                 menu_set_type($1->stype);
 296                 printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 297                         zconf_curname(), zconf_lineno(),
 298                         $1->stype);
 299         } else
 300                 YYERROR;
 301 };
 302
 303 choice_option: T_OPTIONAL T_EOL
 304 {
 305         current_entry->sym->flags |= SYMBOL_OPTIONAL;
 306         printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
 307 };
 308
 309 choice_option: T_DEFAULT nonconst_symbol if_expr T_EOL
 310 {
 311         if ($1->stype == S_UNKNOWN) {
 312                 menu_add_symbol(P_DEFAULT, $2, $3);
 313                 printd(DEBUG_PARSE, "%s:%d:default\n",
 314                         zconf_curname(), zconf_lineno());
 315         } else
 316                 YYERROR;
 317 };
 318
 319 choice_block:
 320           /* empty */
 321         | choice_block common_stmt
 322 ;
 323
 324 /* if entry */
 325
 326 if_entry: T_IF expr T_EOL
 327 {
 328         printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
 329         menu_add_entry(NULL);
 330         menu_add_dep($2);
 331         $$ = menu_add_menu();
 332 };
 333
 334 if_end: end
 335 {
 336         if (zconf_endtoken($1, T_IF, T_ENDIF)) {
 337                 menu_end_menu();
 338                 printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
 339         }
 340 };
 341
 342 if_stmt: if_entry if_block if_end
 343 ;
 344
 345 if_block:
 346           /* empty */
 347         | if_block common_stmt
 348         | if_block menu_stmt
 349         | if_block choice_stmt
 350 ;
 351
 352 /* menu entry */
 353
 354 menu: T_MENU prompt T_EOL
 355 {
 356         menu_add_entry(NULL);
 357         menu_add_prompt(P_MENU, $2, NULL);
 358         printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
 359 };
 360
 361 menu_entry: menu visibility_list depends_list
 362 {
 363         $$ = menu_add_menu();
 364 };
 365
 366 menu_end: end
 367 {
 368         if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
 369                 menu_end_menu();
 370                 printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
 371         }
 372 };
 373
 374 menu_stmt: menu_entry menu_block menu_end
 375 ;
 376
 377 menu_block:
 378           /* empty */
 379         | menu_block common_stmt
 380         | menu_block menu_stmt
 381         | menu_block choice_stmt
 382 ;
 383
 384 source_stmt: T_SOURCE prompt T_EOL
 385 {
 386         printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
 387         zconf_nextfile($2);
 388         free($2);
 389 };
 390
 391 /* comment entry */
 392
 393 comment: T_COMMENT prompt T_EOL
 394 {
 395         menu_add_entry(NULL);
 396         menu_add_prompt(P_COMMENT, $2, NULL);
 397         printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
 398 };
 399
 400 comment_stmt: comment depends_list
 401 ;
 402
 403 /* help option */
 404
 405 help_start: T_HELP T_EOL
 406 {
 407         printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
 408         zconf_starthelp();
 409 };
 410
 411 help: help_start T_HELPTEXT
 412 {
 413         if (current_entry->help) {
 414                 free(current_entry->help);
 415                 zconfprint("warning: '%s' defined with more than one help text -- only the last one will be used",
 416                            current_entry->sym->name ?: "<choice>");
 417         }
 418
 419         /* Is the help text empty or all whitespace? */
 420         if ($2[strspn($2, " \f\n\r\t\v")] == '\0')
 421                 zconfprint("warning: '%s' defined with blank help text",
 422                            current_entry->sym->name ?: "<choice>");
 423
 424         current_entry->help = $2;
 425 };
 426
 427 /* depends option */
 428
 429 depends_list:
 430           /* empty */
 431         | depends_list depends
 432         | depends_list option_error
 433 ;
 434
 435 depends: T_DEPENDS T_ON expr T_EOL
 436 {
 437         menu_add_dep($3);
 438         printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
 439 };
 440
 441 /* visibility option */
 442
 443 visibility_list:
 444           /* empty */
 445         | visibility_list visible
 446 ;
 447
 448 visible: T_VISIBLE if_expr T_EOL
 449 {
 450         menu_add_visibility($2);
 451 };
 452
 453 /* prompt statement */
 454
 455 prompt_stmt_opt:
 456           /* empty */
 457         | prompt if_expr
 458 {
 459         menu_add_prompt(P_PROMPT, $1, $2);
 460 };
 461
 462 prompt:   T_WORD
 463         | T_WORD_QUOTE
 464 ;
 465
 466 end:      T_ENDMENU T_EOL       { $$ = $1; }
 467         | T_ENDCHOICE T_EOL     { $$ = $1; }
 468         | T_ENDIF T_EOL         { $$ = $1; }
 469 ;
 470
 471 if_expr:  /* empty */                   { $$ = NULL; }
 472         | T_IF expr                     { $$ = $2; }
 473 ;
 474
 475 expr:     symbol                                { $$ = expr_alloc_symbol($1); }
 476         | symbol T_LESS symbol                  { $$ = expr_alloc_comp(E_LTH, $1, $3); }
 477         | symbol T_LESS_EQUAL symbol            { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
 478         | symbol T_GREATER symbol               { $$ = expr_alloc_comp(E_GTH, $1, $3); }
 479         | symbol T_GREATER_EQUAL symbol         { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
 480         | symbol T_EQUAL symbol                 { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
 481         | symbol T_UNEQUAL symbol               { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
 482         | T_OPEN_PAREN expr T_CLOSE_PAREN       { $$ = $2; }
 483         | T_NOT expr                            { $$ = expr_alloc_one(E_NOT, $2); }
 484         | expr T_OR expr                        { $$ = expr_alloc_two(E_OR, $1, $3); }
 485         | expr T_AND expr                       { $$ = expr_alloc_two(E_AND, $1, $3); }
 486 ;
 487
 488 /* For symbol definitions, selects, etc., where quotes are not accepted */
 489 nonconst_symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); };
 490
 491 symbol:   nonconst_symbol
 492         | T_WORD_QUOTE  { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
 493 ;
 494
 495 word_opt: /* empty */                   { $$ = NULL; }
 496         | T_WORD
 497
 498 /* assignment statement */
 499
 500 assignment_stmt:  T_VARIABLE T_ASSIGN assign_val T_EOL  { variable_add($1, $3, $2); free($1); free($3); }
 501
 502 assign_val:
 503         /* empty */             { $$ = xstrdup(""); };
 504         | T_ASSIGN_VAL
 505 ;
 506
 507 %%
 508
 509 void conf_parse(const char *name)
 510 {
 511         struct symbol *sym;
 512         int i;
 513
 514         zconf_initscan(name);
 515
 516         _menu_init();
 517         rootmenu.prompt = menu_add_prompt(P_MENU, "CARL9170 Firmware Configuration", NULL);
 518
 519         if (getenv("ZCONF_DEBUG"))
 520                 yydebug = 1;
 521         yyparse();
 522
 523         /* Variables are expanded in the parse phase. We can free them here. */
 524         variable_all_del();
 525
 526         if (yynerrs)
 527                 exit(1);
 528         if (!modules_sym)
 529                 modules_sym = sym_find( "n" );
 530
 531         if (!menu_has_prompt(&rootmenu)) {
 532                 current_entry = &rootmenu;
 533                 menu_add_prompt(P_MENU, "Main menu", NULL);
 534         }
 535
 536         menu_finalize(&rootmenu);
 537         for_all_symbols(i, sym) {
 538                 if (sym_check_deps(sym))
 539                         yynerrs++;
 540         }
 541         if (yynerrs)
 542                 exit(1);
 543         sym_set_change_count(1);
 544 }
 545
 546 static const char *zconf_tokenname(int token)
 547 {
 548         switch (token) {
 549         case T_MENU:            return "menu";
 550         case T_ENDMENU:         return "endmenu";
 551         case T_CHOICE:          return "choice";
 552         case T_ENDCHOICE:       return "endchoice";
 553         case T_IF:              return "if";
 554         case T_ENDIF:           return "endif";
 555         case T_DEPENDS:         return "depends";
 556         case T_VISIBLE:         return "visible";
 557         }
 558         return "<token>";
 559 }
 560
 561 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
 562 {
 563         if (id->token != endtoken) {
 564                 zconf_error("unexpected '%s' within %s block",
 565                         id->name, zconf_tokenname(starttoken));
 566                 yynerrs++;
 567                 return false;
 568         }
 569         if (current_menu->file != current_file) {
 570                 zconf_error("'%s' in different file than '%s'",
 571                         id->name, zconf_tokenname(starttoken));
 572                 fprintf(stderr, "%s:%d: location of the '%s'\n",
 573                         current_menu->file->name, current_menu->lineno,
 574                         zconf_tokenname(starttoken));
 575                 yynerrs++;
 576                 return false;
 577         }
 578         return true;
 579 }
 580
 581 static void zconfprint(const char *err, ...)
 582 {
 583         va_list ap;
 584
 585         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 586         va_start(ap, err);
 587         vfprintf(stderr, err, ap);
 588         va_end(ap);
 589         fprintf(stderr, "\n");
 590 }
 591
 592 static void zconf_error(const char *err, ...)
 593 {
 594         va_list ap;
 595
 596         yynerrs++;
 597         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 598         va_start(ap, err);
 599         vfprintf(stderr, err, ap);
 600         va_end(ap);
 601         fprintf(stderr, "\n");
 602 }
 603
 604 static void yyerror(const char *err)
 605 {
 606         fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
 607 }
 608
 609 static void print_quoted_string(FILE *out, const char *str)
 610 {
 611         const char *p;
 612         int len;
 613
 614         putc('"', out);
 615         while ((p = strchr(str, '"'))) {
 616                 len = p - str;
 617                 if (len)
 618                         fprintf(out, "%.*s", len, str);
 619                 fputs("\\\"", out);
 620                 str = p + 1;
 621         }
 622         fputs(str, out);
 623         putc('"', out);
 624 }
 625
 626 static void print_symbol(FILE *out, struct menu *menu)
 627 {
 628         struct symbol *sym = menu->sym;
 629         struct property *prop;
 630
 631         if (sym_is_choice(sym))
 632                 fprintf(out, "\nchoice\n");
 633         else
 634                 fprintf(out, "\nconfig %s\n", sym->name);
 635         switch (sym->type) {
 636         case S_BOOLEAN:
 637                 fputs("  bool\n", out);
 638                 break;
 639         case S_TRISTATE:
 640                 fputs("  tristate\n", out);
 641                 break;
 642         case S_STRING:
 643                 fputs("  string\n", out);
 644                 break;
 645         case S_INT:
 646                 fputs("  integer\n", out);
 647                 break;
 648         case S_HEX:
 649                 fputs("  hex\n", out);
 650                 break;
 651         default:
 652                 fputs("  ???\n", out);
 653                 break;
 654         }
 655         for (prop = sym->prop; prop; prop = prop->next) {
 656                 if (prop->menu != menu)
 657                         continue;
 658                 switch (prop->type) {
 659                 case P_PROMPT:
 660                         fputs("  prompt ", out);
 661                         print_quoted_string(out, prop->text);
 662                         if (!expr_is_yes(prop->visible.expr)) {
 663                                 fputs(" if ", out);
 664                                 expr_fprint(prop->visible.expr, out);
 665                         }
 666                         fputc('\n', out);
 667                         break;
 668                 case P_DEFAULT:
 669                         fputs( "  default ", out);
 670                         expr_fprint(prop->expr, out);
 671                         if (!expr_is_yes(prop->visible.expr)) {
 672                                 fputs(" if ", out);
 673                                 expr_fprint(prop->visible.expr, out);
 674                         }
 675                         fputc('\n', out);
 676                         break;
 677                 case P_CHOICE:
 678                         fputs("  #choice value\n", out);
 679                         break;
 680                 case P_SELECT:
 681                         fputs( "  select ", out);
 682                         expr_fprint(prop->expr, out);
 683                         fputc('\n', out);
 684                         break;
 685                 case P_IMPLY:
 686                         fputs( "  imply ", out);
 687                         expr_fprint(prop->expr, out);
 688                         fputc('\n', out);
 689                         break;
 690                 case P_RANGE:
 691                         fputs( "  range ", out);
 692                         expr_fprint(prop->expr, out);
 693                         fputc('\n', out);
 694                         break;
 695                 case P_MENU:
 696                         fputs( "  menu ", out);
 697                         print_quoted_string(out, prop->text);
 698                         fputc('\n', out);
 699                         break;
 700                 case P_SYMBOL:
 701                         fputs( "  symbol ", out);
 702                         fprintf(out, "%s\n", prop->sym->name);
 703                         break;
 704                 default:
 705                         fprintf(out, "  unknown prop %d!\n", prop->type);
 706                         break;
 707                 }
 708         }
 709         if (menu->help) {
 710                 int len = strlen(menu->help);
 711                 while (menu->help[--len] == '\n')
 712                         menu->help[len] = 0;
 713                 fprintf(out, "  help\n%s\n", menu->help);
 714         }
 715 }
 716
 717 void zconfdump(FILE *out)
 718 {
 719         struct property *prop;
 720         struct symbol *sym;
 721         struct menu *menu;
 722
 723         menu = rootmenu.list;
 724         while (menu) {
 725                 if ((sym = menu->sym))
 726                         print_symbol(out, menu);
 727                 else if ((prop = menu->prompt)) {
 728                         switch (prop->type) {
 729                         case P_COMMENT:
 730                                 fputs("\ncomment ", out);
 731                                 print_quoted_string(out, prop->text);
 732                                 fputs("\n", out);
 733                                 break;
 734                         case P_MENU:
 735                                 fputs("\nmenu ", out);
 736                                 print_quoted_string(out, prop->text);
 737                                 fputs("\n", out);
 738                                 break;
 739                         default:
 740                                 ;
 741                         }
 742                         if (!expr_is_yes(prop->visible.expr)) {
 743                                 fputs("  depends ", out);
 744                                 expr_fprint(prop->visible.expr, out);
 745                                 fputc('\n', out);
 746                         }
 747                 }
 748
 749                 if (menu->list)
 750                         menu = menu->list;
 751                 else if (menu->next)
 752                         menu = menu->next;
 753                 else while ((menu = menu->parent)) {
 754                         if (menu->prompt && menu->prompt->type == P_MENU)
 755                                 fputs("\nendmenu\n", out);
 756                         if (menu->next) {
 757                                 menu = menu->next;
 758                                 break;
 759                         }
 760                 }
 761         }
 762 }
 763
 764 #include "zconf.lex.c"
 765 #include "util.c"
 766 #include "confdata.c"
 767 #include "expr.c"
 768 #include "symbol.c"
 769 #include "menu.c"
 770 #include "preprocess.c"