eightsync/agenda.scm

   1 ;; Copyright (C) 2015 Christopher Allan Webber <cwebber@dustycloud.org>
   2
   3 ;; This library is free software; you can redistribute it and/or
   4 ;; modify it under the terms of the GNU Lesser General Public
   5 ;; License as published by the Free Software Foundation; either
   6 ;; version 3 of the License, or (at your option) any later version.
   7 ;;
   8 ;; This library is distributed in the hope that it will be useful,
   9 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11 ;; Lesser General Public License for more details.
  12 ;;
  13 ;; You should have received a copy of the GNU Lesser General Public
  14 ;; License along with this library; if not, write to the Free Software
  15 ;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  16 ;; 02110-1301 USA
  17
  18 (define-module (eightsync agenda)
  19   #:use-module (srfi srfi-1)
  20   #:use-module (srfi srfi-9)
  21   #:use-module (srfi srfi-9 gnu)
  22   #:use-module (ice-9 q)
  23   #:use-module (ice-9 match)
  24   #:use-module (ice-9 receive)
  25   #:export (<agenda>
  26             make-agenda agenda?
  27             agenda-queue agenda-prompt-tag
  28             agenda-read-port-map agenda-write-port-map agenda-except-port-map
  29             agenda-schedule
  30
  31             make-async-prompt-tag
  32
  33             <time-segment>
  34             make-time-segment time-segment?
  35             time-segment-time time-segment-queue
  36
  37             time< time= time<= time-delta+
  38             time-minus time-plus
  39
  40             <time-delta>
  41             make-time-delta tdelta time-delta?
  42             time-delta-sec time-delta-usec
  43
  44             <schedule>
  45             make-schedule schedule?
  46             schedule-add! schedule-empty?
  47             schedule-segments
  48             schedule-soonest-time
  49
  50             schedule-segments-split schedule-extract-until!
  51             add-segments-contents-to-queue!
  52
  53             %8sync
  54
  55             <run-request>
  56             make-run-request run-request?
  57             run-request-proc run-request-when
  58
  59             <port-request>
  60             make-port-request port-request port-request?
  61             port-request-port
  62             port-request-read port-request-write port-request-except
  63
  64             run-it wrap wrap-apply run run-at run-delay
  65
  66             %port-request %run %run-at %run-delay
  67
  68             catch-8sync catch-%8sync
  69
  70             ;; used for introspecting the error, but a method for making
  71             ;; is not exposed
  72             wrapped-exception?
  73             wrapped-exception-key wrapped-exception-args
  74             wrapped-exception-stacks
  75
  76             print-error-and-continue
  77
  78             %current-agenda
  79             start-agenda agenda-run-once))
  80
  81 ;; @@: Using immutable agendas here, so wouldn't it make sense to
  82 ;;   replace this queue stuff with using pfds based immutable queues?
  83
  84 \f
  85 ;;; Agenda definition
  86 ;;; =================
  87
  88 ;;; The agenda consists of:
  89 ;;;  - a queue of immediate items to handle
  90 ;;;  - sheduled future events to be added to a future queue
  91 ;;;  - a tag by which running processes can escape for some asynchronous
  92 ;;;    operation (from which they can be returned later)
  93 ;;;  - a mapping of ports to various handler procedures
  94 ;;;
  95 ;;; The goal, eventually, is for this all to be immutable and functional.
  96 ;;; However, we aren't there yet.  Some tricky things:
  97 ;;;  - The schedule needs to be immutable, yet reasonably efficient.
  98 ;;;  - Need to use immutable queues (ijp's pfds library?)
  99 ;;;  - Modeling reading from ports as something repeatable,
 100 ;;;    and with reasonable separation from functional components?
 101
 102 (define-immutable-record-type <agenda>
 103   (make-agenda-intern queue prompt-tag
 104                       read-port-map write-port-map except-port-map
 105                       schedule time catch-handler pre-unwind-handler)
 106   agenda?
 107   (queue agenda-queue)
 108   (prompt-tag agenda-prompt-tag)
 109   (read-port-map agenda-read-port-map)
 110   (write-port-map agenda-write-port-map)
 111   (except-port-map agenda-except-port-map)
 112   (schedule agenda-schedule)
 113   (time agenda-time)
 114   (catch-handler agenda-catch-handler)
 115   (pre-unwind-handler agenda-pre-unwind-handler))
 116
 117 (define (make-async-prompt-tag)
 118   "Make an async prompt tag for an agenda.
 119
 120 Generally done automatically for the user through (make-agenda)."
 121   (make-prompt-tag "prompt"))
 122
 123 (define* (make-agenda #:key
 124                       (queue (make-q))
 125                       (prompt (make-prompt-tag))
 126                       (read-port-map (make-hash-table))
 127                       (write-port-map (make-hash-table))
 128                       (except-port-map (make-hash-table))
 129                       (schedule (make-schedule))
 130                       (time (gettimeofday))
 131                       (catch-handler #f)
 132                       (pre-unwind-handler #f))
 133   ;; TODO: document arguments
 134   "Make a fresh agenda."
 135   (make-agenda-intern queue prompt
 136                       read-port-map write-port-map except-port-map
 137                       schedule time
 138                       catch-handler pre-unwind-handler))
 139
 140 (define (current-agenda-prompt)
 141   "Get the prompt for the current agenda; signal an error if there isn't one."
 142   (let ((current-agenda (%current-agenda)))
 143     (if (not current-agenda)
 144         (throw
 145          'no-current-agenda
 146          "Can't get current agenda prompt if there's no current agenda!")
 147         (agenda-prompt-tag current-agenda))))
 148
 149
 150 \f
 151 ;;; Schedule
 152 ;;; ========
 153
 154 ;;; This is where we handle timed events for the future
 155
 156 ;; This section totally borrows from the ideas in SICP
 157 ;; <3 <3 <3
 158
 159 ;; NOTE: time is a cons of (seconds . microseconds)
 160
 161 (define-record-type <time-segment>
 162   (make-time-segment-intern time queue)
 163   time-segment?
 164   (time time-segment-time)
 165   (queue time-segment-queue))
 166
 167 ;; @@: This seems to be the same as srfi-18's seconds->time procedure?
 168 ;;   Maybe double check and switch to that?  (Thanks amz3!)
 169
 170 (define (time-from-float-or-fraction time)
 171   "Produce a (sec . usec) pair from TIME, a float or fraction"
 172   (let* ((mixed-whole (floor time))
 173          (mixed-rest (- time mixed-whole))  ; float or fraction component
 174          (sec mixed-whole)
 175          (usec (floor (* 1000000 mixed-rest))))
 176     (cons (inexact->exact sec) (inexact->exact usec))))
 177
 178 (define (time-segment-right-format time)
 179   "Ensure TIME is in the right format.
 180
 181 The right format means (second . microsecond).
 182 If an integer, will convert appropriately."
 183   ;; TODO: add floating point / rational number support.
 184   (match time
 185     ;; time is already a cons of second and microsecnd
 186     (((? integer? s) . (? integer? u)) time)
 187     ;; time was just an integer (just the second)
 188     ((? integer? _) (cons time 0))
 189     ((or (? rational? _) (? inexact? _))
 190      (time-from-float-or-fraction time))
 191     (_ (throw 'invalid-time "Invalid time" time))))
 192
 193 (define* (make-time-segment time #:optional (queue (make-q)))
 194   "Make a time segment of TIME and QUEUE
 195
 196 No automatic conversion is done, so you might have to
 197 run (time-segment-right-format) first."
 198   (make-time-segment-intern time queue))
 199
 200 (define (time< time1 time2)
 201   "Check if TIME1 is less than TIME2"
 202   (cond ((< (car time1)
 203             (car time2))
 204          #t)
 205         ((and (= (car time1)
 206                  (car time2))
 207               (< (cdr time1)
 208                  (cdr time2)))
 209          #t)
 210         (else #f)))
 211
 212 (define (time= time1 time2)
 213   "Check whether TIME1 and TIME2 are equivalent"
 214   (and (= (car time1) (car time2))
 215        (= (cdr time1) (cdr time2))))
 216
 217 (define (time<= time1 time2)
 218   "Check if TIME1 is less than or equal to TIME2"
 219   (or (time< time1 time2)
 220       (time= time1 time2)))
 221
 222
 223 (define-record-type <time-delta>
 224   (make-time-delta-intern sec usec)
 225   time-delta?
 226   (sec time-delta-sec)
 227   (usec time-delta-usec))
 228
 229 (define* (make-time-delta time)
 230   "Make a <time-delta> of SEC seconds and USEC microseconds.
 231
 232 This is used primarily so the agenda can recognize RUN-REQUEST objects
 233 which are meant to delay computation"
 234   (match (time-segment-right-format time)
 235     ((sec . usec)
 236      (make-time-delta-intern sec usec))))
 237
 238 (define tdelta make-time-delta)
 239
 240 (define (time-carry-correct time)
 241   "Corrects/handles time microsecond carry.
 242 Will produce (0 . 0) instead of a negative number, if needed."
 243   (cond ((>= (cdr time) 1000000)
 244          (cons
 245           (+ (car time) 1)
 246           (- (cdr time) 1000000)))
 247         ((< (cdr time) 0)
 248          (if (= (car time) 0)
 249              '(0 0)
 250              (cons
 251               (- (car time) 1)
 252               (+ (cdr time) 1000000))))
 253         (else time)))
 254
 255 (define (time-delta+ time time-delta)
 256   "Increment a TIME by the value of TIME-DELTA"
 257   (time-carry-correct
 258    (cons (+ (car time) (time-delta-sec time-delta))
 259          (+ (cdr time) (time-delta-usec time-delta)))))
 260
 261 (define (time-minus time1 time2)
 262   "Subtract TIME2 from TIME1"
 263   (time-carry-correct
 264    (cons (- (car time1) (car time2))
 265          (- (cdr time1) (cdr time2)))))
 266
 267 (define (time-plus time1 time2)
 268   "Add TIME1 and TIME2"
 269   (time-carry-correct
 270    (cons (+ (car time1) (car time2))
 271          (+ (cdr time1) (cdr time2)))))
 272
 273
 274 (define-record-type <schedule>
 275   (make-schedule-intern segments)
 276   schedule?
 277   (segments schedule-segments set-schedule-segments!))
 278
 279 (define* (make-schedule #:optional segments)
 280   "Make a schedule, optionally pre-composed of SEGMENTS"
 281   (make-schedule-intern (or segments '())))
 282
 283 (define (schedule-soonest-time schedule)
 284   "Return a cons of (sec . usec) for next time segement, or #f if none"
 285   (let ((segments (schedule-segments schedule)))
 286     (if (eq? segments '())
 287         #f
 288         (time-segment-time (car segments)))))
 289
 290 ;; TODO: This code is reasonably easy to read but it
 291 ;;   mutates AND is worst case of O(n) in both space and time :(
 292 ;;   but at least it'll be reasonably easy to refactor to
 293 ;;   a more functional setup?
 294 (define (schedule-add! schedule time proc)
 295   "Mutate SCHEDULE, adding PROC at an appropriate time segment for TIME"
 296   (let ((time (time-segment-right-format time)))
 297     (define (new-time-segment)
 298       (let ((new-segment
 299              (make-time-segment time)))
 300         (enq! (time-segment-queue new-segment) proc)
 301         new-segment))
 302     (define (loop segments)
 303       (define (segment-equals-time? segment)
 304         (time= time (time-segment-time segment)))
 305
 306       (define (segment-more-than-time? segment)
 307         (time< time (time-segment-time segment)))
 308
 309       ;; We could switch this out to be more mutate'y
 310       ;; and avoid the O(n) of space... is that over-optimizing?
 311       (match segments
 312         ;; If we're at the end of the list, time to make a new
 313         ;; segment...
 314         ('() (cons (new-time-segment) '()))
 315         ;; If the segment's time is exactly our time, good news
 316         ;; everyone!  Let's append our stuff to its queue
 317         (((? segment-equals-time? first) rest ...)
 318          (enq! (time-segment-queue first) proc)
 319          segments)
 320         ;; If the first segment is more than our time,
 321         ;; ours belongs before this one, so add it and
 322         ;; start consing our way back
 323         (((? segment-more-than-time? first) rest ...)
 324          (cons (new-time-segment) segments))
 325         ;; Otherwise, build up recursive result
 326         ((first rest ... )
 327          (cons first (loop rest)))))
 328     (set-schedule-segments!
 329      schedule
 330      (loop (schedule-segments schedule)))))
 331
 332 (define (schedule-empty? schedule)
 333   "Check if the SCHEDULE is currently empty"
 334   (eq? (schedule-segments schedule) '()))
 335
 336 (define (schedule-segments-split schedule time)
 337   "Does a multiple value return of time segments before/at and after TIME"
 338   (let ((time (time-segment-right-format time)))
 339     (define (segment-is-now? segment)
 340       (time= (time-segment-time segment) time))
 341     (define (segment-is-before-now? segment)
 342       (time< (time-segment-time segment) time))
 343
 344     (let loop ((segments-before '())
 345                (segments-left (schedule-segments schedule)))
 346       (match segments-left
 347         ;; end of the line, return
 348         ('()
 349          (values (reverse segments-before) '()))
 350
 351         ;; It's right now, so time to stop, but include this one in before
 352         ;; but otherwise return
 353         (((? segment-is-now? first) rest ...)
 354          (values (reverse (cons first segments-before)) rest))
 355
 356         ;; This is prior or at now, so add it and keep going
 357         (((? segment-is-before-now? first) rest ...)
 358          (loop (cons first segments-before) rest))
 359
 360         ;; Otherwise it's past now, just return what we have
 361         (segments-after
 362          (values segments-before segments-after))))))
 363
 364 (define (schedule-extract-until! schedule time)
 365   "Extract all segments until TIME from SCHEDULE, and pop old segments off"
 366   (receive (segments-before segments-after)
 367       (schedule-segments-split schedule time)
 368     (set-schedule-segments! schedule segments-after)
 369     segments-before))
 370
 371 (define (add-segments-contents-to-queue! segments queue)
 372   (for-each
 373    (lambda (segment)
 374      (let ((seg-queue (time-segment-queue segment)))
 375        (while (not (q-empty? seg-queue))
 376          (enq! queue (deq! seg-queue)))))
 377    segments))
 378
 379
 380 \f
 381 ;;; Request to run stuff
 382 ;;; ====================
 383
 384 (define-record-type <run-request>
 385   (make-run-request proc when)
 386   run-request?
 387   (proc run-request-proc)
 388   (when run-request-when))
 389
 390 (define* (run-it proc #:optional when)
 391   "Make a request to run PROC (possibly at WHEN)"
 392   (make-run-request proc when))
 393
 394 (define-syntax-rule (wrap body ...)
 395   "Wrap contents in a procedure"
 396   (lambda ()
 397     body ...))
 398
 399 (define-syntax-rule (wrap-apply body)
 400   "Wrap possibly multi-value function in a procedure, applies all arguments"
 401   (lambda args
 402     (apply body args)))
 403
 404
 405 ;; @@: Do we really want `body ...' here?
 406 ;;   what about just `body'?
 407 (define-syntax-rule (run body ...)
 408   "Run everything in BODY but wrap in a convenient procedure"
 409   (make-run-request (wrap body ...) #f))
 410
 411 (define-syntax-rule (run-at body ... when)
 412   "Run BODY at WHEN"
 413   (make-run-request (wrap body ...) when))
 414
 415 ;; @@: Is it okay to overload the term "delay" like this?
 416 ;;   Would `run-in' be better?
 417 (define-syntax-rule (run-delay body ... delay-time)
 418   "Run BODY at DELAY-TIME time from now"
 419   (make-run-request (wrap body ...) (tdelta delay-time)))
 420
 421
 422 ;; A request to set up a port with at least one of read, write, except
 423 ;; handling processes
 424
 425 (define-record-type <port-request>
 426   (make-port-request-intern port read write except)
 427   port-request?
 428   (port port-request-port)
 429   (read port-request-read)
 430   (write port-request-write)
 431   (except port-request-except))
 432
 433 (define* (make-port-request port #:key read write except)
 434   (if (not (or read write except))
 435       (throw 'no-port-handler-given "No port handler given.\n"))
 436   (make-port-request-intern port read write except))
 437
 438 (define port-request make-port-request)
 439
 440
 441 \f
 442 ;;; Asynchronous escape to run things
 443 ;;; =================================
 444
 445 (define-syntax-rule (%8sync async-request)
 446   "Run BODY asynchronously at a prompt, passing args to make-future.
 447
 448 Runs things asynchronously (8synchronously?)"
 449   (propagate-%async-exceptions
 450    (abort-to-prompt (current-agenda-prompt)
 451                     async-request)))
 452
 453 ;; Async port request and run-request meta-requests
 454 (define (make-async-request proc)
 455   "Wrap PROC in an async-request
 456
 457 The purpose of this is to make sure that users don't accidentally
 458 return the wrong thing via (%8sync) and trip themselves up."
 459   (cons '*async-request* proc))
 460
 461 (define (setup-async-request resume-kont async-request)
 462   "Complete an async request for agenda-run-once's continuation handling"
 463   (match async-request
 464     (('*async-request* . async-setup-proc)
 465      (async-setup-proc resume-kont))
 466     ;; TODO: deliver more helpful errors depending on what the user
 467     ;;   returned
 468     (_ (throw 'invalid-async-request
 469               "Invalid request passed back via an (%8sync) procedure."
 470               async-request))))
 471
 472 (define-record-type <wrapped-exception>
 473   (make-wrapped-exception key args stacks)
 474   wrapped-exception?
 475   (key wrapped-exception-key)
 476   (args wrapped-exception-args)
 477   (stacks wrapped-exception-stacks))
 478
 479 (define-syntax-rule (propagate-%async-exceptions body)
 480   (let ((body-result body))
 481     (if (wrapped-exception? body-result)
 482         (throw '8sync-caught-error
 483                (wrapped-exception-key body-result)
 484                (wrapped-exception-args body-result)
 485                (wrapped-exception-stacks body-result))
 486         body-result)))
 487
 488 (define-syntax-rule (%run body ...)
 489   (%run-at body ... #f))
 490
 491 (define-syntax-rule (%run-at body ... when)
 492   ;; Send an asynchronous request to apply a continuation to the
 493   ;; following function, then handle that as a request to the agenda
 494   (make-async-request
 495    (lambda (kont)
 496      ;; We're making a run request
 497      (make-run-request
 498       ;; Wrapping the following execution to run...
 499       (wrap
 500        ;; Once we get the result from the inner part, we'll resume
 501        ;; this continuation, but first
 502        ;; @@: Is this running immediately, or queueing the result
 503        ;;   after evaluation for the next agenda tick?  It looks
 504        ;;   like evaluating immediately.  Is that what we want?
 505        (kont
 506         ;; Any unhandled errors are caught
 507         (let ((exception-stack #f))
 508           (catch #t
 509             ;; Run the actual code the user requested
 510             (lambda ()
 511               body ...)
 512             ;; If something bad happened and we didn't catch it,
 513             ;; we'll wrap it up in such a way that the continuation
 514             ;; can address it
 515             (lambda (key . args)
 516               (cond
 517                ((eq? key '8sync-caught-error)
 518                 (match args
 519                   ((orig-key orig-args orig-stacks)
 520                    (make-wrapped-exception
 521                     orig-key orig-args
 522                     (cons exception-stack orig-stacks)))))
 523                (else
 524                 (make-wrapped-exception key args
 525                                         (list exception-stack)))))
 526             (lambda _
 527               (set! exception-stack (make-stack #t 1 0)))))))
 528       when))))
 529
 530 (define-syntax-rule (%run-delay body ... delay-time)
 531   (%run-at body ... (tdelta delay-time)))
 532
 533 (define-syntax-rule (%port-request add-this-port port-request-args ...)
 534   (make-async-request
 535    (lambda (kont)
 536      (list (make-port-request port-request-args ...)
 537            (make-run-request kont)))))
 538
 539 ;; TODO
 540 (define-syntax-rule (%run-with-return return body ...)
 541   (make-async-request
 542    (lambda (kont)
 543      (let ((return kont))
 544        (lambda ()
 545          body ...)))))
 546
 547 (define-syntax-rule (catch-8sync exp (handler-key handler) ...)
 548   (catch '8sync-caught-error
 549     (lambda ()
 550       exp)
 551     (lambda (_ orig-key orig-args orig-stacks)
 552       (cond
 553        ((or (eq? handler-key #t)
 554             (eq? orig-key handler-key))
 555         (apply handler orig-stacks orig-args)) ...
 556        (else (raise '8sync-caught-error
 557                     orig-key orig-args orig-stacks))))))
 558
 559 ;; Alias...?
 560 (define-syntax-rule (catch-%8sync rest ...)
 561   (catch-8sync rest ...))
 562
 563
 564 \f
 565 ;;; Execution of agenda, and current agenda
 566 ;;; =======================================
 567
 568 (define %current-agenda (make-parameter #f))
 569
 570 (define (update-agenda-from-select! agenda)
 571   "Potentially (select) on ports specified in agenda, adding items to queue"
 572   (define (hash-keys hash)
 573     (hash-map->list (lambda (k v) k) hash))
 574   (define (get-wait-time)
 575     ;; TODO: we need to figure this out based on whether there's anything
 576     ;;   in the queue, and if not, how long till the next scheduled item
 577     (let ((soonest-time (schedule-soonest-time (agenda-schedule agenda))))
 578       (cond
 579        ((not (q-empty? (agenda-queue agenda)))
 580         (cons 0 0))
 581        (soonest-time    ; ie, the agenda is non-empty
 582         (let* ((current-time (agenda-time agenda)))
 583           (if (time<= soonest-time current-time)
 584               ;; Well there's something due so let's select
 585               ;; (this avoids a (possible?) race condition chance)
 586               (cons 0 0)
 587               (time-minus soonest-time current-time))))
 588        (else
 589         (cons #f #f)))))
 590   (define (do-select)
 591     ;; TODO: support usecond wait time too
 592     (match (get-wait-time)
 593       ((sec . usec)
 594        (catch 'system-error
 595          (lambda ()
 596            (select (hash-keys (agenda-read-port-map agenda))
 597                    (hash-keys (agenda-write-port-map agenda))
 598                    (hash-keys (agenda-except-port-map agenda))
 599                    sec usec))
 600          (lambda (key . rest-args)
 601            (match rest-args
 602              ((_ _ _ (EINTR))
 603               '(() () ()))
 604              (_ (error "Unhandled error in select!" key rest-args))))))))
 605   (define (get-procs-to-run)
 606     (define (ports->procs ports port-map)
 607       (lambda (initial-procs)
 608         (fold
 609          (lambda (port prev)
 610            (cons (lambda ()
 611                    ((hash-ref port-map port) port))
 612                  prev))
 613          initial-procs
 614          ports)))
 615     (match (do-select)
 616       ((read-ports write-ports except-ports)
 617        ;; @@: Come on, we can do better than append ;P
 618        ((compose (ports->procs
 619                   read-ports
 620                   (agenda-read-port-map agenda))
 621                  (ports->procs
 622                   write-ports
 623                   (agenda-write-port-map agenda))
 624                  (ports->procs
 625                   except-ports
 626                   (agenda-except-port-map agenda)))
 627         '()))))
 628   (define (update-agenda)
 629     (let ((procs-to-run (get-procs-to-run))
 630           (q (agenda-queue agenda)))
 631       (for-each
 632        (lambda (proc)
 633          (enq! q proc))
 634        procs-to-run))
 635     agenda)
 636   (define (ports-to-select?)
 637     (define (has-items? selector)
 638       ;; @@: O(n)
 639       ;;    ... we could use hash-for-each and a continuation to jump
 640       ;;    out with a #t at first indication of an item
 641       (not (= (hash-count (const #t)
 642                           (selector agenda))
 643               0)))
 644     (or (has-items? agenda-read-port-map)
 645         (has-items? agenda-write-port-map)
 646         (has-items? agenda-except-port-map)))
 647
 648   (if (ports-to-select?)
 649       (update-agenda)
 650       agenda))
 651
 652 (define (agenda-handle-port-request! agenda port-request)
 653   "Update an agenda for a port-request"
 654   (define (handle-selector request-selector port-map-selector)
 655     (if (request-selector port-request)
 656         (hash-set! (port-map-selector agenda)
 657                    (port-request-port port-request)
 658                    (request-selector port-request))))
 659   (handle-selector port-request-read agenda-read-port-map)
 660   (handle-selector port-request-write agenda-write-port-map)
 661   (handle-selector port-request-except agenda-except-port-map))
 662
 663
 664 (define* (start-agenda agenda
 665                        #:key stop-condition
 666                        (get-time gettimeofday)
 667                        (handle-ports update-agenda-from-select!))
 668   ;; TODO: Document fields
 669   "Start up the AGENDA"
 670   (let loop ((agenda agenda))
 671     (let ((agenda
 672            ;; @@: Hm, maybe here would be a great place to handle
 673            ;;   select'ing on ports.
 674            ;;   We could compose over agenda-run-once and agenda-read-ports
 675            (agenda-run-once agenda)))
 676       (if (and stop-condition (stop-condition agenda))
 677           'done
 678           (let* ((agenda
 679                   ;; We have to update the time after ports handled, too
 680                   ;; because it may have changed after a select
 681                   (set-field
 682                    (handle-ports
 683                     ;; Adjust the agenda's time just in time
 684                     ;; We do this here rather than in agenda-run-once to make
 685                     ;; agenda-run-once's behavior fairly predictable
 686                     (set-field agenda (agenda-time) (get-time)))
 687                    (agenda-time) (get-time))))
 688             ;; Update the agenda's current queue based on
 689             ;; currently applicable time segments
 690             (add-segments-contents-to-queue!
 691              (schedule-extract-until! (agenda-schedule agenda) (agenda-time agenda))
 692              (agenda-queue agenda))
 693             (loop agenda))))))
 694
 695 (define (print-error-and-continue key . args)
 696   "Frequently used as pre-unwind-handler for agenda"
 697   (cond
 698    ((eq? key '8sync-caught-error)
 699     (match args
 700       ((orig-key orig-args stacks)
 701        (display "\n*** Caught async exception. ***\n")
 702        (format (current-error-port)
 703                "* Original key '~s and arguments: ~s *\n"
 704                orig-key orig-args)
 705        (display "* Caught stacks below (ending with original) *\n\n")
 706        (for-each
 707         (lambda (s)
 708           (display-backtrace s (current-error-port))
 709           (newline (current-error-port)))
 710         stacks))))
 711    (else
 712     (format (current-error-port)
 713             "\n*** Caught exception with key '~s and arguments: ~s ***\n"
 714             key args)
 715     (display-backtrace (make-stack #t 1 0)
 716                        (current-error-port))
 717     (newline (current-error-port)))))
 718
 719 (define-syntax-rule (maybe-catch-all (catch-handler pre-unwind-handler)
 720                                      body ...)
 721   (if (or catch-handler pre-unwind-handler)
 722       (catch
 723         #t
 724         (lambda ()
 725           body ...)
 726         (or catch-handler (lambda _ #f))
 727         (or pre-unwind-handler (lambda _ #f)))
 728       (begin body ...)))
 729
 730 (define (agenda-run-once agenda)
 731   "Run once through the agenda, and produce a new agenda
 732 based on the results"
 733   (define (call-proc proc)
 734     (call-with-prompt
 735      (agenda-prompt-tag agenda)
 736      (lambda ()
 737        (parameterize ((%current-agenda agenda))
 738          (maybe-catch-all
 739           ((agenda-catch-handler agenda)
 740            (agenda-pre-unwind-handler agenda))
 741           (proc))))
 742      (lambda (kont async-request)
 743        (setup-async-request kont async-request))))
 744
 745   (let ((queue (agenda-queue agenda))
 746         (next-queue (make-q)))
 747     (while (not (q-empty? queue))
 748       (let* ((proc (q-pop! queue))
 749              (proc-result (call-proc proc))
 750              (enqueue
 751               (lambda (run-request)
 752                 (define (schedule-at! time proc)
 753                   (schedule-add! (agenda-schedule agenda) time proc))
 754                 (let ((request-time (run-request-when run-request)))
 755                   (match request-time
 756                     ((? time-delta? time-delta)
 757                      (let ((time (time-delta+ (agenda-time agenda)
 758                                               time-delta)))
 759                        (schedule-at! time (run-request-proc run-request))))
 760                     ((? integer? sec)
 761                      (let ((time (cons sec 0)))
 762                        (schedule-at! time (run-request-proc run-request))))
 763                     (((? integer? sec) . (? integer? usec))
 764                      (schedule-at! request-time (run-request-proc run-request)))
 765                     (#f
 766                      (enq! next-queue (run-request-proc run-request))))))))
 767         (define (handle-individual result)
 768           (match result
 769             ((? run-request? new-proc)
 770              (enqueue new-proc))
 771             ((? port-request? port-request)
 772              (agenda-handle-port-request! agenda port-request))
 773             ;; do nothing
 774             (_ #f)))
 775         ;; @@: We might support delay-wrapped procedures here
 776         (match proc-result
 777           ((results ...)
 778            (for-each handle-individual results))
 779           (one-result (handle-individual one-result)))))
 780     ;; TODO: Alternately, we could return the next-queue
 781     ;;   along with changes to be added to the schedule here?
 782     ;; Return new agenda, with next queue set
 783     (set-field agenda (agenda-queue) next-queue)))