8sync/systems/actors.scm

   1 ;;; 8sync --- Asynchronous programming for Guile
   2 ;;; Copyright (C) 2016 Christopher Allan Webber <cwebber@dustycloud.org>
   3 ;;;
   4 ;;; This file is part of 8sync.
   5 ;;;
   6 ;;; 8sync is free software: you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU Lesser General Public License as
   8 ;;; published by the Free Software Foundation, either version 3 of the
   9 ;;; License, or (at your option) any later version.
  10 ;;;
  11 ;;; 8sync is distributed in the hope that it will be useful,
  12 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU Lesser General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU Lesser General Public
  17 ;;; License along with 8sync.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;; XUDD inspired actor system
  20
  21 (define-module (8sync systems actors)
  22   #:use-module (oop goops)
  23   #:use-module (srfi srfi-9)
  24   #:use-module (srfi srfi-9 gnu)
  25   #:use-module (ice-9 format)
  26   #:use-module (ice-9 match)
  27   #:use-module (ice-9 pretty-print)
  28   #:use-module (8sync agenda)
  29   #:use-module (8sync repl)
  30   #:export (;; utilities... ought to go in their own module
  31             big-random-number
  32             big-random-number-string
  33             simple-message-id-generator
  34
  35             <actor>
  36             actor-id
  37             actor-message-handler
  38
  39             ;;; Commenting out the <address> type for now;
  40             ;;; it may be back when we have better serializers
  41             ;; <address>
  42             make-address address?
  43             address-actor-id address-hive-id
  44
  45             address->string
  46             actor-id-actor
  47             actor-id-hive
  48             actor-id-string
  49
  50             mlambda define-mhandler
  51             build-actions make-action-dispatch
  52             define-simple-actor
  53
  54             <hive>
  55             make-hive
  56             ;; There are more methods for the hive, but there's
  57             ;; no reason for the outside world to look at them maybe?
  58             hive-id
  59             hive-create-actor hive-create-actor*
  60
  61             create-actor create-actor*
  62             self-destruct
  63
  64             <message>
  65             make-message message?
  66             message-to message-action message-from
  67             message-id message-body message-in-reply-to
  68             message-wants-reply
  69             message-ref
  70
  71             send-message send-message-wait
  72             reply-message reply-message-wait
  73
  74             <- <-wait <-reply <-reply-wait
  75
  76             ez-run-hive
  77             bootstrap-message
  78
  79             serialize-message write-message
  80             serialize-message-pretty pprint-message
  81             read-message read-message-from-string))
  82
  83 ;; For ids
  84 (define %random-state
  85   (make-parameter (random-state-from-platform)))
  86
  87 ;; Same size as a uuid4 I think...
  88 (define random-number-size (expt 2 128))
  89
  90 (define (big-random-number)
  91   (random random-number-size (%random-state)))
  92
  93 ;; Would be great to get this base64 encoded instead.
  94 (define (big-random-number-string)
  95   ;; @@: This is slow.  Using format here is wasteful.
  96   (format #f "~x" (big-random-number)))
  97
  98 ;; @@: This is slow.  A mere ~275k / second on my (old) machine.
  99 ;;   The main cost seems to be in number->string.
 100 (define (simple-message-id-generator)
 101   ;; Prepending this cookie makes message ids unique per hive
 102   (let ((prefix (format #f "~x:" (big-random-number)))
 103         (counter 0))
 104     (lambda ()
 105       (set! counter (1+ counter))
 106       (string-append prefix (number->string counter)))))
 107
 108
 109 \f
 110 ;;; Messages
 111 ;;; ========
 112
 113
 114 (define-record-type <message>
 115   (make-message-intern id to from action
 116                        body in-reply-to wants-reply
 117                        replied
 118                        ;; @@: Not used yet.
 119                        ;; Will we ever find a real use case?
 120                        deferred-reply)
 121   message?
 122   (id message-id)
 123   (to message-to)
 124   (from message-from)
 125   (action message-action)
 126   (body message-body)
 127   (in-reply-to message-in-reply-to)
 128   (wants-reply message-wants-reply)
 129
 130   ;; See XUDD source for these.  Not use yet, maybe eventually will be?
 131   ;; XUDD uses them for autoreply.
 132   ;; Requiring mutation on message objects is clearly not great,
 133   ;; but it may be worth it...?  Investigate!
 134   (replied message-replied set-message-replied!)
 135   (deferred-reply message-deferred-reply set-message-deferred-reply!))
 136
 137
 138 (define* (make-message id to from action body
 139                        #:key in-reply-to wants-reply
 140                        replied deferred-reply)
 141   (make-message-intern id to from action body
 142                        in-reply-to wants-reply replied
 143                        deferred-reply))
 144
 145 ;; Note: the body of messages is currently an alist, but it's created
 146 ;;   from a keyword based property list (see the following two functions).
 147 ;;   But, that's an extra conversion step, and maybe totally unnecessary:
 148 ;;   we already have message-ref, and this could just pull a keyword
 149 ;;   from a property list.
 150 ;;   The main ways this might be useful are error checking,
 151 ;;   serialization across the wire (but even that might require some
 152 ;;   change), and using existing tooling (though adding new tooling
 153 ;;   would be negligible in implementation effort.)
 154
 155 ;; This cons cell is immutable and unique (for eq? tests)
 156 (define %nothing-provided (cons 'nothing 'provided))
 157
 158 (define* (message-ref message key #:optional (dflt %nothing-provided))
 159   "Extract KEY from body of MESSAGE.
 160
 161 Optionally set default with [DFLT]
 162 If key not found and DFLT not provided, throw an error."
 163   (let ((result (assoc key (message-body message))))
 164     (if result (cdr result)
 165         (if (eq? dflt %nothing-provided)
 166             (throw 'message-missing-key
 167                    "Message body does not contain key and no default provided"
 168                    #:key key
 169                    #:message message)
 170             dflt))))
 171
 172
 173 (define (message-needs-reply message)
 174   "See if this message needs a reply still"
 175   (and (message-wants-reply message)
 176        (not (or (message-replied message)
 177                 (message-deferred-reply message)))))
 178
 179
 180 (define (kwarg-list-to-alist args)
 181   (let loop ((remaining args)
 182              (result '()))
 183     (match remaining
 184       (((? keyword? key) val rest ...)
 185        (loop rest
 186              (cons (cons (keyword->symbol key) val)
 187                    result)))
 188       (() result)
 189       (_ (throw 'invalid-kwarg-list
 190                 "Invalid keyword argument list"
 191                 args)))))
 192
 193
 194 (define (send-message from-actor to-id action . message-body-args)
 195   "Send a message from an actor to another actor"
 196   (let* ((hive (actor-hive from-actor))
 197          (message (make-message (hive-gen-message-id hive) to-id
 198                                 (actor-id from-actor) action
 199                                 (kwarg-list-to-alist message-body-args))))
 200     (8sync-nowait (hive-process-message hive message))))
 201
 202 (define (send-message-wait from-actor to-id action . message-body-args)
 203   "Send a message from an actor to another, but wait until we get a response"
 204   (let* ((hive (actor-hive from-actor))
 205          (abort-to (hive-prompt (actor-hive from-actor)))
 206          (message (make-message (hive-gen-message-id hive) to-id
 207                                 (actor-id from-actor) action
 208                                 (kwarg-list-to-alist message-body-args)
 209                                 #:wants-reply #t)))
 210     (abort-to-prompt abort-to from-actor message)))
 211
 212 ;; TODO: Intelligently ~propagate(ish) errors on -wait functions.
 213 ;;   We might have `send-message-wait-brazen' to allow callers to
 214 ;;   not have an exception thrown and instead just have a message with
 215 ;;   the appropriate '*error* message returned.
 216
 217 (define (reply-message from-actor original-message
 218                        . message-body-args)
 219   "Reply to a message"
 220   (set-message-replied! original-message #t)
 221   (let* ((hive (actor-hive from-actor))
 222          (new-message (make-message (hive-gen-message-id hive)
 223                                     (message-from original-message)
 224                                     (actor-id from-actor) '*reply*
 225                                     (kwarg-list-to-alist message-body-args)
 226                                     #:in-reply-to (message-id original-message))))
 227     (8sync-nowait (hive-process-message hive new-message))))
 228
 229 (define (reply-message-wait from-actor original-message
 230                             . message-body-args)
 231   "Reply to a messsage, but wait until we get a response"
 232   (set-message-replied! original-message #t)
 233   (let* ((hive (actor-hive from-actor))
 234          (abort-to (hive-prompt (actor-hive from-actor)))
 235          (new-message (make-message (hive-gen-message-id hive)
 236                                     (message-from original-message)
 237                                     (actor-id from-actor) '*reply*
 238                                     (kwarg-list-to-alist message-body-args)
 239                                     #:wants-reply #t
 240                                     #:in-reply-to (message-id original-message))))
 241     (abort-to-prompt abort-to from-actor new-message)))
 242
 243
 244 ;;; Aliases!
 245 ;;; See: http://mumble.net/~jar/articles/oo-moon-weinreb.html
 246 ;;;   (also worth seeing: http://mumble.net/~jar/articles/oo.html )
 247
 248 (define <- send-message)
 249 (define <-wait send-message-wait)
 250 (define <-reply reply-message)
 251 (define <-reply-wait reply-message-wait)
 252
 253
 254 \f
 255 ;;; Main actor implementation
 256 ;;; =========================
 257
 258 (define-class <actor> ()
 259   ;; An address object
 260   (id #:init-keyword #:id
 261       #:getter actor-id)
 262   ;; The hive we're connected to.
 263   ;; We need this to be able to send messages.
 264   (hive #:init-keyword #:hive
 265         #:accessor actor-hive)
 266   ;; How we receive and process new messages
 267   (message-handler #:allocation #:each-subclass))
 268
 269 (define-method (actor-message-handler (actor <actor>))
 270   (slot-ref actor 'message-handler))
 271
 272 ;;; So these are the nicer representations of addresses.
 273 ;;; However, they don't serialize so easily with scheme read/write, so we're
 274 ;;; using the simpler cons cell version below for now.
 275
 276 ;; (define-record-type <address>
 277 ;;   (make-address actor-id hive-id)  ; @@: Do we want the trailing -id?
 278 ;;   address?
 279 ;;   (actor-id address-actor-id)
 280 ;;   (hive-id address-hive-id))
 281 ;;
 282 ;; (set-record-type-printer!
 283 ;;  <address>
 284 ;;  (lambda (record port)
 285 ;;    (format port "<address: ~s@~s>"
 286 ;;            (address-actor-id record) (address-hive-id record))))
 287 ;;
 288
 289 (define (make-address actor-id hive-id)
 290   (cons actor-id hive-id))
 291
 292 (define (address-actor-id address)
 293   (car address))
 294
 295 (define (address-hive-id address)
 296   (cdr address))
 297
 298 (define (address->string address)
 299   (string-append (address-actor-id address) "@"
 300                  (address-hive-id address)))
 301
 302 (define-method (actor-id-actor (actor <actor>))
 303   "Get the actor id component of the actor-id"
 304   (address-actor-id (actor-id actor)))
 305
 306 (define-method (actor-id-hive (actor <actor>))
 307   "Get the hive id component of the actor-id"
 308   (address-hive-id (actor-id actor)))
 309
 310 (define-method (actor-id-string (actor <actor>))
 311   "Render the full actor id as a human-readable string"
 312   (address->string (actor-id actor)))
 313
 314
 315 \f
 316 ;;; Actor utilities
 317 ;;; ===============
 318
 319
 320 (define-syntax-rule (with-message-args (message message-arg ...)
 321                                        body body* ...)
 322   (let ((message-arg (message-ref message (quote message-arg))) ...)
 323     body body* ...))
 324
 325 (define-syntax mlambda
 326   (syntax-rules ()
 327     "A lambda for building message handlers.
 328
 329 Use it like:
 330   (mlambda (actor message foo)
 331     ...)
 332
 333 Which is like doing manually:
 334   (lambda (actor message)
 335     (let ((foo (message-ref message foo)))
 336       ...))"
 337     ((_ (actor message message-arg ...)
 338         body body* ...)
 339      (lambda (actor message)
 340        (with-message-args (message message-arg ...) body body* ...)))))
 341
 342 ;; @@: Sadly, docstrings won't work with this...
 343 ;;   I think we need to bust out syntax-case to make that happen...
 344 (define-syntax-rule (define-mhandler (name actor message message-arg ...)
 345                       body ...)
 346   (define name
 347     (mlambda (actor message message-arg ...)
 348              body ...)))
 349
 350 (define (simple-dispatcher action-map)
 351   (lambda (actor message)
 352     (let* ((action (message-action message))
 353            (method (assoc-ref action-map action)))
 354       (if (not method)
 355           ;; @@: There's every possibility this should be handled in
 356           ;;  hive-process-message instead.
 357           (throw 'action-not-found
 358                  "No appropriate action handler found for actor"
 359                  #:action action
 360                  #:actor actor
 361                  #:message message
 362                  #:available-actions (map car action-map)))
 363       (method actor message))))
 364
 365 (define-syntax %expand-action-item
 366   (syntax-rules ()
 367     ((_ ((action-name action-args ...) body ...))
 368      (cons (quote action-name)
 369            (mlambda (action-args ...)
 370              body ...)))
 371     ((_ (action-name handler))
 372      (cons (quote action-name) handler))))
 373
 374 (define-syntax-rule (build-actions action-item ...)
 375   "Build a mapping of actions.  Same syntax as make-action-dispatch
 376 but this doesn't build the dispatcher for you (you probably want to
 377 pass it to simple-dispatcher).
 378
 379 The advantage here is that since this simply builds an alist, you can
 380 compose it with other action maps."
 381   (list (%expand-action-item action-item) ...))
 382
 383 (define-syntax make-action-dispatch
 384   (syntax-rules ()
 385     "Expand a list of action names and actions into an alist
 386
 387 You can use this like the following:
 388   (make-action-dispatch
 389    (cookies
 390     (lambda (actor message)
 391       (display \"I love cookies!\n\")))
 392    (party
 393     (lambda (actor message)
 394       (display \"Life of the party!\"))))
 395
 396 Alternately, if you'd like to skip the lambda, you could use the slightly
 397 more compact following syntax:
 398   (make-action-dispatch
 399    ((cookies actor message)
 400      (display \"I love cookies!\n\"))
 401    ((party actor message)
 402      (display \"Life of the party!\")))"
 403     ((make-action-dispatch action-item ...)
 404      (simple-dispatcher (build-actions action-item ...)))))
 405
 406 (define-syntax-rule (define-simple-actor class actions ...)
 407   (define-class class (<actor>)
 408     (message-handler
 409      #:init-value (make-action-dispatch actions ...)
 410      #:allocation #:each-subclass)))
 411
 412 \f
 413 ;;; The Hive
 414 ;;; ========
 415 ;;;   Every actor has a hive.  The hive is a kind of "meta-actor"
 416 ;;;   which routes all the rest of the actors in a system.
 417
 418 (define-generic hive-handle-failed-forward)
 419
 420 (define-class <hive> (<actor>)
 421   (actor-registry #:init-thunk make-hash-table
 422                   #:getter hive-actor-registry)
 423   (msg-id-generator #:init-thunk simple-message-id-generator
 424                     #:getter hive-msg-id-generator)
 425   ;; Ambassadors are used (or will be) for inter-hive communication.
 426   ;; These are special actors that know how to route messages to other hives.
 427   (ambassadors #:init-thunk make-weak-key-hash-table
 428                #:getter hive-ambassadors)
 429   ;; Waiting coroutines
 430   ;; This is a map from cons cell of message-id
 431   ;;   to a cons cell of (actor-id . coroutine)
 432   ;; @@: Should we have a <waiting-coroutine> record type?
 433   ;; @@: Should there be any way to clear out "old" coroutines?
 434   (waiting-coroutines #:init-thunk make-hash-table
 435                       #:getter hive-waiting-coroutines)
 436   ;; Message prompt
 437   ;; When actors send messages to each other they abort to this prompt
 438   ;; to send the message, then carry on their way
 439   (prompt #:init-thunk make-prompt-tag
 440           #:getter hive-prompt)
 441   (message-handler
 442    #:init-value
 443    (make-action-dispatch
 444     ;; This is in the case of an ambassador failing to forward a message...
 445     ;; it reports it back to the hive
 446     (*failed-forward* hive-handle-failed-forward))))
 447
 448 (define-method (hive-handle-failed-forward (hive <hive>) message)
 449   "Handle an ambassador failing to forward a message"
 450   'TODO)
 451
 452 (define* (make-hive #:key hive-id)
 453   (let ((hive (make <hive>
 454                 #:id (make-address
 455                       "hive" (or hive-id
 456                                  (big-random-number-string))))))
 457     ;; Set the hive's actor reference to itself
 458     (set! (actor-hive hive) hive)
 459     hive))
 460
 461 (define-method (hive-id (hive <hive>))
 462   (actor-id-hive hive))
 463
 464 (define-method (hive-gen-actor-id (hive <hive>) cookie)
 465   (make-address (if cookie
 466                     (string-append cookie "-" (big-random-number-string))
 467                     (big-random-number-string))
 468                 (hive-id hive)))
 469
 470 (define-method (hive-gen-message-id (hive <hive>))
 471   "Generate a message id using HIVE's message id generator"
 472   ((hive-msg-id-generator hive)))
 473
 474 (define-method (hive-resolve-local-actor (hive <hive>) actor-address)
 475   (hash-ref (hive-actor-registry hive) actor-address))
 476
 477 (define-method (hive-resolve-ambassador (hive <hive>) ambassador-address)
 478   (hash-ref (hive-ambassadors hive) ambassador-address))
 479
 480 (define-method (make-forward-request (hive <hive>) (ambassador <actor>) message)
 481   (make-message (hive-gen-message-id hive) (actor-id ambassador)
 482                 ;; If we make the hive not an actor, we could either switch this
 483                 ;; to #f or to the original actor...?
 484                 ;; Maybe some more thinking should be done on what should
 485                 ;; happen in case of failure to forward?  Handling ambassador failures
 486                 ;; seems like the primary motivation for the hive remaining an actor.
 487                 (actor-id hive)
 488                 '*forward*
 489                 `((original . ,message))))
 490
 491 (define-method (hive-reply-with-error (hive <hive>) original-message
 492                                       error-key error-args)
 493   ;; We only supply the error-args if the original sender is on the same hive
 494   (define (orig-actor-on-same-hive?)
 495     (equal? (hive-id hive)
 496             (address-hive-id (message-from original-message))))
 497   (set-message-replied! original-message #t)
 498   (let* ((new-message-body
 499           (if (orig-actor-on-same-hive?)
 500               `((original-message . ,original-message)
 501                 (error-key . ,error-key)
 502                 (error-args . ,error-args))
 503               `((original-message . ,original-message)
 504                 (error-key . ,error-key))))
 505          (new-message (make-message (hive-gen-message-id hive)
 506                                     (message-from original-message)
 507                                     (actor-id hive) '*error*
 508                                     new-message-body
 509                                     #:in-reply-to (message-id original-message))))
 510     (8sync-nowait (hive-process-message hive new-message))))
 511
 512 (define-method (hive-process-message (hive <hive>) message)
 513   "Handle one message, or forward it via an ambassador"
 514   (define (maybe-autoreply actor)
 515     ;; Possibly autoreply
 516     (if (message-needs-reply message)
 517         ;; @@: Should we give *autoreply* as the action instead of *reply*?
 518         (reply-message actor message
 519                        #:*auto-reply* #t)))
 520
 521   (define (resolve-actor-to)
 522     "Get the actor the message was aimed at"
 523     (let ((actor (hive-resolve-local-actor hive (message-to message))))
 524       (if (not actor)
 525           (throw 'actor-not-found
 526                  (format #f "Message ~a from ~a directed to nonexistant actor ~a"
 527                          (message-id message)
 528                          (address->string (message-from message))
 529                          (address->string (message-to message)))
 530                  message))
 531       actor))
 532
 533   (define (call-catching-coroutine thunk)
 534     (define (call-catching-errors)
 535       (with-throw-handler
 536           #t thunk
 537           (lambda (key . args)
 538             (if (message-needs-reply message)
 539                 ;; If the message is waiting on a reply, let them know
 540                 ;; something went wrong.
 541                 (hive-reply-with-error hive message key args)))))
 542     (call-with-prompt (hive-prompt hive)
 543       call-catching-errors
 544       (lambda (kont actor message)
 545         ;; Register the coroutine
 546         (hash-set! (hive-waiting-coroutines hive)
 547                    (message-id message)
 548                    (cons (actor-id actor) kont))
 549         ;; Send off the message
 550         (8sync (hive-process-message hive message)))))
 551
 552   (define (process-local-message)
 553     (let ((actor (resolve-actor-to)))
 554       (call-catching-coroutine
 555        (lambda ()
 556          (define message-handler (actor-message-handler actor))
 557          ;; @@: Should a more general error handling happen here?
 558          (let ((result
 559                 (message-handler actor message)))
 560            (maybe-autoreply actor)
 561            ;; Returning result allows actors to possibly make a run-request
 562            ;; at the end of handling a message.
 563            ;; ... We do want that, right?
 564            result)))))
 565
 566   (define (resume-waiting-coroutine)
 567     (cond
 568      ((eq? (message-action message) '*reply*)
 569       (call-catching-coroutine
 570        (lambda ()
 571          (match (hash-remove! (hive-waiting-coroutines hive)
 572                               (message-in-reply-to message))
 573            ((_ . (resume-actor-id . kont))
 574             (if (not (equal? (message-to message)
 575                              resume-actor-id))
 576                 (throw 'resuming-to-wrong-actor
 577                        "Attempted to resume a coroutine to the wrong actor!"
 578                        #:expected-actor-id (message-to message)
 579                        #:got-actor-id resume-actor-id
 580                        #:message message))
 581             (let (;; @@: How should we resolve resuming coroutines to actors who are
 582                   ;;   now gone?
 583                   (actor (resolve-actor-to))
 584                   (result (kont message)))
 585               (maybe-autoreply actor)
 586               result))
 587            (#f (throw 'no-waiting-coroutine
 588                       "message in-reply-to tries to resume nonexistent coroutine"
 589                       message))))))
 590      ;; Yikes, we must have gotten an error or something back
 591      (else
 592       ;; @@: Not what we want in the long run?
 593       ;; What we'd *prefer* to do is to resume this message
 594       ;; and throw an error inside the message handler
 595       ;; (say, from send-mesage-wait), but that causes a SIGABRT (??!!)
 596       (hash-remove! (hive-waiting-coroutines hive)
 597                     (message-in-reply-to message))
 598       (let ((explaination
 599              (if (eq? (message-action message) '*reply*)
 600                  "Won't resume coroutine; got an *error* as a reply"
 601                  "Won't resume coroutine because action is not *reply*")))
 602         (throw 'hive-unresumable-coroutine
 603                explaination
 604                #:message message)))))
 605
 606   (define (process-remote-message)
 607     ;; Find the ambassador
 608     (let* ((remote-hive-id (hive-id (message-to message)))
 609            (ambassador (hive-resolve-ambassador remote-hive-id))
 610            (message-handler (actor-message-handler ambassador))
 611            (forward-request (make-forward-request hive ambassador message)))
 612       (message-handler ambassador forward-request)))
 613
 614   (let ((to (message-to message)))
 615     ;; This seems to be an easy mistake to make, so check that addressing
 616     ;; is correct here
 617     (if (not to)
 618         (throw 'missing-addressee
 619                "`to' field is missing on message"
 620                #:message message))
 621     (if (hive-actor-local? hive to)
 622         (if (message-in-reply-to message)
 623             (resume-waiting-coroutine)
 624             (process-local-message))
 625         (process-remote-message))))
 626
 627 (define-method (hive-actor-local? (hive <hive>) address)
 628   (hash-ref (hive-actor-registry hive) address))
 629
 630 (define-method (hive-register-actor! (hive <hive>) (actor <actor>))
 631   (hash-set! (hive-actor-registry hive) (actor-id actor) actor))
 632
 633 (define-method (%hive-create-actor (hive <hive>) actor-class
 634                                    init id-cookie)
 635   "Actual method called by hive-create-actor.
 636
 637 Since this is a define-method it can't accept fancy define* arguments,
 638 so this gets called from the nicer hive-create-actor interface.  See
 639 that method for documentation."
 640   (let* ((actor-id (hive-gen-actor-id hive id-cookie))
 641          (actor (apply make actor-class
 642                        #:hive hive
 643                        #:id actor-id
 644                        init)))
 645     (hive-register-actor! hive actor)
 646     ;; return the actor id
 647     actor-id))
 648
 649 (define* (hive-create-actor hive actor-class #:rest init)
 650   (%hive-create-actor hive actor-class
 651                       init #f))
 652
 653 (define* (hive-create-actor* hive actor-class id-cookie #:rest init)
 654   (%hive-create-actor hive actor-class
 655                       init id-cookie))
 656
 657
 658 \f
 659 ;;; Various API methods for actors to interact with the system
 660 ;;; ==========================================================
 661
 662 ;; TODO: move send-message and friends here...?
 663
 664 (define* (create-actor from-actor actor-class #:rest init)
 665   "Create an instance of actor-class.  Return the new actor's id.
 666
 667 This is the method actors should call directly (unless they want
 668 to supply an id-cookie, in which case they should use
 669 create-actor*)."
 670   (8sync (%hive-create-actor (actor-hive from-actor) actor-class
 671                              init #f)))
 672
 673
 674 (define* (create-actor* from-actor actor-class id-cookie #:rest init)
 675   "Create an instance of actor-class.  Return the new actor's id.
 676
 677 Like create-actor, but permits supplying an id-cookie."
 678   (8sync (%hive-create-actor (actor-hive from-actor) actor-class
 679                              init id-cookie)))
 680
 681
 682 (define (self-destruct actor)
 683   "Remove an actor from the hive."
 684   (hash-remove! (hive-actor-registry (actor-hive actor))
 685                 (actor-id actor)))
 686
 687
 688 \f
 689 ;;; 8sync bootstrap utilities
 690 ;;; =========================
 691
 692 (define* (ez-run-hive hive initial-tasks #:key repl-server)
 693   "Start up an agenda and run HIVE in it with INITIAL-TASKS.
 694
 695 Should we start up a cooperative REPL for live hacking?  REPL-SERVER
 696 wants to know!  You can pass it #t or #f, or if you want to specify a port,
 697 an integer."
 698   (let* ((queue (list->q initial-tasks))
 699          (agenda (make-agenda #:pre-unwind-handler print-error-and-continue
 700                               #:queue queue)))
 701     (cond
 702      ;; If repl-server is an integer, we'll use that as the port
 703      ((integer? repl-server)
 704       (spawn-and-queue-repl-server! agenda repl-server))
 705      (repl-server
 706       (spawn-and-queue-repl-server! agenda)))
 707     (start-agenda agenda)))
 708
 709 (define (bootstrap-message hive to-id action . message-body-args)
 710   (wrap
 711    (apply send-message hive to-id action message-body-args)))
 712
 713
 714 \f
 715 ;;; Basic readers / writers
 716 ;;; =======================
 717
 718 (define (serialize-message message)
 719   "Serialize a message for read/write"
 720   (list
 721    (message-id message)
 722    (message-to message)
 723    (message-from message)
 724    (message-action message)
 725    (message-body message)
 726    (message-in-reply-to message)
 727    (message-wants-reply message)
 728    (message-replied message)
 729    (message-deferred-reply message)))
 730
 731 (define* (write-message message #:optional (port (current-output-port)))
 732   "Write out a message to a port for easy reading later.
 733
 734 Note that if a sub-value can't be easily written to something
 735 Guile's `read' procedure knows how to read, this doesn't do anything
 736 to improve that.  You'll need a better serializer for that.."
 737   (write (serialize-message message) port))
 738
 739 (define (serialize-message-pretty message)
 740   "Serialize a message in a way that's easy for humans to read."
 741   `(*message*
 742     (id ,(message-id message))
 743     (to ,(message-to message))
 744     (from ,(message-from message))
 745     (action ,(message-action message))
 746     (body ,(message-body message))
 747     (in-reply-to ,(message-in-reply-to message))
 748     (wants-reply ,(message-wants-reply message))
 749     (replied ,(message-replied message))
 750     (deferred-reply ,(message-deferred-reply message))))
 751
 752 (define (pprint-message message)
 753   "Pretty print a message."
 754   (pretty-print (serialize-message-pretty message)))
 755
 756 (define* (read-message #:optional (port (current-input-port)))
 757   "Read a message serialized via serialize-message from PORT"
 758   (match (read port)
 759     ((id to from action body in-reply-to wants-reply replied deferred-reply)
 760      (make-message-intern
 761       id to from action body
 762       in-reply-to wants-reply replied deferred-reply))
 763     (anything-else
 764      (throw 'message-read-bad-structure
 765             "Could not read message from structure"
 766             anything-else))))
 767
 768 (define (read-message-from-string message-str)
 769   "Read message from MESSAGE-STR"
 770   (with-input-from-string message-str
 771     (lambda ()
 772       (read-message (current-input-port)))))