config/zconf.l

   1 %option nostdinit noyywrap never-interactive full ecs
   2 %option 8bit nodefault yylineno
   3 %x COMMAND HELP STRING PARAM ASSIGN_VAL
   4 %{
   5 /*
   6  * Copyright (C) 2002 Roman Zippel <zippel@linux-m68k.org>
   7  * Released under the terms of the GNU GPL v2.0.
   8  */
   9
  10 #include <assert.h>
  11 #include <limits.h>
  12 #include <stdio.h>
  13 #include <stdlib.h>
  14 #include <string.h>
  15 #include <unistd.h>
  16
  17 #include "lkc.h"
  18
  19 #define YY_DECL         static int yylex1(void)
  20
  21 #define START_STRSIZE   16
  22
  23 static struct {
  24         struct file *file;
  25         int lineno;
  26 } current_pos;
  27
  28 static int prev_token = T_EOL;
  29 static char *text;
  30 static int text_size, text_asize;
  31
  32 struct buffer {
  33         struct buffer *parent;
  34         YY_BUFFER_STATE state;
  35 };
  36
  37 struct buffer *current_buf;
  38
  39 static int last_ts, first_ts;
  40
  41 static char *expand_token(const char *in, size_t n);
  42 static void append_expanded_string(const char *in);
  43 static void zconf_endhelp(void);
  44 static void zconf_endfile(void);
  45
  46 static void new_string(void)
  47 {
  48         text = xmalloc(START_STRSIZE);
  49         text_asize = START_STRSIZE;
  50         text_size = 0;
  51         *text = 0;
  52 }
  53
  54 static void append_string(const char *str, int size)
  55 {
  56         int new_size = text_size + size + 1;
  57         if (new_size > text_asize) {
  58                 new_size += START_STRSIZE - 1;
  59                 new_size &= -START_STRSIZE;
  60                 text = xrealloc(text, new_size);
  61                 text_asize = new_size;
  62         }
  63         memcpy(text + text_size, str, size);
  64         text_size += size;
  65         text[text_size] = 0;
  66 }
  67
  68 static void alloc_string(const char *str, int size)
  69 {
  70         text = xmalloc(size + 1);
  71         memcpy(text, str, size);
  72         text[size] = 0;
  73 }
  74
  75 static void warn_ignored_character(char chr)
  76 {
  77         fprintf(stderr,
  78                 "%s:%d:warning: ignoring unsupported character '%c'\n",
  79                 current_file->name, yylineno, chr);
  80 }
  81 %}
  82
  83 n       [A-Za-z0-9_-]
  84
  85 %%
  86         int str = 0;
  87         int ts, i;
  88
  89 [ \t]*#.*\n     |
  90 [ \t]*\n        {
  91         return T_EOL;
  92 }
  93 [ \t]*#.*
  94 .       {
  95         unput(yytext[0]);
  96         BEGIN(COMMAND);
  97 }
  98
  99
 100 <COMMAND>{
 101         {n}+    {
 102                 const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
 103                 current_pos.file = current_file;
 104                 current_pos.lineno = yylineno;
 105                 if (id && id->flags & TF_COMMAND) {
 106                         BEGIN(PARAM);
 107                         yylval.id = id;
 108                         return id->token;
 109                 }
 110                 alloc_string(yytext, yyleng);
 111                 yylval.string = text;
 112                 return T_VARIABLE;
 113         }
 114         ({n}|$)+        {
 115                 /* this token includes at least one '$' */
 116                 yylval.string = expand_token(yytext, yyleng);
 117                 if (strlen(yylval.string))
 118                         return T_VARIABLE;
 119                 free(yylval.string);
 120         }
 121         "="     { BEGIN(ASSIGN_VAL); yylval.flavor = VAR_RECURSIVE; return T_ASSIGN; }
 122         ":="    { BEGIN(ASSIGN_VAL); yylval.flavor = VAR_SIMPLE; return T_ASSIGN; }
 123         "+="    { BEGIN(ASSIGN_VAL); yylval.flavor = VAR_APPEND; return T_ASSIGN; }
 124         [[:blank:]]+
 125         .       warn_ignored_character(*yytext);
 126         \n      {
 127                 BEGIN(INITIAL);
 128                 return T_EOL;
 129         }
 130 }
 131
 132 <ASSIGN_VAL>{
 133         [^[:blank:]\n]+.*       {
 134                 alloc_string(yytext, yyleng);
 135                 yylval.string = text;
 136                 return T_ASSIGN_VAL;
 137         }
 138         \n      { BEGIN(INITIAL); return T_EOL; }
 139         .
 140 }
 141
 142 <PARAM>{
 143         "&&"    return T_AND;
 144         "||"    return T_OR;
 145         "("     return T_OPEN_PAREN;
 146         ")"     return T_CLOSE_PAREN;
 147         "!"     return T_NOT;
 148         "="     return T_EQUAL;
 149         "!="    return T_UNEQUAL;
 150         "<="    return T_LESS_EQUAL;
 151         ">="    return T_GREATER_EQUAL;
 152         "<"     return T_LESS;
 153         ">"     return T_GREATER;
 154         \"|\'   {
 155                 str = yytext[0];
 156                 new_string();
 157                 BEGIN(STRING);
 158         }
 159         \n      BEGIN(INITIAL); return T_EOL;
 160         ({n}|[/.])+     {
 161                 const struct kconf_id *id = kconf_id_lookup(yytext, yyleng);
 162                 if (id && id->flags & TF_PARAM) {
 163                         yylval.id = id;
 164                         return id->token;
 165                 }
 166                 alloc_string(yytext, yyleng);
 167                 yylval.string = text;
 168                 return T_WORD;
 169         }
 170         ({n}|[/.$])+    {
 171                 /* this token includes at least one '$' */
 172                 yylval.string = expand_token(yytext, yyleng);
 173                 if (strlen(yylval.string))
 174                         return T_WORD;
 175                 free(yylval.string);
 176         }
 177         #.*     /* comment */
 178         \\\n    ;
 179         [[:blank:]]+
 180         .       warn_ignored_character(*yytext);
 181 }
 182
 183 <STRING>{
 184         "$".*   append_expanded_string(yytext);
 185         [^$'"\\\n]+     {
 186                 append_string(yytext, yyleng);
 187         }
 188         \\.?    {
 189                 append_string(yytext + 1, yyleng - 1);
 190         }
 191         \'|\"   {
 192                 if (str == yytext[0]) {
 193                         BEGIN(PARAM);
 194                         yylval.string = text;
 195                         return T_WORD_QUOTE;
 196                 } else
 197                         append_string(yytext, 1);
 198         }
 199         \n      {
 200                 fprintf(stderr,
 201                         "%s:%d:warning: multi-line strings not supported\n",
 202                         zconf_curname(), zconf_lineno());
 203                 unput('\n');
 204                 BEGIN(INITIAL);
 205                 yylval.string = text;
 206                 return T_WORD_QUOTE;
 207         }
 208         <<EOF>> {
 209                 BEGIN(INITIAL);
 210                 yylval.string = text;
 211                 return T_WORD_QUOTE;
 212         }
 213 }
 214
 215 <HELP>{
 216         [ \t]+  {
 217                 ts = 0;
 218                 for (i = 0; i < yyleng; i++) {
 219                         if (yytext[i] == '\t')
 220                                 ts = (ts & ~7) + 8;
 221                         else
 222                                 ts++;
 223                 }
 224                 last_ts = ts;
 225                 if (first_ts) {
 226                         if (ts < first_ts) {
 227                                 zconf_endhelp();
 228                                 return T_HELPTEXT;
 229                         }
 230                         ts -= first_ts;
 231                         while (ts > 8) {
 232                                 append_string("        ", 8);
 233                                 ts -= 8;
 234                         }
 235                         append_string("        ", ts);
 236                 }
 237         }
 238         [ \t]*\n/[^ \t\n] {
 239                 zconf_endhelp();
 240                 return T_HELPTEXT;
 241         }
 242         [ \t]*\n        {
 243                 append_string("\n", 1);
 244         }
 245         [^ \t\n].* {
 246                 while (yyleng) {
 247                         if ((yytext[yyleng-1] != ' ') && (yytext[yyleng-1] != '\t'))
 248                                 break;
 249                         yyleng--;
 250                 }
 251                 append_string(yytext, yyleng);
 252                 if (!first_ts)
 253                         first_ts = last_ts;
 254         }
 255         <<EOF>> {
 256                 zconf_endhelp();
 257                 return T_HELPTEXT;
 258         }
 259 }
 260
 261 <<EOF>> {
 262         BEGIN(INITIAL);
 263
 264         if (current_file) {
 265                 zconf_endfile();
 266                 return T_EOL;
 267         }
 268         fclose(yyin);
 269         yyterminate();
 270 }
 271
 272 %%
 273
 274 /* second stage lexer */
 275 int yylex(void)
 276 {
 277         int token;
 278
 279 repeat:
 280         token = yylex1();
 281
 282         /* Do not pass unneeded T_EOL to the parser. */
 283         if ((prev_token == T_EOL || prev_token == T_HELPTEXT) && token == T_EOL)
 284                 goto repeat;
 285
 286         prev_token = token;
 287
 288         return token;
 289 }
 290
 291 static char *expand_token(const char *in, size_t n)
 292 {
 293         char *out;
 294         int c;
 295         char c2;
 296         const char *rest, *end;
 297
 298         new_string();
 299         append_string(in, n);
 300
 301         /* get the whole line because we do not know the end of token. */
 302         while ((c = input()) != EOF) {
 303                 if (c == '\n') {
 304                         unput(c);
 305                         break;
 306                 }
 307                 c2 = c;
 308                 append_string(&c2, 1);
 309         }
 310
 311         rest = text;
 312         out = expand_one_token(&rest);
 313
 314         /* push back unused characters to the input stream */
 315         end = rest + strlen(rest);
 316         while (end > rest)
 317                 unput(*--end);
 318
 319         free(text);
 320
 321         return out;
 322 }
 323
 324 static void append_expanded_string(const char *str)
 325 {
 326         const char *end;
 327         char *res;
 328
 329         str++;
 330
 331         res = expand_dollar(&str);
 332
 333         /* push back unused characters to the input stream */
 334         end = str + strlen(str);
 335         while (end > str)
 336                 unput(*--end);
 337
 338         append_string(res, strlen(res));
 339
 340         free(res);
 341 }
 342
 343 void zconf_starthelp(void)
 344 {
 345         new_string();
 346         last_ts = first_ts = 0;
 347         BEGIN(HELP);
 348 }
 349
 350 static void zconf_endhelp(void)
 351 {
 352         yylval.string = text;
 353         BEGIN(INITIAL);
 354 }
 355
 356
 357 /*
 358  * Try to open specified file with following names:
 359  * ./name
 360  * $(srctree)/name
 361  * The latter is used when srctree is separate from objtree
 362  * when compiling the firmware.
 363  * Return NULL if file is not found.
 364  */
 365 FILE *zconf_fopen(const char *name)
 366 {
 367         char *env, fullname[PATH_MAX+1];
 368         FILE *f;
 369
 370         f = fopen(name, "r");
 371         if (!f && name != NULL && name[0] != '/') {
 372                 env = getenv(SRCTREE);
 373                 if (env) {
 374                         sprintf(fullname, "%s/%s", env, name);
 375                         f = fopen(fullname, "r");
 376                 }
 377         }
 378         return f;
 379 }
 380
 381 void zconf_initscan(const char *name)
 382 {
 383         yyin = zconf_fopen(name);
 384         if (!yyin) {
 385                 fprintf(stderr, "can't find file %s\n", name);
 386                 exit(1);
 387         }
 388
 389         current_buf = xmalloc(sizeof(*current_buf));
 390         memset(current_buf, 0, sizeof(*current_buf));
 391
 392         current_file = file_lookup(name);
 393         yylineno = 1;
 394 }
 395
 396 void zconf_nextfile(const char *name)
 397 {
 398         struct file *iter;
 399         struct file *file = file_lookup(name);
 400         struct buffer *buf = xmalloc(sizeof(*buf));
 401         memset(buf, 0, sizeof(*buf));
 402
 403         current_buf->state = YY_CURRENT_BUFFER;
 404         yyin = zconf_fopen(file->name);
 405         if (!yyin) {
 406                 fprintf(stderr, "%s:%d: can't open file \"%s\"\n",
 407                         zconf_curname(), zconf_lineno(), file->name);
 408                 exit(1);
 409         }
 410         yy_switch_to_buffer(yy_create_buffer(yyin, YY_BUF_SIZE));
 411         buf->parent = current_buf;
 412         current_buf = buf;
 413
 414         current_file->lineno = yylineno;
 415         file->parent = current_file;
 416
 417         for (iter = current_file; iter; iter = iter->parent) {
 418                 if (!strcmp(iter->name, file->name)) {
 419                         fprintf(stderr,
 420                                 "Recursive inclusion detected.\n"
 421                                 "Inclusion path:\n"
 422                                 "  current file : %s\n", file->name);
 423                         iter = file;
 424                         do {
 425                                 iter = iter->parent;
 426                                 fprintf(stderr, "  included from: %s:%d\n",
 427                                         iter->name, iter->lineno - 1);
 428                         } while (strcmp(iter->name, file->name));
 429                         exit(1);
 430                 }
 431         }
 432
 433         yylineno = 1;
 434         current_file = file;
 435 }
 436
 437 static void zconf_endfile(void)
 438 {
 439         struct buffer *parent;
 440
 441         current_file = current_file->parent;
 442         if (current_file)
 443                 yylineno = current_file->lineno;
 444
 445         parent = current_buf->parent;
 446         if (parent) {
 447                 fclose(yyin);
 448                 yy_delete_buffer(YY_CURRENT_BUFFER);
 449                 yy_switch_to_buffer(parent->state);
 450         }
 451         free(current_buf);
 452         current_buf = parent;
 453 }
 454
 455 int zconf_lineno(void)
 456 {
 457         return current_pos.lineno;
 458 }
 459
 460 const char *zconf_curname(void)
 461 {
 462         return current_pos.file ? current_pos.file->name : "<none>";
 463 }