8sync/systems/actors.scm

   1 ;;; 8sync --- Asynchronous programming for Guile
   2 ;;; Copyright (C) 2016 Christopher Allan Webber <cwebber@dustycloud.org>
   3 ;;;
   4 ;;; This file is part of 8sync.
   5 ;;;
   6 ;;; 8sync is free software: you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU Lesser General Public License as
   8 ;;; published by the Free Software Foundation, either version 3 of the
   9 ;;; License, or (at your option) any later version.
  10 ;;;
  11 ;;; 8sync is distributed in the hope that it will be useful,
  12 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU Lesser General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU Lesser General Public
  17 ;;; License along with 8sync.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;; XUDD inspired actor system
  20
  21 (define-module (8sync systems actors)
  22   #:use-module (oop goops)
  23   #:use-module (srfi srfi-9)
  24   #:use-module (srfi srfi-9 gnu)
  25   #:use-module (ice-9 format)
  26   #:use-module (ice-9 match)
  27   #:use-module (ice-9 pretty-print)
  28   #:use-module (8sync agenda)
  29   #:use-module (8sync repl)
  30   #:export (;; utilities... ought to go in their own module
  31             big-random-number
  32             big-random-number-string
  33             simple-message-id-generator
  34
  35             <actor>
  36             actor-id
  37             actor-message-handler
  38
  39             ;;; Commenting out the <address> type for now;
  40             ;;; it may be back when we have better serializers
  41             ;; <address>
  42             make-address address?
  43             address-actor-id address-hive-id
  44
  45             address->string
  46             actor-id-actor
  47             actor-id-hive
  48             actor-id-string
  49
  50             mlambda define-mhandler
  51             make-action-dispatch
  52             define-simple-actor
  53
  54             <hive>
  55             make-hive
  56             ;; There are more methods for the hive, but there's
  57             ;; no reason for the outside world to look at them maybe?
  58             hive-id
  59             hive-create-actor hive-create-actor*
  60
  61             create-actor create-actor*
  62             self-destruct
  63
  64             <message>
  65             make-message message?
  66             message-to message-action message-from
  67             message-id message-body message-in-reply-to
  68             message-wants-reply
  69             message-ref
  70
  71             send-message send-message-wait
  72             reply-message reply-message-wait
  73
  74             <- <-wait <-reply <-reply-wait
  75
  76             ez-run-hive
  77             bootstrap-message
  78
  79             serialize-message write-message
  80             serialize-message-pretty pprint-message
  81             read-message read-message-from-string))
  82
  83 ;; For ids
  84 (define %random-state
  85   (make-parameter (random-state-from-platform)))
  86
  87 ;; Same size as a uuid4 I think...
  88 (define random-number-size (expt 2 128))
  89
  90 (define (big-random-number)
  91   (random random-number-size (%random-state)))
  92
  93 ;; Would be great to get this base64 encoded instead.
  94 (define (big-random-number-string)
  95   ;; @@: This is slow.  Using format here is wasteful.
  96   (format #f "~x" (big-random-number)))
  97
  98 ;; @@: This is slow.  A mere ~275k / second on my (old) machine.
  99 ;;   The main cost seems to be in number->string.
 100 (define (simple-message-id-generator)
 101   ;; Prepending this cookie makes message ids unique per hive
 102   (let ((prefix (format #f "~x:" (big-random-number)))
 103         (counter 0))
 104     (lambda ()
 105       (set! counter (1+ counter))
 106       (string-append prefix (number->string counter)))))
 107
 108
 109 \f
 110 ;;; Messages
 111 ;;; ========
 112
 113
 114 (define-record-type <message>
 115   (make-message-intern id to from action
 116                        body in-reply-to wants-reply
 117                        replied
 118                        ;; @@: Not used yet.
 119                        ;; Will we ever find a real use case?
 120                        deferred-reply)
 121   message?
 122   (id message-id)
 123   (to message-to)
 124   (from message-from)
 125   (action message-action)
 126   (body message-body)
 127   (in-reply-to message-in-reply-to)
 128   (wants-reply message-wants-reply)
 129
 130   ;; See XUDD source for these.  Not use yet, maybe eventually will be?
 131   ;; XUDD uses them for autoreply.
 132   ;; Requiring mutation on message objects is clearly not great,
 133   ;; but it may be worth it...?  Investigate!
 134   (replied message-replied set-message-replied!)
 135   (deferred-reply message-deferred-reply set-message-deferred-reply!))
 136
 137
 138 (define* (make-message id to from action body
 139                        #:key in-reply-to wants-reply
 140                        replied deferred-reply)
 141   (make-message-intern id to from action body
 142                        in-reply-to wants-reply replied
 143                        deferred-reply))
 144
 145 ;; Note: the body of messages is currently an alist, but it's created
 146 ;;   from a keyword based property list (see the following two functions).
 147 ;;   But, that's an extra conversion step, and maybe totally unnecessary:
 148 ;;   we already have message-ref, and this could just pull a keyword
 149 ;;   from a property list.
 150 ;;   The main ways this might be useful are error checking,
 151 ;;   serialization across the wire (but even that might require some
 152 ;;   change), and using existing tooling (though adding new tooling
 153 ;;   would be negligible in implementation effort.)
 154
 155 ;; This cons cell is immutable and unique (for eq? tests)
 156 (define %nothing-provided (cons 'nothing 'provided))
 157
 158 (define* (message-ref message key #:optional (dflt %nothing-provided))
 159   "Extract KEY from body of MESSAGE.
 160
 161 Optionally set default with [DFLT]
 162 If key not found and DFLT not provided, throw an error."
 163   (let ((result (assoc key (message-body message))))
 164     (if result (cdr result)
 165         (if (eq? dflt %nothing-provided)
 166             (throw 'message-missing-key
 167                    "Message body does not contain key and no default provided"
 168                    #:key key
 169                    #:message message)
 170             dflt))))
 171
 172
 173 (define (message-needs-reply message)
 174   "See if this message needs a reply still"
 175   (and (message-wants-reply message)
 176        (not (or (message-replied message)
 177                 (message-deferred-reply message)))))
 178
 179
 180 (define (kwarg-list-to-alist args)
 181   (let loop ((remaining args)
 182              (result '()))
 183     (match remaining
 184       (((? keyword? key) val rest ...)
 185        (loop rest
 186              (cons (cons (keyword->symbol key) val)
 187                    result)))
 188       (() result)
 189       (_ (throw 'invalid-kwarg-list
 190                 "Invalid keyword argument list"
 191                 args)))))
 192
 193
 194 (define (send-message from-actor to-id action . message-body-args)
 195   "Send a message from an actor to another actor"
 196   (let* ((hive (actor-hive from-actor))
 197          (message (make-message (hive-gen-message-id hive) to-id
 198                                 (actor-id from-actor) action
 199                                 (kwarg-list-to-alist message-body-args))))
 200     (8sync-nowait (hive-process-message hive message))))
 201
 202 (define (send-message-wait from-actor to-id action . message-body-args)
 203   "Send a message from an actor to another, but wait until we get a response"
 204   (let* ((hive (actor-hive from-actor))
 205          (abort-to (hive-prompt (actor-hive from-actor)))
 206          (message (make-message (hive-gen-message-id hive) to-id
 207                                 (actor-id from-actor) action
 208                                 (kwarg-list-to-alist message-body-args)
 209                                 #:wants-reply #t)))
 210     (abort-to-prompt abort-to from-actor message)))
 211
 212 ;; TODO: Intelligently ~propagate(ish) errors on -wait functions.
 213 ;;   We might have `send-message-wait-brazen' to allow callers to
 214 ;;   not have an exception thrown and instead just have a message with
 215 ;;   the appropriate '*error* message returned.
 216
 217 (define (reply-message from-actor original-message
 218                        . message-body-args)
 219   "Reply to a message"
 220   (set-message-replied! original-message #t)
 221   (let* ((hive (actor-hive from-actor))
 222          (new-message (make-message (hive-gen-message-id hive)
 223                                     (message-from original-message)
 224                                     (actor-id from-actor) '*reply*
 225                                     (kwarg-list-to-alist message-body-args)
 226                                     #:in-reply-to (message-id original-message))))
 227     (8sync-nowait (hive-process-message hive new-message))))
 228
 229 (define (reply-message-wait from-actor original-message
 230                             . message-body-args)
 231   "Reply to a messsage, but wait until we get a response"
 232   (set-message-replied! original-message #t)
 233   (let* ((hive (actor-hive from-actor))
 234          (abort-to (hive-prompt (actor-hive from-actor)))
 235          (new-message (make-message (hive-gen-message-id hive)
 236                                     (message-from original-message)
 237                                     (actor-id from-actor) '*reply*
 238                                     (kwarg-list-to-alist message-body-args)
 239                                     #:wants-reply #t
 240                                     #:in-reply-to (message-id original-message))))
 241     (abort-to-prompt abort-to from-actor new-message)))
 242
 243
 244 ;;; Aliases!
 245 ;;; See: http://mumble.net/~jar/articles/oo-moon-weinreb.html
 246 ;;;   (also worth seeing: http://mumble.net/~jar/articles/oo.html )
 247
 248 (define <- send-message)
 249 (define <-wait send-message-wait)
 250 (define <-reply reply-message)
 251 (define <-reply-wait reply-message-wait)
 252
 253
 254 \f
 255 ;;; Main actor implementation
 256 ;;; =========================
 257
 258 (define-class <actor> ()
 259   ;; An address object
 260   (id #:init-keyword #:id
 261       #:getter actor-id)
 262   ;; The hive we're connected to.
 263   ;; We need this to be able to send messages.
 264   (hive #:init-keyword #:hive
 265         #:accessor actor-hive)
 266   ;; How we receive and process new messages
 267   (message-handler #:allocation #:each-subclass))
 268
 269 (define-method (actor-message-handler (actor <actor>))
 270   (slot-ref actor 'message-handler))
 271
 272 ;;; So these are the nicer representations of addresses.
 273 ;;; However, they don't serialize so easily with scheme read/write, so we're
 274 ;;; using the simpler cons cell version below for now.
 275
 276 ;; (define-record-type <address>
 277 ;;   (make-address actor-id hive-id)  ; @@: Do we want the trailing -id?
 278 ;;   address?
 279 ;;   (actor-id address-actor-id)
 280 ;;   (hive-id address-hive-id))
 281 ;;
 282 ;; (set-record-type-printer!
 283 ;;  <address>
 284 ;;  (lambda (record port)
 285 ;;    (format port "<address: ~s@~s>"
 286 ;;            (address-actor-id record) (address-hive-id record))))
 287 ;;
 288
 289 (define (make-address actor-id hive-id)
 290   (cons actor-id hive-id))
 291
 292 (define (address-actor-id address)
 293   (car address))
 294
 295 (define (address-hive-id address)
 296   (cdr address))
 297
 298 (define (address->string address)
 299   (string-append (address-actor-id address) "@"
 300                  (address-hive-id address)))
 301
 302 (define-method (actor-id-actor (actor <actor>))
 303   "Get the actor id component of the actor-id"
 304   (address-actor-id (actor-id actor)))
 305
 306 (define-method (actor-id-hive (actor <actor>))
 307   "Get the hive id component of the actor-id"
 308   (address-hive-id (actor-id actor)))
 309
 310 (define-method (actor-id-string (actor <actor>))
 311   "Render the full actor id as a human-readable string"
 312   (address->string (actor-id actor)))
 313
 314
 315 \f
 316 ;;; Actor utilities
 317 ;;; ===============
 318
 319
 320 (define-syntax-rule (with-message-args (message message-arg ...)
 321                                        body body* ...)
 322   (let ((message-arg (message-ref message (quote message-arg))) ...)
 323     body body* ...))
 324
 325 (define-syntax mlambda
 326   (syntax-rules ()
 327     "A lambda for building message handlers.
 328
 329 Use it like:
 330   (mlambda (actor message foo)
 331     ...)
 332
 333 Which is like doing manually:
 334   (lambda (actor message)
 335     (let ((foo (message-ref message foo)))
 336       ...))"
 337     ((_ (actor message message-arg ...)
 338         body body* ...)
 339      (lambda (actor message)
 340        (with-message-args (message message-arg ...) body body* ...)))))
 341
 342 ;; @@: Sadly, docstrings won't work with this...
 343 ;;   I think we need to bust out syntax-case to make that happen...
 344 (define-syntax-rule (define-mhandler (name actor message message-arg ...)
 345                       body ...)
 346   (define name
 347     (mlambda (actor message message-arg ...)
 348              body ...)))
 349
 350 (define (simple-dispatcher action-map)
 351   (lambda (actor message)
 352     (let* ((action (message-action message))
 353            (method (assoc-ref action-map action)))
 354       (if (not method)
 355           (throw 'action-not-found
 356                  "No appropriate action handler found for actor"
 357                  #:action action
 358                  #:actor actor
 359                  #:message message
 360                  #:available-actions (map car action-map)))
 361       (method actor message))))
 362
 363 (define-syntax %expand-action-item
 364   (syntax-rules ()
 365     ((_ ((action-name action-args ...) body ...))
 366      (cons (quote action-name)
 367            (mlambda (action-args ...)
 368              body ...)))
 369     ((_ (action-name handler))
 370      (cons (quote action-name) handler))))
 371
 372 (define-syntax make-action-dispatch
 373   (syntax-rules ()
 374     "Expand a list of action names and actions into an alist
 375
 376 You can use this like the following:
 377   (make-action-dispatch
 378    (cookies
 379     (lambda (actor message)
 380       (display \"I love cookies!\n\")))
 381    (party
 382     (lambda (actor message)
 383       (display \"Life of the party!\"))))
 384
 385 Alternately, if you'd like to skip the lambda, you could use the slightly
 386 more compact following syntax:
 387   (make-action-dispatch
 388    ((cookies actor message)
 389      (display \"I love cookies!\n\"))
 390    ((party actor message)
 391      (display \"Life of the party!\")))"
 392     ((make-action-dispatch action-item ...)
 393      (simple-dispatcher
 394       (list (%expand-action-item action-item) ...)))))
 395
 396 (define-syntax-rule (define-simple-actor class actions ...)
 397   (define-class class (<actor>)
 398     (message-handler
 399      #:init-value (make-action-dispatch actions ...)
 400      #:allocation #:each-subclass)))
 401
 402 \f
 403 ;;; The Hive
 404 ;;; ========
 405 ;;;   Every actor has a hive.  The hive is a kind of "meta-actor"
 406 ;;;   which routes all the rest of the actors in a system.
 407
 408 (define-generic hive-handle-failed-forward)
 409
 410 (define-class <hive> (<actor>)
 411   (actor-registry #:init-thunk make-hash-table
 412                   #:getter hive-actor-registry)
 413   (msg-id-generator #:init-thunk simple-message-id-generator
 414                     #:getter hive-msg-id-generator)
 415   ;; Ambassadors are used (or will be) for inter-hive communication.
 416   ;; These are special actors that know how to route messages to other hives.
 417   (ambassadors #:init-thunk make-weak-key-hash-table
 418                #:getter hive-ambassadors)
 419   ;; Waiting coroutines
 420   ;; This is a map from cons cell of message-id
 421   ;;   to a cons cell of (actor-id . coroutine)
 422   ;; @@: Should we have a <waiting-coroutine> record type?
 423   ;; @@: Should there be any way to clear out "old" coroutines?
 424   (waiting-coroutines #:init-thunk make-hash-table
 425                       #:getter hive-waiting-coroutines)
 426   ;; Message prompt
 427   ;; When actors send messages to each other they abort to this prompt
 428   ;; to send the message, then carry on their way
 429   (prompt #:init-thunk make-prompt-tag
 430           #:getter hive-prompt)
 431   (message-handler
 432    #:init-value
 433    (make-action-dispatch
 434     ;; This is in the case of an ambassador failing to forward a message...
 435     ;; it reports it back to the hive
 436     (*failed-forward* hive-handle-failed-forward))))
 437
 438 (define-method (hive-handle-failed-forward (hive <hive>) message)
 439   "Handle an ambassador failing to forward a message"
 440   'TODO)
 441
 442 (define* (make-hive #:key hive-id)
 443   (let ((hive (make <hive>
 444                 #:id (make-address
 445                       "hive" (or hive-id
 446                                  (big-random-number-string))))))
 447     ;; Set the hive's actor reference to itself
 448     (set! (actor-hive hive) hive)
 449     hive))
 450
 451 (define-method (hive-id (hive <hive>))
 452   (actor-id-hive hive))
 453
 454 (define-method (hive-gen-actor-id (hive <hive>) cookie)
 455   (make-address (if cookie
 456                     (string-append cookie "-" (big-random-number-string))
 457                     (big-random-number-string))
 458                 (hive-id hive)))
 459
 460 (define-method (hive-gen-message-id (hive <hive>))
 461   "Generate a message id using HIVE's message id generator"
 462   ((hive-msg-id-generator hive)))
 463
 464 (define-method (hive-resolve-local-actor (hive <hive>) actor-address)
 465   (hash-ref (hive-actor-registry hive) actor-address))
 466
 467 (define-method (hive-resolve-ambassador (hive <hive>) ambassador-address)
 468   (hash-ref (hive-ambassadors hive) ambassador-address))
 469
 470 (define-method (make-forward-request (hive <hive>) (ambassador <actor>) message)
 471   (make-message (hive-gen-message-id hive) (actor-id ambassador)
 472                 ;; If we make the hive not an actor, we could either switch this
 473                 ;; to #f or to the original actor...?
 474                 ;; Maybe some more thinking should be done on what should
 475                 ;; happen in case of failure to forward?  Handling ambassador failures
 476                 ;; seems like the primary motivation for the hive remaining an actor.
 477                 (actor-id hive)
 478                 '*forward*
 479                 `((original . ,message))))
 480
 481 (define-method (hive-reply-with-error (hive <hive>) original-message
 482                                       error-key error-args)
 483   ;; We only supply the error-args if the original sender is on the same hive
 484   (define (orig-actor-on-same-hive?)
 485     (equal? (hive-id hive)
 486             (address-hive-id (message-from original-message))))
 487   (set-message-replied! original-message #t)
 488   (let* ((new-message-body
 489           (if (orig-actor-on-same-hive?)
 490               `((original-message . ,original-message)
 491                 (error-key . ,error-key)
 492                 (error-args . ,error-args))
 493               `((original-message . ,original-message)
 494                 (error-key . ,error-key))))
 495          (new-message (make-message (hive-gen-message-id hive)
 496                                     (message-from original-message)
 497                                     (actor-id hive) '*error*
 498                                     new-message-body
 499                                     #:in-reply-to (message-id original-message))))
 500     (8sync-nowait (hive-process-message hive new-message))))
 501
 502 (define-method (hive-process-message (hive <hive>) message)
 503   "Handle one message, or forward it via an ambassador"
 504   (define (maybe-autoreply actor)
 505     ;; Possibly autoreply
 506     (if (message-needs-reply message)
 507         ;; @@: Should we give *autoreply* as the action instead of *reply*?
 508         (reply-message actor message
 509                        #:*auto-reply* #t)))
 510
 511   (define (resolve-actor-to)
 512     "Get the actor the message was aimed at"
 513     (let ((actor (hive-resolve-local-actor hive (message-to message))))
 514       (if (not actor)
 515           (throw 'actor-not-found
 516                  (format #f "Message ~a from ~a directed to nonexistant actor ~a"
 517                          (message-id message)
 518                          (address->string (message-from message))
 519                          (address->string (message-to message)))
 520                  message))
 521       actor))
 522
 523   (define (call-catching-coroutine thunk)
 524     (define (call-catching-errors)
 525       (with-throw-handler
 526           #t thunk
 527           (lambda (key . args)
 528             (if (message-needs-reply message)
 529                 ;; If the message is waiting on a reply, let them know
 530                 ;; something went wrong.
 531                 (hive-reply-with-error hive message key args)))))
 532     (call-with-prompt (hive-prompt hive)
 533       call-catching-errors
 534       (lambda (kont actor message)
 535         ;; Register the coroutine
 536         (hash-set! (hive-waiting-coroutines hive)
 537                    (message-id message)
 538                    (cons (actor-id actor) kont))
 539         ;; Send off the message
 540         (8sync (hive-process-message hive message)))))
 541
 542   (define (process-local-message)
 543     (let ((actor (resolve-actor-to)))
 544       (call-catching-coroutine
 545        (lambda ()
 546          (define message-handler (actor-message-handler actor))
 547          ;; @@: Should a more general error handling happen here?
 548          (let ((result
 549                 (message-handler actor message)))
 550            (maybe-autoreply actor)
 551            ;; Returning result allows actors to possibly make a run-request
 552            ;; at the end of handling a message.
 553            ;; ... We do want that, right?
 554            result)))))
 555
 556   (define (resume-waiting-coroutine)
 557     (cond
 558      ((eq? (message-action message) '*reply*)
 559       (call-catching-coroutine
 560        (lambda ()
 561          (match (hash-remove! (hive-waiting-coroutines hive)
 562                               (message-in-reply-to message))
 563            ((_ . (resume-actor-id . kont))
 564             (if (not (equal? (message-to message)
 565                              resume-actor-id))
 566                 (throw 'resuming-to-wrong-actor
 567                        "Attempted to resume a coroutine to the wrong actor!"
 568                        #:expected-actor-id (message-to message)
 569                        #:got-actor-id resume-actor-id
 570                        #:message message))
 571             (let (;; @@: How should we resolve resuming coroutines to actors who are
 572                   ;;   now gone?
 573                   (actor (resolve-actor-to))
 574                   (result (kont message)))
 575               (maybe-autoreply actor)
 576               result))
 577            (#f (throw 'no-waiting-coroutine
 578                       "message in-reply-to tries to resume nonexistent coroutine"
 579                       message))))))
 580      ;; Yikes, we must have gotten an error or something back
 581      (else
 582       ;; @@: Not what we want in the long run?
 583       ;; What we'd *prefer* to do is to resume this message
 584       ;; and throw an error inside the message handler
 585       ;; (say, from send-mesage-wait), but that causes a SIGABRT (??!!)
 586       (hash-remove! (hive-waiting-coroutines hive)
 587                     (message-in-reply-to message))
 588       (let ((explaination
 589              (if (eq? (message-action message) '*reply*)
 590                  "Won't resume coroutine; got an *error* as a reply"
 591                  "Won't resume coroutine because action is not *reply*")))
 592         (throw 'hive-unresumable-coroutine
 593                explaination
 594                #:message message)))))
 595
 596   (define (process-remote-message)
 597     ;; Find the ambassador
 598     (let* ((remote-hive-id (hive-id (message-to message)))
 599            (ambassador (hive-resolve-ambassador remote-hive-id))
 600            (message-handler (actor-message-handler ambassador))
 601            (forward-request (make-forward-request hive ambassador message)))
 602       (message-handler ambassador forward-request)))
 603
 604   (let ((to (message-to message)))
 605     ;; This seems to be an easy mistake to make, so check that addressing
 606     ;; is correct here
 607     (if (not to)
 608         (throw 'missing-addressee
 609                "`to' field is missing on message"
 610                #:message message))
 611     (if (hive-actor-local? hive to)
 612         (if (message-in-reply-to message)
 613             (resume-waiting-coroutine)
 614             (process-local-message))
 615         (process-remote-message))))
 616
 617 (define-method (hive-actor-local? (hive <hive>) address)
 618   (hash-ref (hive-actor-registry hive) address))
 619
 620 (define-method (hive-register-actor! (hive <hive>) (actor <actor>))
 621   (hash-set! (hive-actor-registry hive) (actor-id actor) actor))
 622
 623 (define-method (%hive-create-actor (hive <hive>) actor-class
 624                                    init id-cookie)
 625   "Actual method called by hive-create-actor.
 626
 627 Since this is a define-method it can't accept fancy define* arguments,
 628 so this gets called from the nicer hive-create-actor interface.  See
 629 that method for documentation."
 630   (let* ((actor-id (hive-gen-actor-id hive id-cookie))
 631          (actor (apply make actor-class
 632                        #:hive hive
 633                        #:id actor-id
 634                        init)))
 635     (hive-register-actor! hive actor)
 636     ;; return the actor id
 637     actor-id))
 638
 639 (define* (hive-create-actor hive actor-class #:rest init)
 640   (%hive-create-actor hive actor-class
 641                       init #f))
 642
 643 (define* (hive-create-actor* hive actor-class id-cookie #:rest init)
 644   (%hive-create-actor hive actor-class
 645                       init id-cookie))
 646
 647
 648 \f
 649 ;;; Various API methods for actors to interact with the system
 650 ;;; ==========================================================
 651
 652 ;; TODO: move send-message and friends here...?
 653
 654 (define* (create-actor from-actor actor-class #:rest init)
 655   "Create an instance of actor-class.  Return the new actor's id.
 656
 657 This is the method actors should call directly (unless they want
 658 to supply an id-cookie, in which case they should use
 659 create-actor*)."
 660   (8sync (%hive-create-actor (actor-hive from-actor) actor-class
 661                              init #f)))
 662
 663
 664 (define* (create-actor* from-actor actor-class id-cookie #:rest init)
 665   "Create an instance of actor-class.  Return the new actor's id.
 666
 667 Like create-actor, but permits supplying an id-cookie."
 668   (8sync (%hive-create-actor (actor-hive from-actor) actor-class
 669                              init id-cookie)))
 670
 671
 672 (define (self-destruct actor)
 673   "Remove an actor from the hive."
 674   (hash-remove! (hive-actor-registry (actor-hive actor))
 675                 (actor-id actor)))
 676
 677
 678 \f
 679 ;;; 8sync bootstrap utilities
 680 ;;; =========================
 681
 682 (define* (ez-run-hive hive initial-tasks #:key repl-server)
 683   "Start up an agenda and run HIVE in it with INITIAL-TASKS.
 684
 685 Should we start up a cooperative REPL for live hacking?  REPL-SERVER
 686 wants to know!  You can pass it #t or #f, or if you want to specify a port,
 687 an integer."
 688   (let* ((queue (list->q initial-tasks))
 689          (agenda (make-agenda #:pre-unwind-handler print-error-and-continue
 690                               #:queue queue)))
 691     (cond
 692      ;; If repl-server is an integer, we'll use that as the port
 693      ((integer? repl-server)
 694       (spawn-and-queue-repl-server! agenda repl-server))
 695      (repl-server
 696       (spawn-and-queue-repl-server! agenda)))
 697     (start-agenda agenda)))
 698
 699 (define (bootstrap-message hive to-id action . message-body-args)
 700   (wrap
 701    (apply send-message hive to-id action message-body-args)))
 702
 703
 704 \f
 705 ;;; Basic readers / writers
 706 ;;; =======================
 707
 708 (define (serialize-message message)
 709   "Serialize a message for read/write"
 710   (list
 711    (message-id message)
 712    (message-to message)
 713    (message-from message)
 714    (message-action message)
 715    (message-body message)
 716    (message-in-reply-to message)
 717    (message-wants-reply message)
 718    (message-replied message)
 719    (message-deferred-reply message)))
 720
 721 (define* (write-message message #:optional (port (current-output-port)))
 722   "Write out a message to a port for easy reading later.
 723
 724 Note that if a sub-value can't be easily written to something
 725 Guile's `read' procedure knows how to read, this doesn't do anything
 726 to improve that.  You'll need a better serializer for that.."
 727   (write (serialize-message message) port))
 728
 729 (define (serialize-message-pretty message)
 730   "Serialize a message in a way that's easy for humans to read."
 731   `(*message*
 732     (id ,(message-id message))
 733     (to ,(message-to message))
 734     (from ,(message-from message))
 735     (action ,(message-action message))
 736     (body ,(message-body message))
 737     (in-reply-to ,(message-in-reply-to message))
 738     (wants-reply ,(message-wants-reply message))
 739     (replied ,(message-replied message))
 740     (deferred-reply ,(message-deferred-reply message))))
 741
 742 (define (pprint-message message)
 743   "Pretty print a message."
 744   (pretty-print (serialize-message-pretty message)))
 745
 746 (define* (read-message #:optional (port (current-input-port)))
 747   "Read a message serialized via serialize-message from PORT"
 748   (match (read port)
 749     ((id to from action body in-reply-to wants-reply replied deferred-reply)
 750      (make-message-intern
 751       id to from action body
 752       in-reply-to wants-reply replied deferred-reply))
 753     (anything-else
 754      (throw 'message-read-bad-structure
 755             "Could not read message from structure"
 756             anything-else))))
 757
 758 (define (read-message-from-string message-str)
 759   "Read message from MESSAGE-STR"
 760   (with-input-from-string message-str
 761     (lambda ()
 762       (read-message (current-input-port)))))