8sync/systems/actors.scm

   1 ;;; 8sync --- Asynchronous programming for Guile
   2 ;;; Copyright (C) 2016 Christopher Allan Webber <cwebber@dustycloud.org>
   3 ;;;
   4 ;;; This file is part of 8sync.
   5 ;;;
   6 ;;; 8sync is free software: you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU Lesser General Public License as
   8 ;;; published by the Free Software Foundation, either version 3 of the
   9 ;;; License, or (at your option) any later version.
  10 ;;;
  11 ;;; 8sync is distributed in the hope that it will be useful,
  12 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU Lesser General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU Lesser General Public
  17 ;;; License along with 8sync.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;; XUDD inspired actor system
  20
  21 (define-module (8sync systems actors)
  22   #:use-module (oop goops)
  23   #:use-module (srfi srfi-9)
  24   #:use-module (srfi srfi-9 gnu)
  25   #:use-module (ice-9 format)
  26   #:use-module (ice-9 match)
  27   #:use-module (ice-9 pretty-print)
  28   #:use-module (8sync agenda)
  29   #:use-module (8sync repl)
  30   #:export (;; utilities... ought to go in their own module
  31             big-random-number
  32             big-random-number-string
  33             simple-message-id-generator
  34
  35             <actor>
  36             actor-id
  37             actor-message-handler
  38
  39             ;;; Commenting out the <address> type for now;
  40             ;;; it may be back when we have better serializers
  41             ;; <address>
  42             make-address address?
  43             address-actor-id address-hive-id
  44
  45             address->string
  46             actor-id-actor
  47             actor-id-hive
  48             actor-id-string
  49
  50             mlambda define-mhandler
  51             make-action-dispatch
  52             define-simple-actor
  53
  54             <hive>
  55             make-hive
  56             ;; There are more methods for the hive, but there's
  57             ;; no reason for the outside world to look at them maybe?
  58             hive-id
  59             hive-create-actor hive-create-actor*
  60
  61             create-actor create-actor*
  62             self-destruct
  63
  64             <message>
  65             make-message message?
  66             message-to message-action message-from
  67             message-id message-body message-in-reply-to
  68             message-wants-reply
  69             message-ref
  70
  71             send-message send-message-wait
  72             reply-message reply-message-wait
  73
  74             <- <-wait <-reply <-reply-wait
  75
  76             ez-run-hive
  77             bootstrap-message
  78
  79             serialize-message write-message
  80             serialize-message-pretty pprint-message
  81             read-message read-message-from-string))
  82
  83 ;; For ids
  84 (define %random-state
  85   (make-parameter (random-state-from-platform)))
  86
  87 ;; Same size as a uuid4 I think...
  88 (define random-number-size (expt 2 128))
  89
  90 (define (big-random-number)
  91   (random random-number-size (%random-state)))
  92
  93 ;; Would be great to get this base64 encoded instead.
  94 (define (big-random-number-string)
  95   ;; @@: This is slow.  Using format here is wasteful.
  96   (format #f "~x" (big-random-number)))
  97
  98 ;; @@: This is slow.  A mere ~275k / second on my (old) machine.
  99 ;;   The main cost seems to be in number->string.
 100 (define (simple-message-id-generator)
 101   ;; Prepending this cookie makes message ids unique per hive
 102   (let ((prefix (format #f "~x:" (big-random-number)))
 103         (counter 0))
 104     (lambda ()
 105       (set! counter (1+ counter))
 106       (string-append prefix (number->string counter)))))
 107
 108
 109 \f
 110 ;;; Messages
 111 ;;; ========
 112
 113
 114 (define-record-type <message>
 115   (make-message-intern id to from action
 116                        body in-reply-to wants-reply
 117                        replied
 118                        ;; @@: Not used yet.
 119                        ;; Will we ever find a real use case?
 120                        deferred-reply)
 121   message?
 122   (id message-id)
 123   (to message-to)
 124   (from message-from)
 125   (action message-action)
 126   (body message-body)
 127   (in-reply-to message-in-reply-to)
 128   (wants-reply message-wants-reply)
 129
 130   ;; See XUDD source for these.  Not use yet, maybe eventually will be?
 131   ;; XUDD uses them for autoreply.
 132   ;; Requiring mutation on message objects is clearly not great,
 133   ;; but it may be worth it...?  Investigate!
 134   (replied message-replied set-message-replied!)
 135   (deferred-reply message-deferred-reply set-message-deferred-reply!))
 136
 137
 138 (define* (make-message id to from action body
 139                        #:key in-reply-to wants-reply
 140                        replied deferred-reply)
 141   (make-message-intern id to from action body
 142                        in-reply-to wants-reply replied
 143                        deferred-reply))
 144
 145 ;; Note: the body of messages is currently an alist, but it's created
 146 ;;   from a keyword based property list (see the following two functions).
 147 ;;   But, that's an extra conversion step, and maybe totally unnecessary:
 148 ;;   we already have message-ref, and this could just pull a keyword
 149 ;;   from a property list.
 150 ;;   The main ways this might be useful are error checking,
 151 ;;   serialization across the wire (but even that might require some
 152 ;;   change), and using existing tooling (though adding new tooling
 153 ;;   would be negligible in implementation effort.)
 154
 155 ;; This cons cell is immutable and unique (for eq? tests)
 156 (define %nothing-provided (cons 'nothing 'provided))
 157
 158 (define* (message-ref message key #:optional (dflt %nothing-provided))
 159   "Extract KEY from body of MESSAGE.
 160
 161 Optionally set default with [DFLT]
 162 If key not found and DFLT not provided, throw an error."
 163   (let ((result (assoc key (message-body message))))
 164     (if result (cdr result)
 165         (if (eq? dflt %nothing-provided)
 166             (throw 'message-missing-key
 167                    "Message body does not contain key and no default provided"
 168                    #:key key
 169                    #:message message)
 170             dflt))))
 171
 172
 173 (define (message-needs-reply message)
 174   "See if this message needs a reply still"
 175   (and (message-wants-reply message)
 176        (not (or (message-replied message)
 177                 (message-deferred-reply message)))))
 178
 179
 180 (define (kwarg-list-to-alist args)
 181   (let loop ((remaining args)
 182              (result '()))
 183     (match remaining
 184       (((? keyword? key) val rest ...)
 185        (loop rest
 186              (cons (cons (keyword->symbol key) val)
 187                    result)))
 188       (() result)
 189       (_ (throw 'invalid-kwarg-list
 190                 "Invalid keyword argument list"
 191                 args)))))
 192
 193
 194 (define (send-message from-actor to-id action . message-body-args)
 195   "Send a message from an actor to another actor"
 196   (let* ((hive (actor-hive from-actor))
 197          (message (make-message (hive-gen-message-id hive) to-id
 198                                 (actor-id from-actor) action
 199                                 (kwarg-list-to-alist message-body-args))))
 200     (8sync-nowait (hive-process-message hive message))))
 201
 202 (define (send-message-wait from-actor to-id action . message-body-args)
 203   "Send a message from an actor to another, but wait until we get a response"
 204   (let* ((hive (actor-hive from-actor))
 205          (abort-to (hive-prompt (actor-hive from-actor)))
 206          (message (make-message (hive-gen-message-id hive) to-id
 207                                 (actor-id from-actor) action
 208                                 (kwarg-list-to-alist message-body-args)
 209                                 #:wants-reply #t)))
 210     (abort-to-prompt abort-to from-actor message)))
 211
 212 ;; TODO: Intelligently ~propagate(ish) errors on -wait functions.
 213 ;;   We might have `send-message-wait-brazen' to allow callers to
 214 ;;   not have an exception thrown and instead just have a message with
 215 ;;   the appropriate '*error* message returned.
 216
 217 (define (reply-message from-actor original-message
 218                        . message-body-args)
 219   "Reply to a message"
 220   (set-message-replied! original-message #t)
 221   (let* ((hive (actor-hive from-actor))
 222          (new-message (make-message (hive-gen-message-id hive)
 223                                     (message-from original-message)
 224                                     (actor-id from-actor) '*reply*
 225                                     (kwarg-list-to-alist message-body-args)
 226                                     #:in-reply-to (message-id original-message))))
 227     (8sync-nowait (hive-process-message hive new-message))))
 228
 229 (define (reply-message-wait from-actor original-message
 230                             . message-body-args)
 231   "Reply to a messsage, but wait until we get a response"
 232   (set-message-replied! original-message #t)
 233   (let* ((hive (actor-hive from-actor))
 234          (abort-to (hive-prompt (actor-hive from-actor)))
 235          (new-message (make-message (hive-gen-message-id hive)
 236                                     (message-from original-message)
 237                                     (actor-id from-actor) '*reply*
 238                                     (kwarg-list-to-alist message-body-args)
 239                                     #:wants-reply #t
 240                                     #:in-reply-to (message-id original-message))))
 241     (abort-to-prompt abort-to from-actor new-message)))
 242
 243
 244 ;;; Aliases!
 245 ;;; See: http://mumble.net/~jar/articles/oo-moon-weinreb.html
 246 ;;;   (also worth seeing: http://mumble.net/~jar/articles/oo.html )
 247
 248 (define <- send-message)
 249 (define <-wait send-message-wait)
 250 (define <-reply reply-message)
 251 (define <-reply-wait reply-message-wait)
 252
 253
 254 \f
 255 ;;; Main actor implementation
 256 ;;; =========================
 257
 258 (define-class <actor> ()
 259   ;; An address object
 260   (id #:init-keyword #:id
 261       #:getter actor-id)
 262   ;; The hive we're connected to.
 263   ;; We need this to be able to send messages.
 264   (hive #:init-keyword #:hive
 265         #:accessor actor-hive)
 266   ;; How we receive and process new messages
 267   (message-handler #:allocation #:each-subclass))
 268
 269 (define-method (actor-message-handler (actor <actor>))
 270   (slot-ref actor 'message-handler))
 271
 272 ;;; So these are the nicer representations of addresses.
 273 ;;; However, they don't serialize so easily with scheme read/write, so we're
 274 ;;; using the simpler cons cell version below for now.
 275
 276 ;; (define-record-type <address>
 277 ;;   (make-address actor-id hive-id)  ; @@: Do we want the trailing -id?
 278 ;;   address?
 279 ;;   (actor-id address-actor-id)
 280 ;;   (hive-id address-hive-id))
 281 ;;
 282 ;; (set-record-type-printer!
 283 ;;  <address>
 284 ;;  (lambda (record port)
 285 ;;    (format port "<address: ~s@~s>"
 286 ;;            (address-actor-id record) (address-hive-id record))))
 287 ;;
 288
 289 (define (make-address actor-id hive-id)
 290   (cons actor-id hive-id))
 291
 292 (define (address-actor-id address)
 293   (car address))
 294
 295 (define (address-hive-id address)
 296   (cdr address))
 297
 298 (define (address->string address)
 299   (string-append (address-actor-id address) "@"
 300                  (address-hive-id address)))
 301
 302 (define-method (actor-id-actor (actor <actor>))
 303   "Get the actor id component of the actor-id"
 304   (address-actor-id (actor-id actor)))
 305
 306 (define-method (actor-id-hive (actor <actor>))
 307   "Get the hive id component of the actor-id"
 308   (address-hive-id (actor-id actor)))
 309
 310 (define-method (actor-id-string (actor <actor>))
 311   "Render the full actor id as a human-readable string"
 312   (address->string (actor-id actor)))
 313
 314
 315 \f
 316 ;;; Actor utilities
 317 ;;; ===============
 318
 319
 320 (define-syntax-rule (with-message-args (message message-arg ...)
 321                                        body body* ...)
 322   (let ((message-arg (message-ref message (quote message-arg))) ...)
 323     body body* ...))
 324
 325 (define-syntax mlambda
 326   (syntax-rules ()
 327     "A lambda for building message handlers.
 328
 329 Use it like:
 330   (mlambda (actor message foo)
 331     ...)
 332
 333 Which is like doing manually:
 334   (lambda (actor message)
 335     (let ((foo (message-ref message foo)))
 336       ...))"
 337     ((_ (actor message message-arg ...)
 338         body body* ...)
 339      (lambda (actor message)
 340        (with-message-args (message message-arg ...) body body* ...)))))
 341
 342 ;; @@: Sadly, docstrings won't work with this...
 343 ;;   I think we need to bust out syntax-case to make that happen...
 344 (define-syntax-rule (define-mhandler (name actor message message-arg ...)
 345                       body ...)
 346   (define name
 347     (mlambda (actor message message-arg ...)
 348              body ...)))
 349
 350 (define (simple-dispatcher action-map)
 351   (lambda (actor message)
 352     (let* ((action (message-action message))
 353            (method (assoc-ref action-map action)))
 354       (if (not method)
 355           (throw 'action-not-found
 356                  "No appropriate action handler found for actor"
 357                  #:action action
 358                  #:actor actor
 359                  #:message message
 360                  #:available-actions (map car action-map)))
 361       (method actor message))))
 362
 363 (define-syntax %expand-action-item
 364   (syntax-rules ()
 365     ((_ ((action-name action-args ...) body ...))
 366      (cons (quote action-name)
 367            (mlambda (action-args ...)
 368              body ...)))
 369     ((_ (action-name handler))
 370      (cons (quote action-name) handler))))
 371
 372 (define-syntax-rule (build-actions action-item ...)
 373   (list (%expand-action-item action-item) ...))
 374
 375 (define-syntax make-action-dispatch
 376   (syntax-rules ()
 377     "Expand a list of action names and actions into an alist
 378
 379 You can use this like the following:
 380   (make-action-dispatch
 381    (cookies
 382     (lambda (actor message)
 383       (display \"I love cookies!\n\")))
 384    (party
 385     (lambda (actor message)
 386       (display \"Life of the party!\"))))
 387
 388 Alternately, if you'd like to skip the lambda, you could use the slightly
 389 more compact following syntax:
 390   (make-action-dispatch
 391    ((cookies actor message)
 392      (display \"I love cookies!\n\"))
 393    ((party actor message)
 394      (display \"Life of the party!\")))"
 395     ((make-action-dispatch action-item ...)
 396      (simple-dispatcher (build-actions action-item ...)))))
 397
 398 (define-syntax-rule (define-simple-actor class actions ...)
 399   (define-class class (<actor>)
 400     (message-handler
 401      #:init-value (make-action-dispatch actions ...)
 402      #:allocation #:each-subclass)))
 403
 404 \f
 405 ;;; The Hive
 406 ;;; ========
 407 ;;;   Every actor has a hive.  The hive is a kind of "meta-actor"
 408 ;;;   which routes all the rest of the actors in a system.
 409
 410 (define-generic hive-handle-failed-forward)
 411
 412 (define-class <hive> (<actor>)
 413   (actor-registry #:init-thunk make-hash-table
 414                   #:getter hive-actor-registry)
 415   (msg-id-generator #:init-thunk simple-message-id-generator
 416                     #:getter hive-msg-id-generator)
 417   ;; Ambassadors are used (or will be) for inter-hive communication.
 418   ;; These are special actors that know how to route messages to other hives.
 419   (ambassadors #:init-thunk make-weak-key-hash-table
 420                #:getter hive-ambassadors)
 421   ;; Waiting coroutines
 422   ;; This is a map from cons cell of message-id
 423   ;;   to a cons cell of (actor-id . coroutine)
 424   ;; @@: Should we have a <waiting-coroutine> record type?
 425   ;; @@: Should there be any way to clear out "old" coroutines?
 426   (waiting-coroutines #:init-thunk make-hash-table
 427                       #:getter hive-waiting-coroutines)
 428   ;; Message prompt
 429   ;; When actors send messages to each other they abort to this prompt
 430   ;; to send the message, then carry on their way
 431   (prompt #:init-thunk make-prompt-tag
 432           #:getter hive-prompt)
 433   (message-handler
 434    #:init-value
 435    (make-action-dispatch
 436     ;; This is in the case of an ambassador failing to forward a message...
 437     ;; it reports it back to the hive
 438     (*failed-forward* hive-handle-failed-forward))))
 439
 440 (define-method (hive-handle-failed-forward (hive <hive>) message)
 441   "Handle an ambassador failing to forward a message"
 442   'TODO)
 443
 444 (define* (make-hive #:key hive-id)
 445   (let ((hive (make <hive>
 446                 #:id (make-address
 447                       "hive" (or hive-id
 448                                  (big-random-number-string))))))
 449     ;; Set the hive's actor reference to itself
 450     (set! (actor-hive hive) hive)
 451     hive))
 452
 453 (define-method (hive-id (hive <hive>))
 454   (actor-id-hive hive))
 455
 456 (define-method (hive-gen-actor-id (hive <hive>) cookie)
 457   (make-address (if cookie
 458                     (string-append cookie "-" (big-random-number-string))
 459                     (big-random-number-string))
 460                 (hive-id hive)))
 461
 462 (define-method (hive-gen-message-id (hive <hive>))
 463   "Generate a message id using HIVE's message id generator"
 464   ((hive-msg-id-generator hive)))
 465
 466 (define-method (hive-resolve-local-actor (hive <hive>) actor-address)
 467   (hash-ref (hive-actor-registry hive) actor-address))
 468
 469 (define-method (hive-resolve-ambassador (hive <hive>) ambassador-address)
 470   (hash-ref (hive-ambassadors hive) ambassador-address))
 471
 472 (define-method (make-forward-request (hive <hive>) (ambassador <actor>) message)
 473   (make-message (hive-gen-message-id hive) (actor-id ambassador)
 474                 ;; If we make the hive not an actor, we could either switch this
 475                 ;; to #f or to the original actor...?
 476                 ;; Maybe some more thinking should be done on what should
 477                 ;; happen in case of failure to forward?  Handling ambassador failures
 478                 ;; seems like the primary motivation for the hive remaining an actor.
 479                 (actor-id hive)
 480                 '*forward*
 481                 `((original . ,message))))
 482
 483 (define-method (hive-reply-with-error (hive <hive>) original-message
 484                                       error-key error-args)
 485   ;; We only supply the error-args if the original sender is on the same hive
 486   (define (orig-actor-on-same-hive?)
 487     (equal? (hive-id hive)
 488             (address-hive-id (message-from original-message))))
 489   (set-message-replied! original-message #t)
 490   (let* ((new-message-body
 491           (if (orig-actor-on-same-hive?)
 492               `((original-message . ,original-message)
 493                 (error-key . ,error-key)
 494                 (error-args . ,error-args))
 495               `((original-message . ,original-message)
 496                 (error-key . ,error-key))))
 497          (new-message (make-message (hive-gen-message-id hive)
 498                                     (message-from original-message)
 499                                     (actor-id hive) '*error*
 500                                     new-message-body
 501                                     #:in-reply-to (message-id original-message))))
 502     (8sync-nowait (hive-process-message hive new-message))))
 503
 504 (define-method (hive-process-message (hive <hive>) message)
 505   "Handle one message, or forward it via an ambassador"
 506   (define (maybe-autoreply actor)
 507     ;; Possibly autoreply
 508     (if (message-needs-reply message)
 509         ;; @@: Should we give *autoreply* as the action instead of *reply*?
 510         (reply-message actor message
 511                        #:*auto-reply* #t)))
 512
 513   (define (resolve-actor-to)
 514     "Get the actor the message was aimed at"
 515     (let ((actor (hive-resolve-local-actor hive (message-to message))))
 516       (if (not actor)
 517           (throw 'actor-not-found
 518                  (format #f "Message ~a from ~a directed to nonexistant actor ~a"
 519                          (message-id message)
 520                          (address->string (message-from message))
 521                          (address->string (message-to message)))
 522                  message))
 523       actor))
 524
 525   (define (call-catching-coroutine thunk)
 526     (define (call-catching-errors)
 527       (with-throw-handler
 528           #t thunk
 529           (lambda (key . args)
 530             (if (message-needs-reply message)
 531                 ;; If the message is waiting on a reply, let them know
 532                 ;; something went wrong.
 533                 (hive-reply-with-error hive message key args)))))
 534     (call-with-prompt (hive-prompt hive)
 535       call-catching-errors
 536       (lambda (kont actor message)
 537         ;; Register the coroutine
 538         (hash-set! (hive-waiting-coroutines hive)
 539                    (message-id message)
 540                    (cons (actor-id actor) kont))
 541         ;; Send off the message
 542         (8sync (hive-process-message hive message)))))
 543
 544   (define (process-local-message)
 545     (let ((actor (resolve-actor-to)))
 546       (call-catching-coroutine
 547        (lambda ()
 548          (define message-handler (actor-message-handler actor))
 549          ;; @@: Should a more general error handling happen here?
 550          (let ((result
 551                 (message-handler actor message)))
 552            (maybe-autoreply actor)
 553            ;; Returning result allows actors to possibly make a run-request
 554            ;; at the end of handling a message.
 555            ;; ... We do want that, right?
 556            result)))))
 557
 558   (define (resume-waiting-coroutine)
 559     (cond
 560      ((eq? (message-action message) '*reply*)
 561       (call-catching-coroutine
 562        (lambda ()
 563          (match (hash-remove! (hive-waiting-coroutines hive)
 564                               (message-in-reply-to message))
 565            ((_ . (resume-actor-id . kont))
 566             (if (not (equal? (message-to message)
 567                              resume-actor-id))
 568                 (throw 'resuming-to-wrong-actor
 569                        "Attempted to resume a coroutine to the wrong actor!"
 570                        #:expected-actor-id (message-to message)
 571                        #:got-actor-id resume-actor-id
 572                        #:message message))
 573             (let (;; @@: How should we resolve resuming coroutines to actors who are
 574                   ;;   now gone?
 575                   (actor (resolve-actor-to))
 576                   (result (kont message)))
 577               (maybe-autoreply actor)
 578               result))
 579            (#f (throw 'no-waiting-coroutine
 580                       "message in-reply-to tries to resume nonexistent coroutine"
 581                       message))))))
 582      ;; Yikes, we must have gotten an error or something back
 583      (else
 584       ;; @@: Not what we want in the long run?
 585       ;; What we'd *prefer* to do is to resume this message
 586       ;; and throw an error inside the message handler
 587       ;; (say, from send-mesage-wait), but that causes a SIGABRT (??!!)
 588       (hash-remove! (hive-waiting-coroutines hive)
 589                     (message-in-reply-to message))
 590       (let ((explaination
 591              (if (eq? (message-action message) '*reply*)
 592                  "Won't resume coroutine; got an *error* as a reply"
 593                  "Won't resume coroutine because action is not *reply*")))
 594         (throw 'hive-unresumable-coroutine
 595                explaination
 596                #:message message)))))
 597
 598   (define (process-remote-message)
 599     ;; Find the ambassador
 600     (let* ((remote-hive-id (hive-id (message-to message)))
 601            (ambassador (hive-resolve-ambassador remote-hive-id))
 602            (message-handler (actor-message-handler ambassador))
 603            (forward-request (make-forward-request hive ambassador message)))
 604       (message-handler ambassador forward-request)))
 605
 606   (let ((to (message-to message)))
 607     ;; This seems to be an easy mistake to make, so check that addressing
 608     ;; is correct here
 609     (if (not to)
 610         (throw 'missing-addressee
 611                "`to' field is missing on message"
 612                #:message message))
 613     (if (hive-actor-local? hive to)
 614         (if (message-in-reply-to message)
 615             (resume-waiting-coroutine)
 616             (process-local-message))
 617         (process-remote-message))))
 618
 619 (define-method (hive-actor-local? (hive <hive>) address)
 620   (hash-ref (hive-actor-registry hive) address))
 621
 622 (define-method (hive-register-actor! (hive <hive>) (actor <actor>))
 623   (hash-set! (hive-actor-registry hive) (actor-id actor) actor))
 624
 625 (define-method (%hive-create-actor (hive <hive>) actor-class
 626                                    init id-cookie)
 627   "Actual method called by hive-create-actor.
 628
 629 Since this is a define-method it can't accept fancy define* arguments,
 630 so this gets called from the nicer hive-create-actor interface.  See
 631 that method for documentation."
 632   (let* ((actor-id (hive-gen-actor-id hive id-cookie))
 633          (actor (apply make actor-class
 634                        #:hive hive
 635                        #:id actor-id
 636                        init)))
 637     (hive-register-actor! hive actor)
 638     ;; return the actor id
 639     actor-id))
 640
 641 (define* (hive-create-actor hive actor-class #:rest init)
 642   (%hive-create-actor hive actor-class
 643                       init #f))
 644
 645 (define* (hive-create-actor* hive actor-class id-cookie #:rest init)
 646   (%hive-create-actor hive actor-class
 647                       init id-cookie))
 648
 649
 650 \f
 651 ;;; Various API methods for actors to interact with the system
 652 ;;; ==========================================================
 653
 654 ;; TODO: move send-message and friends here...?
 655
 656 (define* (create-actor from-actor actor-class #:rest init)
 657   "Create an instance of actor-class.  Return the new actor's id.
 658
 659 This is the method actors should call directly (unless they want
 660 to supply an id-cookie, in which case they should use
 661 create-actor*)."
 662   (8sync (%hive-create-actor (actor-hive from-actor) actor-class
 663                              init #f)))
 664
 665
 666 (define* (create-actor* from-actor actor-class id-cookie #:rest init)
 667   "Create an instance of actor-class.  Return the new actor's id.
 668
 669 Like create-actor, but permits supplying an id-cookie."
 670   (8sync (%hive-create-actor (actor-hive from-actor) actor-class
 671                              init id-cookie)))
 672
 673
 674 (define (self-destruct actor)
 675   "Remove an actor from the hive."
 676   (hash-remove! (hive-actor-registry (actor-hive actor))
 677                 (actor-id actor)))
 678
 679
 680 \f
 681 ;;; 8sync bootstrap utilities
 682 ;;; =========================
 683
 684 (define* (ez-run-hive hive initial-tasks #:key repl-server)
 685   "Start up an agenda and run HIVE in it with INITIAL-TASKS.
 686
 687 Should we start up a cooperative REPL for live hacking?  REPL-SERVER
 688 wants to know!  You can pass it #t or #f, or if you want to specify a port,
 689 an integer."
 690   (let* ((queue (list->q initial-tasks))
 691          (agenda (make-agenda #:pre-unwind-handler print-error-and-continue
 692                               #:queue queue)))
 693     (cond
 694      ;; If repl-server is an integer, we'll use that as the port
 695      ((integer? repl-server)
 696       (spawn-and-queue-repl-server! agenda repl-server))
 697      (repl-server
 698       (spawn-and-queue-repl-server! agenda)))
 699     (start-agenda agenda)))
 700
 701 (define (bootstrap-message hive to-id action . message-body-args)
 702   (wrap
 703    (apply send-message hive to-id action message-body-args)))
 704
 705
 706 \f
 707 ;;; Basic readers / writers
 708 ;;; =======================
 709
 710 (define (serialize-message message)
 711   "Serialize a message for read/write"
 712   (list
 713    (message-id message)
 714    (message-to message)
 715    (message-from message)
 716    (message-action message)
 717    (message-body message)
 718    (message-in-reply-to message)
 719    (message-wants-reply message)
 720    (message-replied message)
 721    (message-deferred-reply message)))
 722
 723 (define* (write-message message #:optional (port (current-output-port)))
 724   "Write out a message to a port for easy reading later.
 725
 726 Note that if a sub-value can't be easily written to something
 727 Guile's `read' procedure knows how to read, this doesn't do anything
 728 to improve that.  You'll need a better serializer for that.."
 729   (write (serialize-message message) port))
 730
 731 (define (serialize-message-pretty message)
 732   "Serialize a message in a way that's easy for humans to read."
 733   `(*message*
 734     (id ,(message-id message))
 735     (to ,(message-to message))
 736     (from ,(message-from message))
 737     (action ,(message-action message))
 738     (body ,(message-body message))
 739     (in-reply-to ,(message-in-reply-to message))
 740     (wants-reply ,(message-wants-reply message))
 741     (replied ,(message-replied message))
 742     (deferred-reply ,(message-deferred-reply message))))
 743
 744 (define (pprint-message message)
 745   "Pretty print a message."
 746   (pretty-print (serialize-message-pretty message)))
 747
 748 (define* (read-message #:optional (port (current-input-port)))
 749   "Read a message serialized via serialize-message from PORT"
 750   (match (read port)
 751     ((id to from action body in-reply-to wants-reply replied deferred-reply)
 752      (make-message-intern
 753       id to from action body
 754       in-reply-to wants-reply replied deferred-reply))
 755     (anything-else
 756      (throw 'message-read-bad-structure
 757             "Could not read message from structure"
 758             anything-else))))
 759
 760 (define (read-message-from-string message-str)
 761   "Read message from MESSAGE-STR"
 762   (with-input-from-string message-str
 763     (lambda ()
 764       (read-message (current-input-port)))))