config/zconf.y

   1 %{
   2 /*
   3  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   4  * Released under the terms of the GNU GPL v2.0.
   5  */
   6
   7 #include <ctype.h>
   8 #include <stdarg.h>
   9 #include <stdio.h>
  10 #include <stdlib.h>
  11 #include <string.h>
  12 #include <stdbool.h>
  13
  14 #include "lkc.h"
  15
  16 #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  17
  18 #define PRINTD          0x0001
  19 #define DEBUG_PARSE     0x0002
  20
  21 int cdebug = PRINTD;
  22
  23 extern int zconflex(void);
  24 static void zconfprint(const char *err, ...);
  25 static void zconf_error(const char *err, ...);
  26 static void zconferror(const char *err);
  27 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken);
  28
  29 struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  30
  31 static struct menu *current_menu, *current_entry;
  32
  33 %}
  34 %expect 32
  35
  36 %union
  37 {
  38         char *string;
  39         struct file *file;
  40         struct symbol *symbol;
  41         struct expr *expr;
  42         struct menu *menu;
  43         const struct kconf_id *id;
  44 }
  45
  46 %token <id>T_MAINMENU
  47 %token <id>T_MENU
  48 %token <id>T_ENDMENU
  49 %token <id>T_SOURCE
  50 %token <id>T_CHOICE
  51 %token <id>T_ENDCHOICE
  52 %token <id>T_COMMENT
  53 %token <id>T_CONFIG
  54 %token <id>T_MENUCONFIG
  55 %token <id>T_HELP
  56 %token <string> T_HELPTEXT
  57 %token <id>T_IF
  58 %token <id>T_ENDIF
  59 %token <id>T_DEPENDS
  60 %token <id>T_OPTIONAL
  61 %token <id>T_PROMPT
  62 %token <id>T_TYPE
  63 %token <id>T_DEFAULT
  64 %token <id>T_SELECT
  65 %token <id>T_IMPLY
  66 %token <id>T_RANGE
  67 %token <id>T_VISIBLE
  68 %token <id>T_OPTION
  69 %token <id>T_ON
  70 %token <string> T_WORD
  71 %token <string> T_WORD_QUOTE
  72 %token T_UNEQUAL
  73 %token T_LESS
  74 %token T_LESS_EQUAL
  75 %token T_GREATER
  76 %token T_GREATER_EQUAL
  77 %token T_CLOSE_PAREN
  78 %token T_OPEN_PAREN
  79 %token T_EOL
  80
  81 %left T_OR
  82 %left T_AND
  83 %left T_EQUAL T_UNEQUAL
  84 %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  85 %nonassoc T_NOT
  86
  87 %type <string> prompt
  88 %type <symbol> nonconst_symbol
  89 %type <symbol> symbol
  90 %type <expr> expr
  91 %type <expr> if_expr
  92 %type <id> end
  93 %type <id> option_name
  94 %type <menu> if_entry menu_entry choice_entry
  95 %type <string> symbol_option_arg word_opt
  96
  97 %destructor {
  98         fprintf(stderr, "%s:%d: missing end statement for this entry\n",
  99                 $$->file->name, $$->lineno);
 100         if (current_menu == $$)
 101                 menu_end_menu();
 102 } if_entry menu_entry choice_entry
 103
 104 %{
 105 /* Include kconf_id.c here so it can see the token constants. */
 106 #include "kconf_id.c"
 107 %}
 108
 109 %%
 110 input: nl start | start;
 111
 112 start: mainmenu_stmt stmt_list | no_mainmenu_stmt stmt_list;
 113
 114 /* mainmenu entry */
 115
 116 mainmenu_stmt: T_MAINMENU prompt nl
 117 {
 118         menu_add_prompt(P_MENU, $2, NULL);
 119 };
 120
 121 /* Default main menu, if there's no mainmenu entry */
 122
 123 no_mainmenu_stmt: /* empty */
 124 {
 125         /*
 126          * Hack: Keep the main menu title on the heap so we can safely free it
 127          * later regardless of whether it comes from the 'prompt' in
 128          * mainmenu_stmt or here
 129          */
 130         menu_add_prompt(P_MENU, strdup("Linux Kernel Configuration"), NULL);
 131 };
 132
 133
 134 stmt_list:
 135           /* empty */
 136         | stmt_list common_stmt
 137         | stmt_list choice_stmt
 138         | stmt_list menu_stmt
 139         | stmt_list end                 { zconf_error("unexpected end statement"); }
 140         | stmt_list T_WORD error T_EOL  { zconf_error("unknown statement \"%s\"", $2); }
 141         | stmt_list option_name error T_EOL
 142 {
 143         zconf_error("unexpected option \"%s\"", $2->name);
 144 }
 145         | stmt_list error T_EOL         { zconf_error("invalid statement"); }
 146 ;
 147
 148 option_name:
 149         T_DEPENDS | T_PROMPT | T_TYPE | T_SELECT | T_IMPLY | T_OPTIONAL | T_RANGE | T_DEFAULT | T_VISIBLE
 150 ;
 151
 152 common_stmt:
 153           T_EOL
 154         | if_stmt
 155         | comment_stmt
 156         | config_stmt
 157         | menuconfig_stmt
 158         | source_stmt
 159 ;
 160
 161 option_error:
 162           T_WORD error T_EOL            { zconf_error("unknown option \"%s\"", $1); }
 163         | error T_EOL                   { zconf_error("invalid option"); }
 164 ;
 165
 166
 167 /* config/menuconfig entry */
 168
 169 config_entry_start: T_CONFIG nonconst_symbol T_EOL
 170 {
 171         $2->flags |= SYMBOL_OPTIONAL;
 172         menu_add_entry($2);
 173         printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2->name);
 174 };
 175
 176 config_stmt: config_entry_start config_option_list
 177 {
 178         menu_end_entry();
 179         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 180 };
 181
 182 menuconfig_entry_start: T_MENUCONFIG nonconst_symbol T_EOL
 183 {
 184         $2->flags |= SYMBOL_OPTIONAL;
 185         menu_add_entry($2);
 186         printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2->name);
 187 };
 188
 189 menuconfig_stmt: menuconfig_entry_start config_option_list
 190 {
 191         if (current_entry->prompt)
 192                 current_entry->prompt->type = P_MENU;
 193         else
 194                 zconfprint("warning: menuconfig statement without prompt");
 195         menu_end_entry();
 196         printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
 197 };
 198
 199 config_option_list:
 200           /* empty */
 201         | config_option_list config_option
 202         | config_option_list symbol_option
 203         | config_option_list depends
 204         | config_option_list help
 205         | config_option_list option_error
 206         | config_option_list T_EOL
 207 ;
 208
 209 config_option: T_TYPE prompt_stmt_opt T_EOL
 210 {
 211         menu_set_type($1->stype);
 212         printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 213                 zconf_curname(), zconf_lineno(),
 214                 $1->stype);
 215 };
 216
 217 config_option: T_PROMPT prompt if_expr T_EOL
 218 {
 219         menu_add_prompt(P_PROMPT, $2, $3);
 220         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 221 };
 222
 223 config_option: T_DEFAULT expr if_expr T_EOL
 224 {
 225         menu_add_expr(P_DEFAULT, $2, $3);
 226         if ($1->stype != S_UNKNOWN)
 227                 menu_set_type($1->stype);
 228         printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
 229                 zconf_curname(), zconf_lineno(),
 230                 $1->stype);
 231 };
 232
 233 config_option: T_SELECT nonconst_symbol if_expr T_EOL
 234 {
 235         menu_add_symbol(P_SELECT, $2, $3);
 236         printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
 237 };
 238
 239 config_option: T_IMPLY nonconst_symbol if_expr T_EOL
 240 {
 241         menu_add_symbol(P_IMPLY, $2, $3);
 242         printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
 243 };
 244
 245 config_option: T_RANGE symbol symbol if_expr T_EOL
 246 {
 247         menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
 248         printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
 249 };
 250
 251 symbol_option: T_OPTION symbol_option_list T_EOL
 252 ;
 253
 254 symbol_option_list:
 255           /* empty */
 256         | symbol_option_list T_WORD symbol_option_arg
 257 {
 258         const struct kconf_id *id = kconf_id_lookup($2, strlen($2));
 259         if (id && id->flags & TF_OPTION) {
 260                 menu_add_option(id->token, $3);
 261                 free($3);
 262         }
 263         else
 264                 zconfprint("warning: ignoring unknown option %s", $2);
 265         free($2);
 266 };
 267
 268 symbol_option_arg:
 269           /* empty */           { $$ = NULL; }
 270         | T_EQUAL prompt        { $$ = $2; }
 271 ;
 272
 273 /* choice entry */
 274
 275 choice: T_CHOICE word_opt T_EOL
 276 {
 277         struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
 278         sym->flags |= SYMBOL_AUTO;
 279         menu_add_entry(sym);
 280         menu_add_expr(P_CHOICE, NULL, NULL);
 281         printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
 282 };
 283
 284 choice_entry: choice choice_option_list
 285 {
 286         $$ = menu_add_menu();
 287 };
 288
 289 choice_end: end
 290 {
 291         if (zconf_endtoken($1, T_CHOICE, T_ENDCHOICE)) {
 292                 menu_end_menu();
 293                 printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
 294         }
 295 };
 296
 297 choice_stmt: choice_entry choice_block choice_end
 298 ;
 299
 300 choice_option_list:
 301           /* empty */
 302         | choice_option_list choice_option
 303         | choice_option_list depends
 304         | choice_option_list help
 305         | choice_option_list T_EOL
 306         | choice_option_list option_error
 307 ;
 308
 309 choice_option: T_PROMPT prompt if_expr T_EOL
 310 {
 311         menu_add_prompt(P_PROMPT, $2, $3);
 312         printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
 313 };
 314
 315 choice_option: T_TYPE prompt_stmt_opt T_EOL
 316 {
 317         if ($1->stype == S_BOOLEAN || $1->stype == S_TRISTATE) {
 318                 menu_set_type($1->stype);
 319                 printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
 320                         zconf_curname(), zconf_lineno(),
 321                         $1->stype);
 322         } else
 323                 YYERROR;
 324 };
 325
 326 choice_option: T_OPTIONAL T_EOL
 327 {
 328         current_entry->sym->flags |= SYMBOL_OPTIONAL;
 329         printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
 330 };
 331
 332 choice_option: T_DEFAULT nonconst_symbol if_expr T_EOL
 333 {
 334         if ($1->stype == S_UNKNOWN) {
 335                 menu_add_symbol(P_DEFAULT, $2, $3);
 336                 printd(DEBUG_PARSE, "%s:%d:default\n",
 337                         zconf_curname(), zconf_lineno());
 338         } else
 339                 YYERROR;
 340 };
 341
 342 choice_block:
 343           /* empty */
 344         | choice_block common_stmt
 345 ;
 346
 347 /* if entry */
 348
 349 if_entry: T_IF expr nl
 350 {
 351         printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
 352         menu_add_entry(NULL);
 353         menu_add_dep($2);
 354         $$ = menu_add_menu();
 355 };
 356
 357 if_end: end
 358 {
 359         if (zconf_endtoken($1, T_IF, T_ENDIF)) {
 360                 menu_end_menu();
 361                 printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
 362         }
 363 };
 364
 365 if_stmt: if_entry if_block if_end
 366 ;
 367
 368 if_block:
 369           /* empty */
 370         | if_block common_stmt
 371         | if_block menu_stmt
 372         | if_block choice_stmt
 373 ;
 374
 375 /* menu entry */
 376
 377 menu: T_MENU prompt T_EOL
 378 {
 379         menu_add_entry(NULL);
 380         menu_add_prompt(P_MENU, $2, NULL);
 381         printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
 382 };
 383
 384 menu_entry: menu visibility_list depends_list
 385 {
 386         $$ = menu_add_menu();
 387 };
 388
 389 menu_end: end
 390 {
 391         if (zconf_endtoken($1, T_MENU, T_ENDMENU)) {
 392                 menu_end_menu();
 393                 printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
 394         }
 395 };
 396
 397 menu_stmt: menu_entry menu_block menu_end
 398 ;
 399
 400 menu_block:
 401           /* empty */
 402         | menu_block common_stmt
 403         | menu_block menu_stmt
 404         | menu_block choice_stmt
 405 ;
 406
 407 source_stmt: T_SOURCE prompt T_EOL
 408 {
 409         printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
 410         zconf_nextfile($2);
 411         free($2);
 412 };
 413
 414 /* comment entry */
 415
 416 comment: T_COMMENT prompt T_EOL
 417 {
 418         menu_add_entry(NULL);
 419         menu_add_prompt(P_COMMENT, $2, NULL);
 420         printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
 421 };
 422
 423 comment_stmt: comment depends_list
 424 {
 425         menu_end_entry();
 426 };
 427
 428 /* help option */
 429
 430 help_start: T_HELP T_EOL
 431 {
 432         printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
 433         zconf_starthelp();
 434 };
 435
 436 help: help_start T_HELPTEXT
 437 {
 438         current_entry->help = $2;
 439 };
 440
 441 /* depends option */
 442
 443 depends_list:
 444           /* empty */
 445         | depends_list depends
 446         | depends_list T_EOL
 447         | depends_list option_error
 448 ;
 449
 450 depends: T_DEPENDS T_ON expr T_EOL
 451 {
 452         menu_add_dep($3);
 453         printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
 454 };
 455
 456 /* visibility option */
 457
 458 visibility_list:
 459           /* empty */
 460         | visibility_list visible
 461         | visibility_list T_EOL
 462 ;
 463
 464 visible: T_VISIBLE if_expr
 465 {
 466         menu_add_visibility($2);
 467 };
 468
 469 /* prompt statement */
 470
 471 prompt_stmt_opt:
 472           /* empty */
 473         | prompt if_expr
 474 {
 475         menu_add_prompt(P_PROMPT, $1, $2);
 476 };
 477
 478 prompt:   T_WORD
 479         | T_WORD_QUOTE
 480 ;
 481
 482 end:      T_ENDMENU T_EOL       { $$ = $1; }
 483         | T_ENDCHOICE T_EOL     { $$ = $1; }
 484         | T_ENDIF T_EOL         { $$ = $1; }
 485 ;
 486
 487 nl:
 488           T_EOL
 489         | nl T_EOL
 490 ;
 491
 492 if_expr:  /* empty */                   { $$ = NULL; }
 493         | T_IF expr                     { $$ = $2; }
 494 ;
 495
 496 expr:     symbol                                { $$ = expr_alloc_symbol($1); }
 497         | symbol T_LESS symbol                  { $$ = expr_alloc_comp(E_LTH, $1, $3); }
 498         | symbol T_LESS_EQUAL symbol            { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
 499         | symbol T_GREATER symbol               { $$ = expr_alloc_comp(E_GTH, $1, $3); }
 500         | symbol T_GREATER_EQUAL symbol         { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
 501         | symbol T_EQUAL symbol                 { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
 502         | symbol T_UNEQUAL symbol               { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
 503         | T_OPEN_PAREN expr T_CLOSE_PAREN       { $$ = $2; }
 504         | T_NOT expr                            { $$ = expr_alloc_one(E_NOT, $2); }
 505         | expr T_OR expr                        { $$ = expr_alloc_two(E_OR, $1, $3); }
 506         | expr T_AND expr                       { $$ = expr_alloc_two(E_AND, $1, $3); }
 507 ;
 508
 509 /* For symbol definitions, selects, etc., where quotes are not accepted */
 510 nonconst_symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); };
 511
 512 symbol:   nonconst_symbol
 513         | T_WORD_QUOTE  { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
 514 ;
 515
 516 word_opt: /* empty */                   { $$ = NULL; }
 517         | T_WORD
 518
 519 %%
 520
 521 void conf_parse(const char *name)
 522 {
 523         const char *tmp;
 524         struct symbol *sym;
 525         int i;
 526
 527         zconf_initscan(name);
 528
 529         sym_init();
 530         _menu_init();
 531         rootmenu.prompt = menu_add_prompt(P_MENU, "CARL9170 Firmware Configuration", NULL);
 532
 533         if (getenv("ZCONF_DEBUG"))
 534                 zconfdebug = 1;
 535         zconfparse();
 536         if (zconfnerrs)
 537                 exit(1);
 538         if (!modules_sym)
 539                 modules_sym = sym_find( "n" );
 540
 541         tmp = rootmenu.prompt->text;
 542         rootmenu.prompt->text = _(rootmenu.prompt->text);
 543         rootmenu.prompt->text = sym_expand_string_value(rootmenu.prompt->text);
 544         free((char*)tmp);
 545
 546         menu_finalize(&rootmenu);
 547         for_all_symbols(i, sym) {
 548                 if (sym_check_deps(sym))
 549                         zconfnerrs++;
 550         }
 551         if (zconfnerrs)
 552                 exit(1);
 553         sym_set_change_count(1);
 554 }
 555
 556 static const char *zconf_tokenname(int token)
 557 {
 558         switch (token) {
 559         case T_MENU:            return "menu";
 560         case T_ENDMENU:         return "endmenu";
 561         case T_CHOICE:          return "choice";
 562         case T_ENDCHOICE:       return "endchoice";
 563         case T_IF:              return "if";
 564         case T_ENDIF:           return "endif";
 565         case T_DEPENDS:         return "depends";
 566         case T_VISIBLE:         return "visible";
 567         }
 568         return "<token>";
 569 }
 570
 571 static bool zconf_endtoken(const struct kconf_id *id, int starttoken, int endtoken)
 572 {
 573         if (id->token != endtoken) {
 574                 zconf_error("unexpected '%s' within %s block",
 575                         id->name, zconf_tokenname(starttoken));
 576                 zconfnerrs++;
 577                 return false;
 578         }
 579         if (current_menu->file != current_file) {
 580                 zconf_error("'%s' in different file than '%s'",
 581                         id->name, zconf_tokenname(starttoken));
 582                 fprintf(stderr, "%s:%d: location of the '%s'\n",
 583                         current_menu->file->name, current_menu->lineno,
 584                         zconf_tokenname(starttoken));
 585                 zconfnerrs++;
 586                 return false;
 587         }
 588         return true;
 589 }
 590
 591 static void zconfprint(const char *err, ...)
 592 {
 593         va_list ap;
 594
 595         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 596         va_start(ap, err);
 597         vfprintf(stderr, err, ap);
 598         va_end(ap);
 599         fprintf(stderr, "\n");
 600 }
 601
 602 static void zconf_error(const char *err, ...)
 603 {
 604         va_list ap;
 605
 606         zconfnerrs++;
 607         fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
 608         va_start(ap, err);
 609         vfprintf(stderr, err, ap);
 610         va_end(ap);
 611         fprintf(stderr, "\n");
 612 }
 613
 614 static void zconferror(const char *err)
 615 {
 616         fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
 617 }
 618
 619 static void print_quoted_string(FILE *out, const char *str)
 620 {
 621         const char *p;
 622         int len;
 623
 624         putc('"', out);
 625         while ((p = strchr(str, '"'))) {
 626                 len = p - str;
 627                 if (len)
 628                         fprintf(out, "%.*s", len, str);
 629                 fputs("\\\"", out);
 630                 str = p + 1;
 631         }
 632         fputs(str, out);
 633         putc('"', out);
 634 }
 635
 636 static void print_symbol(FILE *out, struct menu *menu)
 637 {
 638         struct symbol *sym = menu->sym;
 639         struct property *prop;
 640
 641         if (sym_is_choice(sym))
 642                 fprintf(out, "\nchoice\n");
 643         else
 644                 fprintf(out, "\nconfig %s\n", sym->name);
 645         switch (sym->type) {
 646         case S_BOOLEAN:
 647                 fputs("  boolean\n", out);
 648                 break;
 649         case S_TRISTATE:
 650                 fputs("  tristate\n", out);
 651                 break;
 652         case S_STRING:
 653                 fputs("  string\n", out);
 654                 break;
 655         case S_INT:
 656                 fputs("  integer\n", out);
 657                 break;
 658         case S_HEX:
 659                 fputs("  hex\n", out);
 660                 break;
 661         default:
 662                 fputs("  ???\n", out);
 663                 break;
 664         }
 665         for (prop = sym->prop; prop; prop = prop->next) {
 666                 if (prop->menu != menu)
 667                         continue;
 668                 switch (prop->type) {
 669                 case P_PROMPT:
 670                         fputs("  prompt ", out);
 671                         print_quoted_string(out, prop->text);
 672                         if (!expr_is_yes(prop->visible.expr)) {
 673                                 fputs(" if ", out);
 674                                 expr_fprint(prop->visible.expr, out);
 675                         }
 676                         fputc('\n', out);
 677                         break;
 678                 case P_DEFAULT:
 679                         fputs( "  default ", out);
 680                         expr_fprint(prop->expr, out);
 681                         if (!expr_is_yes(prop->visible.expr)) {
 682                                 fputs(" if ", out);
 683                                 expr_fprint(prop->visible.expr, out);
 684                         }
 685                         fputc('\n', out);
 686                         break;
 687                 case P_CHOICE:
 688                         fputs("  #choice value\n", out);
 689                         break;
 690                 case P_SELECT:
 691                         fputs( "  select ", out);
 692                         expr_fprint(prop->expr, out);
 693                         fputc('\n', out);
 694                         break;
 695                 case P_IMPLY:
 696                         fputs( "  imply ", out);
 697                         expr_fprint(prop->expr, out);
 698                         fputc('\n', out);
 699                         break;
 700                 case P_RANGE:
 701                         fputs( "  range ", out);
 702                         expr_fprint(prop->expr, out);
 703                         fputc('\n', out);
 704                         break;
 705                 case P_MENU:
 706                         fputs( "  menu ", out);
 707                         print_quoted_string(out, prop->text);
 708                         fputc('\n', out);
 709                         break;
 710                 default:
 711                         fprintf(out, "  unknown prop %d!\n", prop->type);
 712                         break;
 713                 }
 714         }
 715         if (menu->help) {
 716                 int len = strlen(menu->help);
 717                 while (menu->help[--len] == '\n')
 718                         menu->help[len] = 0;
 719                 fprintf(out, "  help\n%s\n", menu->help);
 720         }
 721 }
 722
 723 void zconfdump(FILE *out)
 724 {
 725         struct property *prop;
 726         struct symbol *sym;
 727         struct menu *menu;
 728
 729         menu = rootmenu.list;
 730         while (menu) {
 731                 if ((sym = menu->sym))
 732                         print_symbol(out, menu);
 733                 else if ((prop = menu->prompt)) {
 734                         switch (prop->type) {
 735                         case P_COMMENT:
 736                                 fputs("\ncomment ", out);
 737                                 print_quoted_string(out, prop->text);
 738                                 fputs("\n", out);
 739                                 break;
 740                         case P_MENU:
 741                                 fputs("\nmenu ", out);
 742                                 print_quoted_string(out, prop->text);
 743                                 fputs("\n", out);
 744                                 break;
 745                         default:
 746                                 ;
 747                         }
 748                         if (!expr_is_yes(prop->visible.expr)) {
 749                                 fputs("  depends ", out);
 750                                 expr_fprint(prop->visible.expr, out);
 751                                 fputc('\n', out);
 752                         }
 753                 }
 754
 755                 if (menu->list)
 756                         menu = menu->list;
 757                 else if (menu->next)
 758                         menu = menu->next;
 759                 else while ((menu = menu->parent)) {
 760                         if (menu->prompt && menu->prompt->type == P_MENU)
 761                                 fputs("\nendmenu\n", out);
 762                         if (menu->next) {
 763                                 menu = menu->next;
 764                                 break;
 765                         }
 766                 }
 767         }
 768 }
 769
 770 #include "zconf.lex.c"
 771 #include "util.c"
 772 #include "confdata.c"
 773 #include "expr.c"
 774 #include "symbol.c"
 775 #include "menu.c"