eightsync/agenda.scm

   1 ;; Copyright (C) 2015 Christopher Allan Webber <cwebber@dustycloud.org>
   2
   3 ;; This library is free software; you can redistribute it and/or
   4 ;; modify it under the terms of the GNU Lesser General Public
   5 ;; License as published by the Free Software Foundation; either
   6 ;; version 3 of the License, or (at your option) any later version.
   7 ;;
   8 ;; This library is distributed in the hope that it will be useful,
   9 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  11 ;; Lesser General Public License for more details.
  12 ;;
  13 ;; You should have received a copy of the GNU Lesser General Public
  14 ;; License along with this library; if not, write to the Free Software
  15 ;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  16 ;; 02110-1301 USA
  17
  18 (define-module (eightsync agenda)
  19   #:use-module (srfi srfi-1)
  20   #:use-module (srfi srfi-9)
  21   #:use-module (srfi srfi-9 gnu)
  22   #:use-module (ice-9 q)
  23   #:use-module (ice-9 match)
  24   #:use-module (ice-9 receive)
  25   #:export (<agenda>
  26             make-agenda agenda?
  27             agenda-queue agenda-prompt-tag
  28             agenda-read-port-map agenda-write-port-map agenda-except-port-map
  29             agenda-schedule
  30
  31             make-async-prompt-tag
  32
  33             <time-segment>
  34             make-time-segment time-segment?
  35             time-segment-time time-segment-queue
  36
  37             time< time= time<= time-delta+
  38             time-minus time-plus
  39
  40             <time-delta>
  41             make-time-delta tdelta time-delta?
  42             time-delta-sec time-delta-usec
  43
  44             <schedule>
  45             make-schedule schedule?
  46             schedule-add! schedule-empty?
  47             schedule-segments
  48             schedule-soonest-time
  49
  50             schedule-segments-split schedule-extract-until!
  51             add-segments-contents-to-queue!
  52
  53             %8sync
  54
  55             <run-request>
  56             make-run-request run-request?
  57             run-request-proc run-request-when
  58
  59             <port-request>
  60             make-port-request port-request port-request?
  61             port-request-port
  62             port-request-read port-request-write port-request-except
  63
  64             run-it wrap wrap-apply run run-at run-delay
  65
  66             %port-request %run %run-at %run-delay
  67
  68             catch-8sync catch-%8sync
  69
  70             print-error-and-continue
  71
  72             %current-agenda
  73             start-agenda agenda-run-once))
  74
  75 ;; @@: Using immutable agendas here, so wouldn't it make sense to
  76 ;;   replace this queue stuff with using pfds based immutable queues?
  77
  78 \f
  79 ;;; Agenda definition
  80 ;;; =================
  81
  82 ;;; The agenda consists of:
  83 ;;;  - a queue of immediate items to handle
  84 ;;;  - sheduled future events to be added to a future queue
  85 ;;;  - a tag by which running processes can escape for some asynchronous
  86 ;;;    operation (from which they can be returned later)
  87 ;;;  - a mapping of ports to various handler procedures
  88 ;;;
  89 ;;; The goal, eventually, is for this all to be immutable and functional.
  90 ;;; However, we aren't there yet.  Some tricky things:
  91 ;;;  - The schedule needs to be immutable, yet reasonably efficient.
  92 ;;;  - Need to use immutable queues (ijp's pfds library?)
  93 ;;;  - Modeling reading from ports as something repeatable,
  94 ;;;    and with reasonable separation from functional components?
  95
  96 (define-immutable-record-type <agenda>
  97   (make-agenda-intern queue prompt-tag
  98                       read-port-map write-port-map except-port-map
  99                       schedule time catch-handler pre-unwind-handler)
 100   agenda?
 101   (queue agenda-queue)
 102   (prompt-tag agenda-prompt-tag)
 103   (read-port-map agenda-read-port-map)
 104   (write-port-map agenda-write-port-map)
 105   (except-port-map agenda-except-port-map)
 106   (schedule agenda-schedule)
 107   (time agenda-time)
 108   (catch-handler agenda-catch-handler)
 109   (pre-unwind-handler agenda-pre-unwind-handler))
 110
 111 (define (make-async-prompt-tag)
 112   "Make an async prompt tag for an agenda.
 113
 114 Generally done automatically for the user through (make-agenda)."
 115   (make-prompt-tag "prompt"))
 116
 117 (define* (make-agenda #:key
 118                       (queue (make-q))
 119                       (prompt (make-prompt-tag))
 120                       (read-port-map (make-hash-table))
 121                       (write-port-map (make-hash-table))
 122                       (except-port-map (make-hash-table))
 123                       (schedule (make-schedule))
 124                       (time (gettimeofday))
 125                       (catch-handler #f)
 126                       (pre-unwind-handler #f))
 127   ;; TODO: document arguments
 128   "Make a fresh agenda."
 129   (make-agenda-intern queue prompt
 130                       read-port-map write-port-map except-port-map
 131                       schedule time
 132                       catch-handler pre-unwind-handler))
 133
 134 (define (current-agenda-prompt)
 135   "Get the prompt for the current agenda; signal an error if there isn't one."
 136   (let ((current-agenda (%current-agenda)))
 137     (if (not current-agenda)
 138         (throw
 139          'no-current-agenda
 140          "Can't get current agenda prompt if there's no current agenda!")
 141         (agenda-prompt-tag current-agenda))))
 142
 143
 144 \f
 145 ;;; Schedule
 146 ;;; ========
 147
 148 ;;; This is where we handle timed events for the future
 149
 150 ;; This section totally borrows from the ideas in SICP
 151 ;; <3 <3 <3
 152
 153 ;; NOTE: time is a cons of (seconds . microseconds)
 154
 155 (define-record-type <time-segment>
 156   (make-time-segment-intern time queue)
 157   time-segment?
 158   (time time-segment-time)
 159   (queue time-segment-queue))
 160
 161 ;; @@: This seems to be the same as srfi-18's seconds->time procedure?
 162 ;;   Maybe double check and switch to that?  (Thanks amz3!)
 163
 164 (define (time-from-float-or-fraction time)
 165   "Produce a (sec . usec) pair from TIME, a float or fraction"
 166   (let* ((mixed-whole (floor time))
 167          (mixed-rest (- time mixed-whole))  ; float or fraction component
 168          (sec mixed-whole)
 169          (usec (floor (* 1000000 mixed-rest))))
 170     (cons (inexact->exact sec) (inexact->exact usec))))
 171
 172 (define (time-segment-right-format time)
 173   "Ensure TIME is in the right format.
 174
 175 The right format means (second . microsecond).
 176 If an integer, will convert appropriately."
 177   ;; TODO: add floating point / rational number support.
 178   (match time
 179     ;; time is already a cons of second and microsecnd
 180     (((? integer? s) . (? integer? u)) time)
 181     ;; time was just an integer (just the second)
 182     ((? integer? _) (cons time 0))
 183     ((or (? rational? _) (? inexact? _))
 184      (time-from-float-or-fraction time))
 185     (_ (throw 'invalid-time "Invalid time" time))))
 186
 187 (define* (make-time-segment time #:optional (queue (make-q)))
 188   "Make a time segment of TIME and QUEUE
 189
 190 No automatic conversion is done, so you might have to
 191 run (time-segment-right-format) first."
 192   (make-time-segment-intern time queue))
 193
 194 (define (time< time1 time2)
 195   "Check if TIME1 is less than TIME2"
 196   (cond ((< (car time1)
 197             (car time2))
 198          #t)
 199         ((and (= (car time1)
 200                  (car time2))
 201               (< (cdr time1)
 202                  (cdr time2)))
 203          #t)
 204         (else #f)))
 205
 206 (define (time= time1 time2)
 207   "Check whether TIME1 and TIME2 are equivalent"
 208   (and (= (car time1) (car time2))
 209        (= (cdr time1) (cdr time2))))
 210
 211 (define (time<= time1 time2)
 212   "Check if TIME1 is less than or equal to TIME2"
 213   (or (time< time1 time2)
 214       (time= time1 time2)))
 215
 216
 217 (define-record-type <time-delta>
 218   (make-time-delta-intern sec usec)
 219   time-delta?
 220   (sec time-delta-sec)
 221   (usec time-delta-usec))
 222
 223 (define* (make-time-delta time)
 224   "Make a <time-delta> of SEC seconds and USEC microseconds.
 225
 226 This is used primarily so the agenda can recognize RUN-REQUEST objects
 227 which are meant to delay computation"
 228   (match (time-segment-right-format time)
 229     ((sec . usec)
 230      (make-time-delta-intern sec usec))))
 231
 232 (define tdelta make-time-delta)
 233
 234 (define (time-carry-correct time)
 235   "Corrects/handles time microsecond carry.
 236 Will produce (0 . 0) instead of a negative number, if needed."
 237   (cond ((>= (cdr time) 1000000)
 238          (cons
 239           (+ (car time) 1)
 240           (- (cdr time) 1000000)))
 241         ((< (cdr time) 0)
 242          (if (= (car time) 0)
 243              '(0 0)
 244              (cons
 245               (- (car time) 1)
 246               (+ (cdr time) 1000000))))
 247         (else time)))
 248
 249 (define (time-delta+ time time-delta)
 250   "Increment a TIME by the value of TIME-DELTA"
 251   (time-carry-correct
 252    (cons (+ (car time) (time-delta-sec time-delta))
 253          (+ (cdr time) (time-delta-usec time-delta)))))
 254
 255 (define (time-minus time1 time2)
 256   "Subtract TIME2 from TIME1"
 257   (time-carry-correct
 258    (cons (- (car time1) (car time2))
 259          (- (cdr time1) (cdr time2)))))
 260
 261 (define (time-plus time1 time2)
 262   "Add TIME1 and TIME2"
 263   (time-carry-correct
 264    (cons (+ (car time1) (car time2))
 265          (+ (cdr time1) (cdr time2)))))
 266
 267
 268 (define-record-type <schedule>
 269   (make-schedule-intern segments)
 270   schedule?
 271   (segments schedule-segments set-schedule-segments!))
 272
 273 (define* (make-schedule #:optional segments)
 274   "Make a schedule, optionally pre-composed of SEGMENTS"
 275   (make-schedule-intern (or segments '())))
 276
 277 (define (schedule-soonest-time schedule)
 278   "Return a cons of (sec . usec) for next time segement, or #f if none"
 279   (let ((segments (schedule-segments schedule)))
 280     (if (eq? segments '())
 281         #f
 282         (time-segment-time (car segments)))))
 283
 284 ;; TODO: This code is reasonably easy to read but it
 285 ;;   mutates AND is worst case of O(n) in both space and time :(
 286 ;;   but at least it'll be reasonably easy to refactor to
 287 ;;   a more functional setup?
 288 (define (schedule-add! schedule time proc)
 289   "Mutate SCHEDULE, adding PROC at an appropriate time segment for TIME"
 290   (let ((time (time-segment-right-format time)))
 291     (define (new-time-segment)
 292       (let ((new-segment
 293              (make-time-segment time)))
 294         (enq! (time-segment-queue new-segment) proc)
 295         new-segment))
 296     (define (loop segments)
 297       (define (segment-equals-time? segment)
 298         (time= time (time-segment-time segment)))
 299
 300       (define (segment-more-than-time? segment)
 301         (time< time (time-segment-time segment)))
 302
 303       ;; We could switch this out to be more mutate'y
 304       ;; and avoid the O(n) of space... is that over-optimizing?
 305       (match segments
 306         ;; If we're at the end of the list, time to make a new
 307         ;; segment...
 308         ('() (cons (new-time-segment) '()))
 309         ;; If the segment's time is exactly our time, good news
 310         ;; everyone!  Let's append our stuff to its queue
 311         (((? segment-equals-time? first) rest ...)
 312          (enq! (time-segment-queue first) proc)
 313          segments)
 314         ;; If the first segment is more than our time,
 315         ;; ours belongs before this one, so add it and
 316         ;; start consing our way back
 317         (((? segment-more-than-time? first) rest ...)
 318          (cons (new-time-segment) segments))
 319         ;; Otherwise, build up recursive result
 320         ((first rest ... )
 321          (cons first (loop rest)))))
 322     (set-schedule-segments!
 323      schedule
 324      (loop (schedule-segments schedule)))))
 325
 326 (define (schedule-empty? schedule)
 327   "Check if the SCHEDULE is currently empty"
 328   (eq? (schedule-segments schedule) '()))
 329
 330 (define (schedule-segments-split schedule time)
 331   "Does a multiple value return of time segments before/at and after TIME"
 332   (let ((time (time-segment-right-format time)))
 333     (define (segment-is-now? segment)
 334       (time= (time-segment-time segment) time))
 335     (define (segment-is-before-now? segment)
 336       (time< (time-segment-time segment) time))
 337
 338     (let loop ((segments-before '())
 339                (segments-left (schedule-segments schedule)))
 340       (match segments-left
 341         ;; end of the line, return
 342         ('()
 343          (values (reverse segments-before) '()))
 344
 345         ;; It's right now, so time to stop, but include this one in before
 346         ;; but otherwise return
 347         (((? segment-is-now? first) rest ...)
 348          (values (reverse (cons first segments-before)) rest))
 349
 350         ;; This is prior or at now, so add it and keep going
 351         (((? segment-is-before-now? first) rest ...)
 352          (loop (cons first segments-before) rest))
 353
 354         ;; Otherwise it's past now, just return what we have
 355         (segments-after
 356          (values segments-before segments-after))))))
 357
 358 (define (schedule-extract-until! schedule time)
 359   "Extract all segments until TIME from SCHEDULE, and pop old segments off"
 360   (receive (segments-before segments-after)
 361       (schedule-segments-split schedule time)
 362     (set-schedule-segments! schedule segments-after)
 363     segments-before))
 364
 365 (define (add-segments-contents-to-queue! segments queue)
 366   (for-each
 367    (lambda (segment)
 368      (let ((seg-queue (time-segment-queue segment)))
 369        (while (not (q-empty? seg-queue))
 370          (enq! queue (deq! seg-queue)))))
 371    segments))
 372
 373
 374 \f
 375 ;;; Request to run stuff
 376 ;;; ====================
 377
 378 (define-record-type <run-request>
 379   (make-run-request proc when)
 380   run-request?
 381   (proc run-request-proc)
 382   (when run-request-when))
 383
 384 (define* (run-it proc #:optional when)
 385   "Make a request to run PROC (possibly at WHEN)"
 386   (make-run-request proc when))
 387
 388 (define-syntax-rule (wrap body ...)
 389   "Wrap contents in a procedure"
 390   (lambda ()
 391     body ...))
 392
 393 (define-syntax-rule (wrap-apply body)
 394   "Wrap possibly multi-value function in a procedure, applies all arguments"
 395   (lambda args
 396     (apply body args)))
 397
 398
 399 ;; @@: Do we really want `body ...' here?
 400 ;;   what about just `body'?
 401 (define-syntax-rule (run body ...)
 402   "Run everything in BODY but wrap in a convenient procedure"
 403   (make-run-request (wrap body ...) #f))
 404
 405 (define-syntax-rule (run-at body ... when)
 406   "Run BODY at WHEN"
 407   (make-run-request (wrap body ...) when))
 408
 409 ;; @@: Is it okay to overload the term "delay" like this?
 410 ;;   Would `run-in' be better?
 411 (define-syntax-rule (run-delay body ... delay-time)
 412   "Run BODY at DELAY-TIME time from now"
 413   (make-run-request (wrap body ...) (tdelta delay-time)))
 414
 415
 416 ;; A request to set up a port with at least one of read, write, except
 417 ;; handling processes
 418
 419 (define-record-type <port-request>
 420   (make-port-request-intern port read write except)
 421   port-request?
 422   (port port-request-port)
 423   (read port-request-read)
 424   (write port-request-write)
 425   (except port-request-except))
 426
 427 (define* (make-port-request port #:key read write except)
 428   (if (not (or read write except))
 429       (throw 'no-port-handler-given "No port handler given.\n"))
 430   (make-port-request-intern port read write except))
 431
 432 (define port-request make-port-request)
 433
 434
 435 \f
 436 ;;; Asynchronous escape to run things
 437 ;;; =================================
 438
 439 (define (agenda-on-error agenda)
 440   (const #f))
 441
 442 (define (agenda-on-fail agenda)
 443   (const #f))
 444
 445 (define-syntax-rule (%8sync async-request)
 446   "Run BODY asynchronously at a prompt, passing args to make-future.
 447
 448 Runs things asynchronously (8synchronously?)"
 449   (propagate-%async-exceptions
 450    (abort-to-prompt (current-agenda-prompt)
 451                     async-request)))
 452
 453 ;; Async port request and run-request meta-requests
 454 (define (make-async-request proc)
 455   "Wrap PROC in an async-request
 456
 457 The purpose of this is to make sure that users don't accidentally
 458 return the wrong thing via (%8sync) and trip themselves up."
 459   (cons '*async-request* proc))
 460
 461 (define (setup-async-request resume-kont async-request)
 462   "Complete an async request for agenda-run-once's continuation handling"
 463   (match async-request
 464     (('*async-request* . async-setup-proc)
 465      (async-setup-proc resume-kont))
 466     ;; TODO: deliver more helpful errors depending on what the user
 467     ;;   returned
 468     (_ (throw 'invalid-async-request
 469               "Invalid request passed back via an (%8sync) procedure."
 470               async-request))))
 471
 472 (define-record-type <wrapped-exception>
 473   (make-wrapped-exception key args stacks)
 474   wrapped-exception?
 475   (key wrapped-exception-key)
 476   (args wrapped-exception-args)
 477   (stacks wrapped-exception-stacks))
 478
 479 (define-syntax-rule (propagate-%async-exceptions body)
 480   (let ((body-result body))
 481     (if (wrapped-exception? body-result)
 482         (throw '8sync-caught-error
 483                (wrapped-exception-key body-result)
 484                (wrapped-exception-args body-result)
 485                (wrapped-exception-stacks body-result))
 486         body-result)))
 487
 488 (define-syntax-rule (%run body ...)
 489   (%run-at body ... #f))
 490
 491 (define-syntax-rule (%run-at body ... when)
 492   ;; Send an asynchronous request to apply a continuation to the
 493   ;; following function, then handle that as a request to the agenda
 494   (make-async-request
 495    (lambda (kont)
 496      ;; We're making a run request
 497      (make-run-request
 498       ;; Wrapping the following execution to run...
 499       (wrap
 500        ;; Once we get the result from the inner part, we'll resume
 501        ;; this continuation, but first
 502        ;; @@: Is this running immediately, or queueing the result
 503        ;;   after evaluation for the next agenda tick?  It looks
 504        ;;   like evaluating immediately.  Is that what we want?
 505        (kont
 506         ;; Any unhandled errors are caught
 507         (let ((exception-stack #f))
 508           (catch #t
 509             ;; Run the actual code the user requested
 510             (lambda ()
 511               body ...)
 512             ;; If something bad happened and we didn't catch it,
 513             ;; we'll wrap it up in such a way that the continuation
 514             ;; can address it
 515             (lambda (key . args)
 516               (cond
 517                ((eq? key '8sync-caught-error)
 518                 (match args
 519                   ((orig-key orig-args orig-stacks)
 520                    (make-wrapped-exception
 521                     orig-key orig-args
 522                     (cons exception-stack orig-stacks)))))
 523                (else
 524                 (make-wrapped-exception key args
 525                                         (list exception-stack)))))
 526             (lambda _
 527               (set! exception-stack (make-stack #t 1 0)))))))
 528       when))))
 529
 530 (define-syntax-rule (%run-delay body ... delay-time)
 531   (%run-at body ... (tdelta delay-time)))
 532
 533 (define-syntax-rule (%port-request add-this-port port-request-args ...)
 534   (make-async-request
 535    (lambda (kont)
 536      (list (make-port-request port-request-args ...)
 537            (make-run-request kont)))))
 538
 539 ;; TODO
 540 (define-syntax-rule (%run-with-return return body ...)
 541   (make-async-request
 542    (lambda (kont)
 543      (let ((return kont))
 544        (lambda ()
 545          body ...)))))
 546
 547 (define-syntax-rule (catch-8sync exp (handler-key handler) ...)
 548   (catch '8sync-caught-error
 549     (lambda ()
 550       exp)
 551     (lambda (_ orig-key orig-args orig-stacks)
 552       (cond
 553        ((or (eq? handler-key #t)
 554             (eq? orig-key handler-key))
 555         (apply handler orig-stacks orig-args)) ...
 556        (else (raise '8sync-caught-error
 557                     orig-key orig-args orig-stacks))))))
 558
 559 ;; Alias...?
 560 (define-syntax-rule (catch-%8sync rest ...)
 561   (catch-8sync rest ...))
 562
 563
 564 \f
 565 ;;; Execution of agenda, and current agenda
 566 ;;; =======================================
 567
 568 (define %current-agenda (make-parameter #f))
 569
 570 (define (update-agenda-from-select! agenda)
 571   "Potentially (select) on ports specified in agenda, adding items to queue"
 572   (define (hash-keys hash)
 573     (hash-map->list (lambda (k v) k) hash))
 574   (define (get-wait-time)
 575     ;; TODO: we need to figure this out based on whether there's anything
 576     ;;   in the queue, and if not, how long till the next scheduled item
 577     (let ((soonest-time (schedule-soonest-time (agenda-schedule agenda))))
 578       (cond
 579        ((not (q-empty? (agenda-queue agenda)))
 580         (cons 0 0))
 581        (soonest-time    ; ie, the agenda is non-empty
 582         (let* ((current-time (agenda-time agenda)))
 583           (if (time<= soonest-time current-time)
 584               ;; Well there's something due so let's select
 585               ;; (this avoids a (possible?) race condition chance)
 586               (cons 0 0)
 587               (time-minus soonest-time current-time))))
 588        (else
 589         (cons #f #f)))))
 590   (define (do-select)
 591     ;; TODO: support usecond wait time too
 592     (match (get-wait-time)
 593       ((sec . usec)
 594        (catch 'system-error
 595          (lambda ()
 596            (select (hash-keys (agenda-read-port-map agenda))
 597                    (hash-keys (agenda-write-port-map agenda))
 598                    (hash-keys (agenda-except-port-map agenda))
 599                    sec usec))
 600          (lambda (key . rest-args)
 601            (match rest-args
 602              ((_ _ _ (EINTR))
 603               '(() () ()))
 604              (_ (error "Unhandled error in select!" key rest-args))))))))
 605   (define (get-procs-to-run)
 606     (define (ports->procs ports port-map)
 607       (lambda (initial-procs)
 608         (fold
 609          (lambda (port prev)
 610            (cons (lambda ()
 611                    ((hash-ref port-map port) port))
 612                  prev))
 613          initial-procs
 614          ports)))
 615     (match (do-select)
 616       ((read-ports write-ports except-ports)
 617        ;; @@: Come on, we can do better than append ;P
 618        ((compose (ports->procs
 619                   read-ports
 620                   (agenda-read-port-map agenda))
 621                  (ports->procs
 622                   write-ports
 623                   (agenda-write-port-map agenda))
 624                  (ports->procs
 625                   except-ports
 626                   (agenda-except-port-map agenda)))
 627         '()))))
 628   (define (update-agenda)
 629     (let ((procs-to-run (get-procs-to-run))
 630           (q (agenda-queue agenda)))
 631       (for-each
 632        (lambda (proc)
 633          (enq! q proc))
 634        procs-to-run))
 635     agenda)
 636   (define (ports-to-select?)
 637     (define (has-items? selector)
 638       ;; @@: O(n)
 639       ;;    ... we could use hash-for-each and a continuation to jump
 640       ;;    out with a #t at first indication of an item
 641       (not (= (hash-count (const #t)
 642                           (selector agenda))
 643               0)))
 644     (or (has-items? agenda-read-port-map)
 645         (has-items? agenda-write-port-map)
 646         (has-items? agenda-except-port-map)))
 647
 648   (if (ports-to-select?)
 649       (update-agenda)
 650       agenda))
 651
 652 (define (agenda-handle-port-request! agenda port-request)
 653   "Update an agenda for a port-request"
 654   (define (handle-selector request-selector port-map-selector)
 655     (if (request-selector port-request)
 656         (hash-set! (port-map-selector agenda)
 657                    (port-request-port port-request)
 658                    (request-selector port-request))))
 659   (handle-selector port-request-read agenda-read-port-map)
 660   (handle-selector port-request-write agenda-write-port-map)
 661   (handle-selector port-request-except agenda-except-port-map))
 662
 663
 664 (define* (start-agenda agenda
 665                        #:key stop-condition
 666                        (get-time gettimeofday)
 667                        (handle-ports update-agenda-from-select!))
 668   ;; TODO: Document fields
 669   "Start up the AGENDA"
 670   (let loop ((agenda agenda))
 671     (let ((agenda
 672            ;; @@: Hm, maybe here would be a great place to handle
 673            ;;   select'ing on ports.
 674            ;;   We could compose over agenda-run-once and agenda-read-ports
 675            (agenda-run-once agenda)))
 676       (if (and stop-condition (stop-condition agenda))
 677           'done
 678           (let* ((agenda
 679                   ;; We have to update the time after ports handled, too
 680                   ;; because it may have changed after a select
 681                   (set-field
 682                    (handle-ports
 683                     ;; Adjust the agenda's time just in time
 684                     ;; We do this here rather than in agenda-run-once to make
 685                     ;; agenda-run-once's behavior fairly predictable
 686                     (set-field agenda (agenda-time) (get-time)))
 687                    (agenda-time) (get-time))))
 688             ;; Update the agenda's current queue based on
 689             ;; currently applicable time segments
 690             (add-segments-contents-to-queue!
 691              (schedule-extract-until! (agenda-schedule agenda) (agenda-time agenda))
 692              (agenda-queue agenda))
 693             (loop agenda))))))
 694
 695 (define (print-error-and-continue . args)
 696   "Frequently used as pre-unwind-handler for agenda"
 697   (format (current-error-port) "\n*** Caught exception with arguments: ~s ***\n"
 698           args)
 699   (display-backtrace (make-stack #t 1 0)
 700                      (current-error-port))
 701   (newline (current-error-port)))
 702
 703 (define-syntax-rule (maybe-catch-all (catch-handler pre-unwind-handler)
 704                                      body ...)
 705   (if (or catch-handler pre-unwind-handler)
 706       (catch
 707         #t
 708         (lambda ()
 709           body ...)
 710         (or catch-handler (lambda _ #f))
 711         (or pre-unwind-handler (lambda _ #f)))
 712       (begin body ...)))
 713
 714 (define (agenda-run-once agenda)
 715   "Run once through the agenda, and produce a new agenda
 716 based on the results"
 717   (define (call-proc proc)
 718     (call-with-prompt
 719      (agenda-prompt-tag agenda)
 720      (lambda ()
 721        (parameterize ((%current-agenda agenda))
 722          (maybe-catch-all
 723           ((agenda-catch-handler agenda)
 724            (agenda-pre-unwind-handler agenda))
 725           (proc))))
 726      (lambda (kont async-request)
 727        (setup-async-request kont async-request))))
 728
 729   (let ((queue (agenda-queue agenda))
 730         (next-queue (make-q)))
 731     (while (not (q-empty? queue))
 732       (let* ((proc (q-pop! queue))
 733              (proc-result (call-proc proc))
 734              (enqueue
 735               (lambda (run-request)
 736                 (define (schedule-at! time proc)
 737                   (schedule-add! (agenda-schedule agenda) time proc))
 738                 (let ((request-time (run-request-when run-request)))
 739                   (match request-time
 740                     ((? time-delta? time-delta)
 741                      (let ((time (time-delta+ (agenda-time agenda)
 742                                               time-delta)))
 743                        (schedule-at! time (run-request-proc run-request))))
 744                     ((? integer? sec)
 745                      (let ((time (cons sec 0)))
 746                        (schedule-at! time (run-request-proc run-request))))
 747                     (((? integer? sec) . (? integer? usec))
 748                      (schedule-at! request-time (run-request-proc run-request)))
 749                     (#f
 750                      (enq! next-queue (run-request-proc run-request))))))))
 751         (define (handle-individual result)
 752           (match result
 753             ((? run-request? new-proc)
 754              (enqueue new-proc))
 755             ((? port-request? port-request)
 756              (agenda-handle-port-request! agenda port-request))
 757             ;; do nothing
 758             (_ #f)))
 759         ;; @@: We might support delay-wrapped procedures here
 760         (match proc-result
 761           ((results ...)
 762            (for-each handle-individual results))
 763           (one-result (handle-individual one-result)))))
 764     ;; TODO: Alternately, we could return the next-queue
 765     ;;   along with changes to be added to the schedule here?
 766     ;; Return new agenda, with next queue set
 767     (set-field agenda (agenda-queue) next-queue)))