config/zconf.l

   1 %option nostdinit noyywrap never-interactive full ecs
   2 %option 8bit nodefault yylineno
   3 %x COMMAND HELP STRING PARAM ASSIGN_VAL
   4 %{
   5 /*
   6  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   7  * Released under the terms of the GNU GPL v2.0.
   8  */
   9
  10 #include <assert.h>
  11 #include <limits.h>
  12 #include <stdio.h>
  13 #include <stdlib.h>
  14 #include <string.h>
  15 #include <unistd.h>
  16
  17 #include "lkc.h"
  18
  19 #define YY_DECL         static int yylex1(void)
  20
  21 #define START_STRSIZE   16
  22
  23 static struct {
  24         struct file *file;
  25         int lineno;
  26 } current_pos;
  27
  28 static int prev_token = T_EOL;
  29 static char *text;
  30 static int text_size, text_asize;
  31
  32 struct buffer {
  33         struct buffer *parent;
  34         YY_BUFFER_STATE state;
  35 };
  36
  37 struct buffer *current_buf;
  38
  39 static int last_ts, first_ts;
  40
  41 static char *expand_token(const char *in, size_t n);
  42 static void append_expanded_string(const char *in);
  43 static void zconf_endhelp(void);
  44 static void zconf_endfile(void);
  45
  46 static void new_string(void)
  47 {
  48         text = xmalloc(START_STRSIZE);
  49         text_asize = START_STRSIZE;
  50         text_size = 0;
  51         *text = 0;
  52 }
  53
  54 static void append_string(const char *str, int size)
  55 {
  56         int new_size = text_size + size + 1;
  57         if (new_size > text_asize) {
  58                 new_size += START_STRSIZE - 1;
  59                 new_size &= -START_STRSIZE;
  60                 text = xrealloc(text, new_size);
  61                 text_asize = new_size;
  62         }
  63         memcpy(text + text_size, str, size);
  64         text_size += size;
  65         text[text_size] = 0;
  66 }
  67
  68 static void alloc_string(const char *str, int size)
  69 {
  70         text = xmalloc(size + 1);
  71         memcpy(text, str, size);
  72         text[size] = 0;
  73 }
  74
  75 static void warn_ignored_character(char chr)
  76 {
  77         fprintf(stderr,
  78                 "%s:%d:warning: ignoring unsupported character '%c'\n",
  79                 current_file->name, yylineno, chr);
  80 }
  81 %}
  82
  83 n       [A-Za-z0-9_-]
  84
  85 %%
  86         int str = 0;
  87         int ts, i;
  88
  89 [ \t]*#.*\n     |
  90 [ \t]*\n        {
  91         return T_EOL;
  92 }
  93 [ \t]*#.*
  94 .       {
  95         unput(yytext[0]);
  96         BEGIN(COMMAND);
  97 }
  98
  99
 100 <COMMAND>{
 101         {n}+    {
 102                 const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
 103                 current_pos.file = current_file;
 104                 current_pos.lineno = yylineno;
 105                 if (id && id->flags & TF_COMMAND) {
 106                         BEGIN(PARAM);
 107                         yylval.id = id;
 108                         return id->token;
 109                 }
 110                 alloc_string(yytext, yyleng);
 111                 yylval.string = text;
 112                 return T_VARIABLE;
 113         }
 114         ({n}|$)+        {
 115                 /* this token includes at least one '$' */
 116                 yylval.string = expand_token(yytext, yyleng);
 117                 if (strlen(yylval.string))
 118                         return T_VARIABLE;
 119                 free(yylval.string);
 120         }
 121         "="     { BEGIN(ASSIGN_VAL); yylval.flavor = VAR_RECURSIVE; return T_ASSIGN; }
 122         ":="    { BEGIN(ASSIGN_VAL); yylval.flavor = VAR_SIMPLE; return T_ASSIGN; }
 123         "+="    { BEGIN(ASSIGN_VAL); yylval.flavor = VAR_APPEND; return T_ASSIGN; }
 124         [[:blank:]]+
 125         .       warn_ignored_character(*yytext);
 126         \n      {
 127                 BEGIN(INITIAL);
 128                 return T_EOL;
 129         }
 130 }
 131
 132 <ASSIGN_VAL>{
 133         [^[:blank:]\n]+.*       {
 134                 alloc_string(yytext, yyleng);
 135                 yylval.string = text;
 136                 return T_ASSIGN_VAL;
 137         }
 138         \n      { BEGIN(INITIAL); return T_EOL; }
 139         .
 140 }
 141
 142 <PARAM>{
 143         "&&"    return T_AND;
 144         "||"    return T_OR;
 145         "("     return T_OPEN_PAREN;
 146         ")"     return T_CLOSE_PAREN;
 147         "!"     return T_NOT;
 148         "="     return T_EQUAL;
 149         "!="    return T_UNEQUAL;
 150         "<="    return T_LESS_EQUAL;
 151         ">="    return T_GREATER_EQUAL;
 152         "<"     return T_LESS;
 153         ">"     return T_GREATER;
 154         \"|\'   {
 155                 str = yytext[0];
 156                 new_string();
 157                 BEGIN(STRING);
 158         }
 159         \n      BEGIN(INITIAL); return T_EOL;
 160         ({n}|[/.])+     {
 161                 const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
 162                 if (id && id->flags & TF_PARAM) {
 163                         yylval.id = id;
 164                         return id->token;
 165                 }
 166                 alloc_string(yytext, yyleng);
 167                 yylval.string = text;
 168                 return T_WORD;
 169         }
 170         ({n}|[/.$])+    {
 171                 /* this token includes at least one '$' */
 172                 yylval.string = expand_token(yytext, yyleng);
 173                 if (strlen(yylval.string))
 174                         return T_WORD;
 175                 free(yylval.string);
 176         }
 177         #.*     /* comment */
 178         \\\n    ;
 179         [[:blank:]]+
 180         .       warn_ignored_character(*yytext);
 181         <<EOF>> {
 182                 BEGIN(INITIAL);
 183         }
 184 }
 185
 186 <STRING>{
 187         "$".*   append_expanded_string(yytext);
 188         [^$'"\\\n]+     {
 189                 append_string(yytext, yyleng);
 190         }
 191         \\.?    {
 192                 append_string(yytext + 1, yyleng - 1);
 193         }
 194         \'|\"   {
 195                 if (str == yytext[0]) {
 196                         BEGIN(PARAM);
 197                         yylval.string = text;
 198                         return T_WORD_QUOTE;
 199                 } else
 200                         append_string(yytext, 1);
 201         }
 202         \n      {
 203                 fprintf(stderr,
 204                         "%s:%d:warning: multi-line strings not supported\n",
 205                         zconf_curname(), zconf_lineno());
 206                 unput('\n');
 207                 BEGIN(INITIAL);
 208                 yylval.string = text;
 209                 return T_WORD_QUOTE;
 210         }
 211         <<EOF>> {
 212                 BEGIN(INITIAL);
 213                 yylval.string = text;
 214                 return T_WORD_QUOTE;
 215         }
 216 }
 217
 218 <HELP>{
 219         [ \t]+  {
 220                 ts = 0;
 221                 for (i = 0; i < yyleng; i++) {
 222                         if (yytext[i] == '\t')
 223                                 ts = (ts & ~7) + 8;
 224                         else
 225                                 ts++;
 226                 }
 227                 last_ts = ts;
 228                 if (first_ts) {
 229                         if (ts < first_ts) {
 230                                 zconf_endhelp();
 231                                 return T_HELPTEXT;
 232                         }
 233                         ts -= first_ts;
 234                         while (ts > 8) {
 235                                 append_string("        ", 8);
 236                                 ts -= 8;
 237                         }
 238                         append_string("        ", ts);
 239                 }
 240         }
 241         [ \t]*\n/[^ \t\n] {
 242                 zconf_endhelp();
 243                 return T_HELPTEXT;
 244         }
 245         [ \t]*\n        {
 246                 append_string("\n", 1);
 247         }
 248         [^ \t\n].* {
 249                 while (yyleng) {
 250                         if ((yytext[yyleng-1] != ' ') && (yytext[yyleng-1] != '\t'))
 251                                 break;
 252                         yyleng--;
 253                 }
 254                 append_string(yytext, yyleng);
 255                 if (!first_ts)
 256                         first_ts = last_ts;
 257         }
 258         <<EOF>> {
 259                 zconf_endhelp();
 260                 return T_HELPTEXT;
 261         }
 262 }
 263
 264 <<EOF>> {
 265         if (current_file) {
 266                 zconf_endfile();
 267                 return T_EOL;
 268         }
 269         fclose(yyin);
 270         yyterminate();
 271 }
 272
 273 %%
 274
 275 /* second stage lexer */
 276 int yylex(void)
 277 {
 278         int token;
 279
 280 repeat:
 281         token = yylex1();
 282
 283         /* Do not pass unneeded T_EOL to the parser. */
 284         if ((prev_token == T_EOL || prev_token == T_HELPTEXT) && token == T_EOL)
 285                 goto repeat;
 286
 287         prev_token = token;
 288
 289         return token;
 290 }
 291
 292 static char *expand_token(const char *in, size_t n)
 293 {
 294         char *out;
 295         int c;
 296         char c2;
 297         const char *rest, *end;
 298
 299         new_string();
 300         append_string(in, n);
 301
 302         /* get the whole line because we do not know the end of token. */
 303         while ((c = input()) != EOF) {
 304                 if (c == '\n') {
 305                         unput(c);
 306                         break;
 307                 }
 308                 c2 = c;
 309                 append_string(&c2, 1);
 310         }
 311
 312         rest = text;
 313         out = expand_one_token(&rest);
 314
 315         /* push back unused characters to the input stream */
 316         end = rest + strlen(rest);
 317         while (end > rest)
 318                 unput(*--end);
 319
 320         free(text);
 321
 322         return out;
 323 }
 324
 325 static void append_expanded_string(const char *str)
 326 {
 327         const char *end;
 328         char *res;
 329
 330         str++;
 331
 332         res = expand_dollar(&str);
 333
 334         /* push back unused characters to the input stream */
 335         end = str + strlen(str);
 336         while (end > str)
 337                 unput(*--end);
 338
 339         append_string(res, strlen(res));
 340
 341         free(res);
 342 }
 343
 344 void zconf_starthelp(void)
 345 {
 346         new_string();
 347         last_ts = first_ts = 0;
 348         BEGIN(HELP);
 349 }
 350
 351 static void zconf_endhelp(void)
 352 {
 353         yylval.string = text;
 354         BEGIN(INITIAL);
 355 }
 356
 357
 358 /*
 359  * Try to open specified file with following names:
 360  * ./name
 361  * $(srctree)/name
 362  * The latter is used when srctree is separate from objtree
 363  * when compiling the firmware.
 364  * Return NULL if file is not found.
 365  */
 366 FILE *zconf_fopen(const char *name)
 367 {
 368         char *env, fullname[PATH_MAX+1];
 369         FILE *f;
 370
 371         f = fopen(name, "r");
 372         if (!f && name != NULL && name[0] != '/') {
 373                 env = getenv(SRCTREE);
 374                 if (env) {
 375                         sprintf(fullname, "%s/%s", env, name);
 376                         f = fopen(fullname, "r");
 377                 }
 378         }
 379         return f;
 380 }
 381
 382 void zconf_initscan(const char *name)
 383 {
 384         yyin = zconf_fopen(name);
 385         if (!yyin) {
 386                 fprintf(stderr, "can't find file %s\n", name);
 387                 exit(1);
 388         }
 389
 390         current_buf = xmalloc(sizeof(*current_buf));
 391         memset(current_buf, 0, sizeof(*current_buf));
 392
 393         current_file = file_lookup(name);
 394         yylineno = 1;
 395 }
 396
 397 void zconf_nextfile(const char *name)
 398 {
 399         struct file *iter;
 400         struct file *file = file_lookup(name);
 401         struct buffer *buf = xmalloc(sizeof(*buf));
 402         memset(buf, 0, sizeof(*buf));
 403
 404         current_buf->state = YY_CURRENT_BUFFER;
 405         yyin = zconf_fopen(file->name);
 406         if (!yyin) {
 407                 fprintf(stderr, "%s:%d: can't open file \"%s\"\n",
 408                         zconf_curname(), zconf_lineno(), file->name);
 409                 exit(1);
 410         }
 411         yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
 412         buf->parent = current_buf;
 413         current_buf = buf;
 414
 415         current_file->lineno = yylineno;
 416         file->parent = current_file;
 417
 418         for (iter = current_file; iter; iter = iter->parent) {
 419                 if (!strcmp(iter->name, file->name)) {
 420                         fprintf(stderr,
 421                                 "Recursive inclusion detected.\n"
 422                                 "Inclusion path:\n"
 423                                 "  current file : %s\n", file->name);
 424                         iter = file;
 425                         do {
 426                                 iter = iter->parent;
 427                                 fprintf(stderr, "  included from: %s:%d\n",
 428                                         iter->name, iter->lineno - 1);
 429                         } while (strcmp(iter->name, file->name));
 430                         exit(1);
 431                 }
 432         }
 433
 434         yylineno = 1;
 435         current_file = file;
 436 }
 437
 438 static void zconf_endfile(void)
 439 {
 440         struct buffer *parent;
 441
 442         current_file = current_file->parent;
 443         if (current_file)
 444                 yylineno = current_file->lineno;
 445
 446         parent = current_buf->parent;
 447         if (parent) {
 448                 fclose(yyin);
 449                 yy_delete_buffer(YY_CURRENT_BUFFER);
 450                 yy_switch_to_buffer(parent->state);
 451         }
 452         free(current_buf);
 453         current_buf = parent;
 454 }
 455
 456 int zconf_lineno(void)
 457 {
 458         return current_pos.lineno;
 459 }
 460
 461 const char *zconf_curname(void)
 462 {
 463         return current_pos.file ? current_pos.file->name : "<none>";
 464 }