config/zconf.y

   1 %{
   2 /*
   3  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   4  * Released under the terms of the GNU GPL v2.0.
   5  */
   6
   7 #include <ctype.h>
   8 #include <stdarg.h>
   9 #include <stdio.h>
  10 #include <stdlib.h>
  11 #include <string.h>
  12 #include <stdbool.h>
  13
  14 #include "lkc.h"
  15
  16 #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  17
  18 #define PRINTD          0x0001
  19 #define DEBUG_PARSE     0x0002
  20
  21 int cdebug = PRINTD;
  22
  23 int yylex(void);
  24 static void yyerror(const char *err);
  25 static void zconfprint(const char *err, ...);
  26 static void zconf_error(const char *err, ...);
  27 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);
  28
  29 struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  30
  31 static struct menu *current_menu, *current_entry;
  32
  33 %}
  34 %expect 32
  35
  36 %union
  37 {
  38         char *string;
  39         struct file *file;
  40         struct symbol *symbol;
  41         struct expr *expr;
  42         struct menu *menu;
  43         const struct kconf_id *id;
  44 }
  45
  46 %token <id>T_MAINMENU
  47 %token <id>T_MENU
  48 %token <id>T_ENDMENU
  49 %token <id>T_SOURCE
  50 %token <id>T_CHOICE
  51 %token <id>T_ENDCHOICE
  52 %token <id>T_COMMENT
  53 %token <id>T_CONFIG
  54 %token <id>T_MENUCONFIG
  55 %token <id>T_HELP
  56 %token <string> T_HELPTEXT
  57 %token <id>T_IF
  58 %token <id>T_ENDIF
  59 %token <id>T_DEPENDS
  60 %token <id>T_OPTIONAL
  61 %token <id>T_PROMPT
  62 %token <id>T_TYPE
  63 %token <id>T_DEFAULT
  64 %token <id>T_SELECT
  65 %token <id>T_IMPLY
  66 %token <id>T_RANGE
  67 %token <id>T_VISIBLE
  68 %token <id>T_OPTION
  69 %token <id>T_ON
  70 %token <string> T_WORD
  71 %token <string> T_WORD_QUOTE
  72 %token T_UNEQUAL
  73 %token T_LESS
  74 %token T_LESS_EQUAL
  75 %token T_GREATER
  76 %token T_GREATER_EQUAL
  77 %token T_CLOSE_PAREN
  78 %token T_OPEN_PAREN
  79 %token T_EOL
  80
  81 %left T_OR
  82 %left T_AND
  83 %left T_EQUAL T_UNEQUAL
  84 %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  85 %nonassoc T_NOT
  86
  87 %type <string> prompt
  88 %type <symbol> nonconst_symbol
  89 %type <symbol> symbol
  90 %type <expr> expr
  91 %type <expr> if_expr
  92 %type <id> end
  93 %type <id> option_name
  94 %type <menu> if_entry menu_entry choice_entry
  95 %type <string> symbol_option_arg word_opt
  96
  97 %destructor {
  98         fprintf(stderr, "%s:%d: missing end statement for this entry\n",
  99                 $$->file->name, $$->lineno);
 100         if (current_menu == $$)
 101                 menu_end_menu();
 102 } if_entry menu_entry choice_entry
 103
 104 %{
 105 /* Include kconf_id.c here so it can see the token constants. */
 106 #include "kconf_id.c"
 107 %}
 108
 109 %%
 110 input: nl start | start;
 111
 112 start: mainmenu_stmt stmt_list | no_mainmenu_stmt stmt_list;
 113
 114 /* mainmenu entry */
 115
 116 mainmenu_stmt: T_MAINMENU prompt nl
 117 {
 118         menu_add_prompt(P_MENU, $2, NULL);
 119 };
 120
 121 /* Default main menu, if there's no mainmenu entry */
 122
 123 no_mainmenu_stmt: /* empty */
 124 {
 125         /*
 126          * Hack: Keep the main menu title on the heap so we can safely free it
 127          * later regardless of whether it comes from the 'prompt' in
 128          * mainmenu_stmt or here
 129          */
 130         menu_add_prompt(P_MENU, strdup("Linux Kernel Configuration"), NULL);
 131 };
 132
 133
 134 stmt_list:
 135           /* empty */
 136         | stmt_list common_stmt
 137         | stmt_list choice_stmt
 138         | stmt_list menu_stmt
 139         | stmt_list end                 { zconf_error("unexpected end statement"); }
 140         | stmt_list T_WORD error T_EOL  { zconf_error("unknown statement \"%s\"", $2); }
 141         | stmt_list option_name error T_EOL
 142 {
 143         zconf_error("unexpected option \"%s\"", $2->name);
 144 }
 145         | stmt_list error T_EOL         { zconf_error("invalid statement"); }
 146 ;
 147
 148 option_name:
 149         T_DEPENDS | T_PROMPT | T_TYPE | T_SELECT | T_IMPLY | T_OPTIONAL | T_RANGE | T_DEFAULT | T_VISIBLE
 150 ;
 151
 152 common_stmt:
 153           T_EOL
 154         | if_stmt
 155         | comment_stmt
 156         | config_stmt
 157         | menuconfig_stmt
 158         | source_stmt
 159 ;
 160
 161 option_error:
 162           T_WORD error T_EOL            { zconf_error("unknown option \"%s\"", $1); }
 163         | error T_EOL                   { zconf_error("invalid option"); }
 164 ;
 165
 166
 167 /* config/menuconfig entry */
 168
 169 config_entry_start: T_CONFIG nonconst_symbol T_EOL
 170 {
 171         $2->flags |= SYMBOL_OPTIONAL;
 172         menu_add_entry($2);
 173         printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2->name);
 174 };
 175
 176 config_stmt: config_entry_start config_option_list
 177 {
 178         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 179 };
 180
 181 menuconfig_entry_start: T_MENUCONFIG nonconst_symbol T_EOL
 182 {
 183         $2->flags |= SYMBOL_OPTIONAL;
 184         menu_add_entry($2);
 185         printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2->name);
 186 };
 187
 188 menuconfig_stmt: menuconfig_entry_start config_option_list
 189 {
 190         if (current_entry->prompt)
 191                 current_entry->prompt->type = P_MENU;
 192         else
 193                 zconfprint("warning: menuconfig statement without prompt");
 194         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 195 };
 196
 197 config_option_list:
 198           /* empty */
 199         | config_option_list config_option
 200         | config_option_list symbol_option
 201         | config_option_list depends
 202         | config_option_list help
 203         | config_option_list option_error
 204         | config_option_list T_EOL
 205 ;
 206
 207 config_option: T_TYPE prompt_stmt_opt T_EOL
 208 {
 209         menu_set_type($1->stype);
 210         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 211                 zconf_curname(), zconf_lineno(),
 212                 $1->stype);
 213 };
 214
 215 config_option: T_PROMPT prompt if_expr T_EOL
 216 {
 217         menu_add_prompt(P_PROMPT, $2, $3);
 218         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 219 };
 220
 221 config_option: T_DEFAULT expr if_expr T_EOL
 222 {
 223         menu_add_expr(P_DEFAULT, $2, $3);
 224         if ($1->stype != S_UNKNOWN)
 225                 menu_set_type($1->stype);
 226         printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
 227                 zconf_curname(), zconf_lineno(),
 228                 $1->stype);
 229 };
 230
 231 config_option: T_SELECT nonconst_symbol if_expr T_EOL
 232 {
 233         menu_add_symbol(P_SELECT, $2, $3);
 234         printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
 235 };
 236
 237 config_option: T_IMPLY nonconst_symbol if_expr T_EOL
 238 {
 239         menu_add_symbol(P_IMPLY, $2, $3);
 240         printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
 241 };
 242
 243 config_option: T_RANGE symbol symbol if_expr T_EOL
 244 {
 245         menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
 246         printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
 247 };
 248
 249 symbol_option: T_OPTION symbol_option_list T_EOL
 250 ;
 251
 252 symbol_option_list:
 253           /* empty */
 254         | symbol_option_list T_WORD symbol_option_arg
 255 {
 256         const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
 257         if (id && id->flags & TF_OPTION) {
 258                 menu_add_option(id->token, $3);
 259                 free($3);
 260         }
 261         else
 262                 zconfprint("warning: ignoring unknown option %s", $2);
 263         free($2);
 264 };
 265
 266 symbol_option_arg:
 267           /* empty */           { $$ = NULL; }
 268         | T_EQUAL prompt        { $$ = $2; }
 269 ;
 270
 271 /* choice entry */
 272
 273 choice: T_CHOICE word_opt T_EOL
 274 {
 275         struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
 276         sym->flags |= SYMBOL_AUTO;
 277         menu_add_entry(sym);
 278         menu_add_expr(P_CHOICE, NULL, NULL);
 279         printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
 280 };
 281
 282 choice_entry: choice choice_option_list
 283 {
 284         $$ = menu_add_menu();
 285 };
 286
 287 choice_end: end
 288 {
 289         if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
 290                 menu_end_menu();
 291                 printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
 292         }
 293 };
 294
 295 choice_stmt: choice_entry choice_block choice_end
 296 ;
 297
 298 choice_option_list:
 299           /* empty */
 300         | choice_option_list choice_option
 301         | choice_option_list depends
 302         | choice_option_list help
 303         | choice_option_list T_EOL
 304         | choice_option_list option_error
 305 ;
 306
 307 choice_option: T_PROMPT prompt if_expr T_EOL
 308 {
 309         menu_add_prompt(P_PROMPT, $2, $3);
 310         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 311 };
 312
 313 choice_option: T_TYPE prompt_stmt_opt T_EOL
 314 {
 315         if ($1->stype == S_BOOLEAN || $1->stype == S_TRISTATE) {
 316                 menu_set_type($1->stype);
 317                 printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 318                         zconf_curname(), zconf_lineno(),
 319                         $1->stype);
 320         } else
 321                 YYERROR;
 322 };
 323
 324 choice_option: T_OPTIONAL T_EOL
 325 {
 326         current_entry->sym->flags |= SYMBOL_OPTIONAL;
 327         printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
 328 };
 329
 330 choice_option: T_DEFAULT nonconst_symbol if_expr T_EOL
 331 {
 332         if ($1->stype == S_UNKNOWN) {
 333                 menu_add_symbol(P_DEFAULT, $2, $3);
 334                 printd(DEBUG_PARSE, "%s:%d:default\n",
 335                         zconf_curname(), zconf_lineno());
 336         } else
 337                 YYERROR;
 338 };
 339
 340 choice_block:
 341           /* empty */
 342         | choice_block common_stmt
 343 ;
 344
 345 /* if entry */
 346
 347 if_entry: T_IF expr nl
 348 {
 349         printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
 350         menu_add_entry(NULL);
 351         menu_add_dep($2);
 352         $$ = menu_add_menu();
 353 };
 354
 355 if_end: end
 356 {
 357         if (zconf_endtoken($1, T_IF, T_ENDIF)) {
 358                 menu_end_menu();
 359                 printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
 360         }
 361 };
 362
 363 if_stmt: if_entry if_block if_end
 364 ;
 365
 366 if_block:
 367           /* empty */
 368         | if_block common_stmt
 369         | if_block menu_stmt
 370         | if_block choice_stmt
 371 ;
 372
 373 /* menu entry */
 374
 375 menu: T_MENU prompt T_EOL
 376 {
 377         menu_add_entry(NULL);
 378         menu_add_prompt(P_MENU, $2, NULL);
 379         printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
 380 };
 381
 382 menu_entry: menu visibility_list depends_list
 383 {
 384         $$ = menu_add_menu();
 385 };
 386
 387 menu_end: end
 388 {
 389         if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
 390                 menu_end_menu();
 391                 printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
 392         }
 393 };
 394
 395 menu_stmt: menu_entry menu_block menu_end
 396 ;
 397
 398 menu_block:
 399           /* empty */
 400         | menu_block common_stmt
 401         | menu_block menu_stmt
 402         | menu_block choice_stmt
 403 ;
 404
 405 source_stmt: T_SOURCE prompt T_EOL
 406 {
 407         printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
 408         zconf_nextfile($2);
 409         free($2);
 410 };
 411
 412 /* comment entry */
 413
 414 comment: T_COMMENT prompt T_EOL
 415 {
 416         menu_add_entry(NULL);
 417         menu_add_prompt(P_COMMENT, $2, NULL);
 418         printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
 419 };
 420
 421 comment_stmt: comment depends_list
 422 ;
 423
 424 /* help option */
 425
 426 help_start: T_HELP T_EOL
 427 {
 428         printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
 429         zconf_starthelp();
 430 };
 431
 432 help: help_start T_HELPTEXT
 433 {
 434         if (current_entry->help) {
 435                 free(current_entry->help);
 436                 zconfprint("warning: '%s' defined with more than one help text -- only the last one will be used",
 437                            current_entry->sym->name ?: "<choice>");
 438         }
 439         current_entry->help = $2;
 440 };
 441
 442 /* depends option */
 443
 444 depends_list:
 445           /* empty */
 446         | depends_list depends
 447         | depends_list T_EOL
 448         | depends_list option_error
 449 ;
 450
 451 depends: T_DEPENDS T_ON expr T_EOL
 452 {
 453         menu_add_dep($3);
 454         printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
 455 };
 456
 457 /* visibility option */
 458
 459 visibility_list:
 460           /* empty */
 461         | visibility_list visible
 462         | visibility_list T_EOL
 463 ;
 464
 465 visible: T_VISIBLE if_expr
 466 {
 467         menu_add_visibility($2);
 468 };
 469
 470 /* prompt statement */
 471
 472 prompt_stmt_opt:
 473           /* empty */
 474         | prompt if_expr
 475 {
 476         menu_add_prompt(P_PROMPT, $1, $2);
 477 };
 478
 479 prompt:   T_WORD
 480         | T_WORD_QUOTE
 481 ;
 482
 483 end:      T_ENDMENU T_EOL       { $$ = $1; }
 484         | T_ENDCHOICE T_EOL     { $$ = $1; }
 485         | T_ENDIF T_EOL         { $$ = $1; }
 486 ;
 487
 488 nl:
 489           T_EOL
 490         | nl T_EOL
 491 ;
 492
 493 if_expr:  /* empty */                   { $$ = NULL; }
 494         | T_IF expr                     { $$ = $2; }
 495 ;
 496
 497 expr:     symbol                                { $$ = expr_alloc_symbol($1); }
 498         | symbol T_LESS symbol                  { $$ = expr_alloc_comp(E_LTH, $1, $3); }
 499         | symbol T_LESS_EQUAL symbol            { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
 500         | symbol T_GREATER symbol               { $$ = expr_alloc_comp(E_GTH, $1, $3); }
 501         | symbol T_GREATER_EQUAL symbol         { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
 502         | symbol T_EQUAL symbol                 { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
 503         | symbol T_UNEQUAL symbol               { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
 504         | T_OPEN_PAREN expr T_CLOSE_PAREN       { $$ = $2; }
 505         | T_NOT expr                            { $$ = expr_alloc_one(E_NOT, $2); }
 506         | expr T_OR expr                        { $$ = expr_alloc_two(E_OR, $1, $3); }
 507         | expr T_AND expr                       { $$ = expr_alloc_two(E_AND, $1, $3); }
 508 ;
 509
 510 /* For symbol definitions, selects, etc., where quotes are not accepted */
 511 nonconst_symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); };
 512
 513 symbol:   nonconst_symbol
 514         | T_WORD_QUOTE  { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
 515 ;
 516
 517 word_opt: /* empty */                   { $$ = NULL; }
 518         | T_WORD
 519
 520 %%
 521
 522 void conf_parse(const char *name)
 523 {
 524         const char *tmp;
 525         struct symbol *sym;
 526         int i;
 527
 528         zconf_initscan(name);
 529
 530         sym_init();
 531         _menu_init();
 532         rootmenu.prompt = menu_add_prompt(P_MENU, "CARL9170 Firmware Configuration", NULL);
 533
 534         if (getenv("ZCONF_DEBUG"))
 535                 yydebug = 1;
 536         yyparse();
 537         if (yynerrs)
 538                 exit(1);
 539         if (!modules_sym)
 540                 modules_sym = sym_find( "n" );
 541
 542         tmp = rootmenu.prompt->text;
 543         rootmenu.prompt->text = _(rootmenu.prompt->text);
 544         rootmenu.prompt->text = sym_expand_string_value(rootmenu.prompt->text);
 545         free((char*)tmp);
 546
 547         menu_finalize(&rootmenu);
 548         for_all_symbols(i, sym) {
 549                 if (sym_check_deps(sym))
 550                         yynerrs++;
 551         }
 552         if (yynerrs)
 553                 exit(1);
 554         sym_set_change_count(1);
 555 }
 556
 557 static const char *zconf_tokenname(int token)
 558 {
 559         switch (token) {
 560         case T_MENU:            return "menu";
 561         case T_ENDMENU:         return "endmenu";
 562         case T_CHOICE:          return "choice";
 563         case T_ENDCHOICE:       return "endchoice";
 564         case T_IF:              return "if";
 565         case T_ENDIF:           return "endif";
 566         case T_DEPENDS:         return "depends";
 567         case T_VISIBLE:         return "visible";
 568         }
 569         return "<token>";
 570 }
 571
 572 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
 573 {
 574         if (id->token != endtoken) {
 575                 zconf_error("unexpected '%s' within %s block",
 576                         id->name, zconf_tokenname(starttoken));
 577                 yynerrs++;
 578                 return false;
 579         }
 580         if (current_menu->file != current_file) {
 581                 zconf_error("'%s' in different file than '%s'",
 582                         id->name, zconf_tokenname(starttoken));
 583                 fprintf(stderr, "%s:%d: location of the '%s'\n",
 584                         current_menu->file->name, current_menu->lineno,
 585                         zconf_tokenname(starttoken));
 586                 yynerrs++;
 587                 return false;
 588         }
 589         return true;
 590 }
 591
 592 static void zconfprint(const char *err, ...)
 593 {
 594         va_list ap;
 595
 596         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 597         va_start(ap, err);
 598         vfprintf(stderr, err, ap);
 599         va_end(ap);
 600         fprintf(stderr, "\n");
 601 }
 602
 603 static void zconf_error(const char *err, ...)
 604 {
 605         va_list ap;
 606
 607         yynerrs++;
 608         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 609         va_start(ap, err);
 610         vfprintf(stderr, err, ap);
 611         va_end(ap);
 612         fprintf(stderr, "\n");
 613 }
 614
 615 static void yyerror(const char *err)
 616 {
 617         fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
 618 }
 619
 620 static void print_quoted_string(FILE *out, const char *str)
 621 {
 622         const char *p;
 623         int len;
 624
 625         putc('"', out);
 626         while ((p = strchr(str, '"'))) {
 627                 len = p - str;
 628                 if (len)
 629                         fprintf(out, "%.*s", len, str);
 630                 fputs("\\\"", out);
 631                 str = p + 1;
 632         }
 633         fputs(str, out);
 634         putc('"', out);
 635 }
 636
 637 static void print_symbol(FILE *out, struct menu *menu)
 638 {
 639         struct symbol *sym = menu->sym;
 640         struct property *prop;
 641
 642         if (sym_is_choice(sym))
 643                 fprintf(out, "\nchoice\n");
 644         else
 645                 fprintf(out, "\nconfig %s\n", sym->name);
 646         switch (sym->type) {
 647         case S_BOOLEAN:
 648                 fputs("  bool\n", out);
 649                 break;
 650         case S_TRISTATE:
 651                 fputs("  tristate\n", out);
 652                 break;
 653         case S_STRING:
 654                 fputs("  string\n", out);
 655                 break;
 656         case S_INT:
 657                 fputs("  integer\n", out);
 658                 break;
 659         case S_HEX:
 660                 fputs("  hex\n", out);
 661                 break;
 662         default:
 663                 fputs("  ???\n", out);
 664                 break;
 665         }
 666         for (prop = sym->prop; prop; prop = prop->next) {
 667                 if (prop->menu != menu)
 668                         continue;
 669                 switch (prop->type) {
 670                 case P_PROMPT:
 671                         fputs("  prompt ", out);
 672                         print_quoted_string(out, prop->text);
 673                         if (!expr_is_yes(prop->visible.expr)) {
 674                                 fputs(" if ", out);
 675                                 expr_fprint(prop->visible.expr, out);
 676                         }
 677                         fputc('\n', out);
 678                         break;
 679                 case P_DEFAULT:
 680                         fputs( "  default ", out);
 681                         expr_fprint(prop->expr, out);
 682                         if (!expr_is_yes(prop->visible.expr)) {
 683                                 fputs(" if ", out);
 684                                 expr_fprint(prop->visible.expr, out);
 685                         }
 686                         fputc('\n', out);
 687                         break;
 688                 case P_CHOICE:
 689                         fputs("  #choice value\n", out);
 690                         break;
 691                 case P_SELECT:
 692                         fputs( "  select ", out);
 693                         expr_fprint(prop->expr, out);
 694                         fputc('\n', out);
 695                         break;
 696                 case P_IMPLY:
 697                         fputs( "  imply ", out);
 698                         expr_fprint(prop->expr, out);
 699                         fputc('\n', out);
 700                         break;
 701                 case P_RANGE:
 702                         fputs( "  range ", out);
 703                         expr_fprint(prop->expr, out);
 704                         fputc('\n', out);
 705                         break;
 706                 case P_MENU:
 707                         fputs( "  menu ", out);
 708                         print_quoted_string(out, prop->text);
 709                         fputc('\n', out);
 710                         break;
 711                 default:
 712                         fprintf(out, "  unknown prop %d!\n", prop->type);
 713                         break;
 714                 }
 715         }
 716         if (menu->help) {
 717                 int len = strlen(menu->help);
 718                 while (menu->help[--len] == '\n')
 719                         menu->help[len] = 0;
 720                 fprintf(out, "  help\n%s\n", menu->help);
 721         }
 722 }
 723
 724 void zconfdump(FILE *out)
 725 {
 726         struct property *prop;
 727         struct symbol *sym;
 728         struct menu *menu;
 729
 730         menu = rootmenu.list;
 731         while (menu) {
 732                 if ((sym = menu->sym))
 733                         print_symbol(out, menu);
 734                 else if ((prop = menu->prompt)) {
 735                         switch (prop->type) {
 736                         case P_COMMENT:
 737                                 fputs("\ncomment ", out);
 738                                 print_quoted_string(out, prop->text);
 739                                 fputs("\n", out);
 740                                 break;
 741                         case P_MENU:
 742                                 fputs("\nmenu ", out);
 743                                 print_quoted_string(out, prop->text);
 744                                 fputs("\n", out);
 745                                 break;
 746                         default:
 747                                 ;
 748                         }
 749                         if (!expr_is_yes(prop->visible.expr)) {
 750                                 fputs("  depends ", out);
 751                                 expr_fprint(prop->visible.expr, out);
 752                                 fputc('\n', out);
 753                         }
 754                 }
 755
 756                 if (menu->list)
 757                         menu = menu->list;
 758                 else if (menu->next)
 759                         menu = menu->next;
 760                 else while ((menu = menu->parent)) {
 761                         if (menu->prompt && menu->prompt->type == P_MENU)
 762                                 fputs("\nendmenu\n", out);
 763                         if (menu->next) {
 764                                 menu = menu->next;
 765                                 break;
 766                         }
 767                 }
 768         }
 769 }
 770
 771 #include "zconf.lex.c"
 772 #include "util.c"
 773 #include "confdata.c"
 774 #include "expr.c"
 775 #include "symbol.c"
 776 #include "menu.c"