8sync/systems/actors.scm

   1 ;;; 8sync --- Asynchronous programming for Guile
   2 ;;; Copyright (C) 2016 Christopher Allan Webber <cwebber@dustycloud.org>
   3 ;;;
   4 ;;; This file is part of 8sync.
   5 ;;;
   6 ;;; 8sync is free software: you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU Lesser General Public License as
   8 ;;; published by the Free Software Foundation, either version 3 of the
   9 ;;; License, or (at your option) any later version.
  10 ;;;
  11 ;;; 8sync is distributed in the hope that it will be useful,
  12 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU Lesser General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU Lesser General Public
  17 ;;; License along with 8sync.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;; XUDD inspired actor system
  20
  21 (define-module (8sync systems actors)
  22   #:use-module (oop goops)
  23   #:use-module (srfi srfi-9)
  24   #:use-module (srfi srfi-9 gnu)
  25   #:use-module (ice-9 format)
  26   #:use-module (ice-9 match)
  27   #:use-module (ice-9 pretty-print)
  28   #:use-module (8sync agenda)
  29   #:use-module (8sync repl)
  30   #:export (;; utilities... ought to go in their own module
  31             big-random-number
  32             big-random-number-string
  33             simple-message-id-generator
  34
  35             <actor>
  36             actor-id
  37             actor-message-handler
  38
  39             ;;; Commenting out the <address> type for now;
  40             ;;; it may be back when we have better serializers
  41             ;; <address>
  42             make-address address?
  43             address-actor-id address-hive-id
  44
  45             address->string
  46             actor-id-actor
  47             actor-id-hive
  48             actor-id-string
  49
  50             mlambda
  51             make-action-dispatch
  52             define-simple-actor
  53
  54             <hive>
  55             make-hive
  56             ;; There are more methods for the hive, but there's
  57             ;; no reason for the outside world to look at them maybe?
  58             hive-id
  59             hive-create-actor hive-create-actor*
  60
  61             create-actor create-actor*
  62             self-destruct
  63
  64             <message>
  65             make-message message?
  66             message-to message-action message-from
  67             message-id message-body message-in-reply-to
  68             message-wants-reply
  69             message-ref
  70
  71             send-message send-message-wait
  72             reply-message reply-message-wait
  73
  74             <- <-wait <-reply <-reply-wait
  75
  76             ez-run-hive
  77             bootstrap-message
  78
  79             serialize-message write-message
  80             serialize-message-pretty pprint-message
  81             read-message read-message-from-string))
  82
  83 ;; For ids
  84 (define %random-state
  85   (make-parameter (random-state-from-platform)))
  86
  87 ;; Same size as a uuid4 I think...
  88 (define random-number-size (expt 2 128))
  89
  90 (define (big-random-number)
  91   (random random-number-size (%random-state)))
  92
  93 ;; Would be great to get this base64 encoded instead.
  94 (define (big-random-number-string)
  95   ;; @@: This is slow.  Using format here is wasteful.
  96   (format #f "~x" (big-random-number)))
  97
  98 ;; @@: This is slow.  A mere ~275k / second on my (old) machine.
  99 ;;   The main cost seems to be in number->string.
 100 (define (simple-message-id-generator)
 101   ;; Prepending this cookie makes message ids unique per hive
 102   (let ((prefix (format #f "~x:" (big-random-number)))
 103         (counter 0))
 104     (lambda ()
 105       (set! counter (1+ counter))
 106       (string-append prefix (number->string counter)))))
 107
 108
 109 \f
 110 ;;; Messages
 111 ;;; ========
 112
 113
 114 (define-record-type <message>
 115   (make-message-intern id to from action
 116                        body in-reply-to wants-reply
 117                        replied
 118                        ;; @@: Not used yet.
 119                        ;; Will we ever find a real use case?
 120                        deferred-reply)
 121   message?
 122   (id message-id)
 123   (to message-to)
 124   (from message-from)
 125   (action message-action)
 126   (body message-body)
 127   (in-reply-to message-in-reply-to)
 128   (wants-reply message-wants-reply)
 129
 130   ;; See XUDD source for these.  Not use yet, maybe eventually will be?
 131   ;; XUDD uses them for autoreply.
 132   ;; Requiring mutation on message objects is clearly not great,
 133   ;; but it may be worth it...?  Investigate!
 134   (replied message-replied set-message-replied!)
 135   (deferred-reply message-deferred-reply set-message-deferred-reply!))
 136
 137
 138 (define* (make-message id to from action body
 139                        #:key in-reply-to wants-reply
 140                        replied deferred-reply)
 141   (make-message-intern id to from action body
 142                        in-reply-to wants-reply replied
 143                        deferred-reply))
 144
 145 ;; Note: the body of messages is currently an alist, but it's created
 146 ;;   from a keyword based property list (see the following two functions).
 147 ;;   But, that's an extra conversion step, and maybe totally unnecessary:
 148 ;;   we already have message-ref, and this could just pull a keyword
 149 ;;   from a property list.
 150 ;;   The main ways this might be useful are error checking,
 151 ;;   serialization across the wire (but even that might require some
 152 ;;   change), and using existing tooling (though adding new tooling
 153 ;;   would be negligible in implementation effort.)
 154
 155 ;; This cons cell is immutable and unique (for eq? tests)
 156 (define %nothing-provided (cons 'nothing 'provided))
 157
 158 (define* (message-ref message key #:optional (dflt %nothing-provided))
 159   "Extract KEY from body of MESSAGE.
 160
 161 Optionally set default with [DFLT]
 162 If key not found and DFLT not provided, throw an error."
 163   (let ((result (assoc key (message-body message))))
 164     (if result (cdr result)
 165         (if (eq? dflt %nothing-provided)
 166             (throw 'message-missing-key
 167                    "Message body does not contain key and no default provided"
 168                    #:key key
 169                    #:message message)
 170             dflt))))
 171
 172
 173 (define (message-needs-reply message)
 174   "See if this message needs a reply still"
 175   (and (message-wants-reply message)
 176        (not (or (message-replied message)
 177                 (message-deferred-reply message)))))
 178
 179
 180 (define (kwarg-list-to-alist args)
 181   (let loop ((remaining args)
 182              (result '()))
 183     (match remaining
 184       (((? keyword? key) val rest ...)
 185        (loop rest
 186              (cons (cons (keyword->symbol key) val)
 187                    result)))
 188       (() result)
 189       (_ (throw 'invalid-kwarg-list
 190                 "Invalid keyword argument list"
 191                 args)))))
 192
 193
 194 (define (send-message from-actor to-id action . message-body-args)
 195   "Send a message from an actor to another actor"
 196   (let* ((hive (actor-hive from-actor))
 197          (message (make-message (hive-gen-message-id hive) to-id
 198                                 (actor-id from-actor) action
 199                                 (kwarg-list-to-alist message-body-args))))
 200     (8sync-nowait (hive-process-message hive message))))
 201
 202 (define (send-message-wait from-actor to-id action . message-body-args)
 203   "Send a message from an actor to another, but wait until we get a response"
 204   (let* ((hive (actor-hive from-actor))
 205          (abort-to (hive-prompt (actor-hive from-actor)))
 206          (message (make-message (hive-gen-message-id hive) to-id
 207                                 (actor-id from-actor) action
 208                                 (kwarg-list-to-alist message-body-args)
 209                                 #:wants-reply #t)))
 210     (abort-to-prompt abort-to from-actor message)))
 211
 212 ;; TODO: Intelligently ~propagate(ish) errors on -wait functions.
 213 ;;   We might have `send-message-wait-brazen' to allow callers to
 214 ;;   not have an exception thrown and instead just have a message with
 215 ;;   the appropriate '*error* message returned.
 216
 217 (define (reply-message from-actor original-message
 218                        . message-body-args)
 219   "Reply to a message"
 220   (set-message-replied! original-message #t)
 221   (let* ((hive (actor-hive from-actor))
 222          (new-message (make-message (hive-gen-message-id hive)
 223                                     (message-from original-message)
 224                                     (actor-id from-actor) '*reply*
 225                                     (kwarg-list-to-alist message-body-args)
 226                                     #:in-reply-to (message-id original-message))))
 227     (8sync-nowait (hive-process-message hive new-message))))
 228
 229 (define (reply-message-wait from-actor original-message
 230                             . message-body-args)
 231   "Reply to a messsage, but wait until we get a response"
 232   (set-message-replied! original-message #t)
 233   (let* ((hive (actor-hive from-actor))
 234          (abort-to (hive-prompt (actor-hive from-actor)))
 235          (new-message (make-message (hive-gen-message-id hive)
 236                                     (message-from original-message)
 237                                     (actor-id from-actor) '*reply*
 238                                     (kwarg-list-to-alist message-body-args)
 239                                     #:wants-reply #t
 240                                     #:in-reply-to (message-id original-message))))
 241     (abort-to-prompt abort-to from-actor new-message)))
 242
 243
 244 ;;; Aliases!
 245 ;;; See: http://mumble.net/~jar/articles/oo-moon-weinreb.html
 246 ;;;   (also worth seeing: http://mumble.net/~jar/articles/oo.html )
 247
 248 (define <- send-message)
 249 (define <-wait send-message-wait)
 250 (define <-reply reply-message)
 251 (define <-reply-wait reply-message-wait)
 252
 253
 254 \f
 255 ;;; Main actor implementation
 256 ;;; =========================
 257
 258 (define-class <actor> ()
 259   ;; An address object
 260   (id #:init-keyword #:id
 261       #:getter actor-id)
 262   ;; The hive we're connected to.
 263   ;; We need this to be able to send messages.
 264   (hive #:init-keyword #:hive
 265         #:accessor actor-hive)
 266   ;; How we receive and process new messages
 267   (message-handler #:allocation #:each-subclass))
 268
 269 (define-method (actor-message-handler (actor <actor>))
 270   (slot-ref actor 'message-handler))
 271
 272 ;;; So these are the nicer representations of addresses.
 273 ;;; However, they don't serialize so easily with scheme read/write, so we're
 274 ;;; using the simpler cons cell version below for now.
 275
 276 ;; (define-record-type <address>
 277 ;;   (make-address actor-id hive-id)  ; @@: Do we want the trailing -id?
 278 ;;   address?
 279 ;;   (actor-id address-actor-id)
 280 ;;   (hive-id address-hive-id))
 281 ;;
 282 ;; (set-record-type-printer!
 283 ;;  <address>
 284 ;;  (lambda (record port)
 285 ;;    (format port "<address: ~s@~s>"
 286 ;;            (address-actor-id record) (address-hive-id record))))
 287 ;;
 288
 289 (define (make-address actor-id hive-id)
 290   (cons actor-id hive-id))
 291
 292 (define (address-actor-id address)
 293   (car address))
 294
 295 (define (address-hive-id address)
 296   (cdr address))
 297
 298 (define (address->string address)
 299   (string-append (address-actor-id address) "@"
 300                  (address-hive-id address)))
 301
 302 (define-method (actor-id-actor (actor <actor>))
 303   "Get the actor id component of the actor-id"
 304   (address-actor-id (actor-id actor)))
 305
 306 (define-method (actor-id-hive (actor <actor>))
 307   "Get the hive id component of the actor-id"
 308   (address-hive-id (actor-id actor)))
 309
 310 (define-method (actor-id-string (actor <actor>))
 311   "Render the full actor id as a human-readable string"
 312   (address->string (actor-id actor)))
 313
 314
 315 \f
 316 ;;; Actor utilities
 317 ;;; ===============
 318
 319 (define-syntax mlambda
 320   (syntax-rules ()
 321     "A lambda for building message handlers.
 322
 323 Use it like:
 324   (mlambda (actor message foo)
 325     ...)
 326
 327 Which is like doing manually:
 328   (lambda (actor message)
 329     (let ((foo (message-ref message foo)))
 330       ...))"
 331     ((_ (actor message message-arg ...)
 332         body body* ...)
 333      (lambda (actor message)
 334        (let ((message-arg (message-ref message (quote message-arg))) ...)
 335          body body* ...)))))
 336
 337 (define (simple-dispatcher action-map)
 338   (lambda (actor message)
 339     (let* ((action (message-action message))
 340            (method (assoc-ref action-map action)))
 341       (if (not method)
 342           (throw 'action-not-found
 343                  "No appropriate action handler found for actor"
 344                  #:action action
 345                  #:actor actor
 346                  #:message message
 347                  #:available-actions (map car action-map)))
 348       (method actor message))))
 349
 350 (define-syntax %expand-action-item
 351   (syntax-rules ()
 352     ((_ ((action-name action-args ...) body ...))
 353      (cons (quote action-name)
 354            (mlambda (action-args ...)
 355              body ...)))
 356     ((_ (action-name handler))
 357      (cons (quote action-name) handler))))
 358
 359 (define-syntax make-action-dispatch
 360   (syntax-rules ()
 361     "Expand a list of action names and actions into an alist
 362
 363 You can use this like the following:
 364   (make-action-dispatch
 365    (cookies
 366     (lambda (actor message)
 367       (display \"I love cookies!\n\")))
 368    (party
 369     (lambda (actor message)
 370       (display \"Life of the party!\"))))
 371
 372 Alternately, if you'd like to skip the lambda, you could use the slightly
 373 more compact following syntax:
 374   (make-action-dispatch
 375    ((cookies actor message)
 376      (display \"I love cookies!\n\"))
 377    ((party actor message)
 378      (display \"Life of the party!\")))"
 379     ((make-action-dispatch action-item ...)
 380      (simple-dispatcher
 381       (list (%expand-action-item action-item) ...)))))
 382
 383 (define-syntax-rule (define-simple-actor class actions ...)
 384   (define-class class (<actor>)
 385     (message-handler
 386      #:init-value (make-action-dispatch actions ...)
 387      #:allocation #:each-subclass)))
 388
 389 \f
 390 ;;; The Hive
 391 ;;; ========
 392 ;;;   Every actor has a hive.  The hive is a kind of "meta-actor"
 393 ;;;   which routes all the rest of the actors in a system.
 394
 395 (define-generic hive-handle-failed-forward)
 396
 397 (define-class <hive> (<actor>)
 398   (actor-registry #:init-thunk make-hash-table
 399                   #:getter hive-actor-registry)
 400   (msg-id-generator #:init-thunk simple-message-id-generator
 401                     #:getter hive-msg-id-generator)
 402   ;; Ambassadors are used (or will be) for inter-hive communication.
 403   ;; These are special actors that know how to route messages to other hives.
 404   (ambassadors #:init-thunk make-weak-key-hash-table
 405                #:getter hive-ambassadors)
 406   ;; Waiting coroutines
 407   ;; This is a map from cons cell of message-id
 408   ;;   to a cons cell of (actor-id . coroutine)
 409   ;; @@: Should we have a <waiting-coroutine> record type?
 410   ;; @@: Should there be any way to clear out "old" coroutines?
 411   (waiting-coroutines #:init-thunk make-hash-table
 412                       #:getter hive-waiting-coroutines)
 413   ;; Message prompt
 414   ;; When actors send messages to each other they abort to this prompt
 415   ;; to send the message, then carry on their way
 416   (prompt #:init-thunk make-prompt-tag
 417           #:getter hive-prompt)
 418   (message-handler
 419    #:init-value
 420    (make-action-dispatch
 421     ;; This is in the case of an ambassador failing to forward a message...
 422     ;; it reports it back to the hive
 423     (*failed-forward* hive-handle-failed-forward))))
 424
 425 (define-method (hive-handle-failed-forward (hive <hive>) message)
 426   "Handle an ambassador failing to forward a message"
 427   'TODO)
 428
 429 (define* (make-hive #:key hive-id)
 430   (let ((hive (make <hive>
 431                 #:id (make-address
 432                       "hive" (or hive-id
 433                                  (big-random-number-string))))))
 434     ;; Set the hive's actor reference to itself
 435     (set! (actor-hive hive) hive)
 436     hive))
 437
 438 (define-method (hive-id (hive <hive>))
 439   (actor-id-hive hive))
 440
 441 (define-method (hive-gen-actor-id (hive <hive>) cookie)
 442   (make-address (if cookie
 443                     (string-append cookie "-" (big-random-number-string))
 444                     (big-random-number-string))
 445                 (hive-id hive)))
 446
 447 (define-method (hive-gen-message-id (hive <hive>))
 448   "Generate a message id using HIVE's message id generator"
 449   ((hive-msg-id-generator hive)))
 450
 451 (define-method (hive-resolve-local-actor (hive <hive>) actor-address)
 452   (hash-ref (hive-actor-registry hive) actor-address))
 453
 454 (define-method (hive-resolve-ambassador (hive <hive>) ambassador-address)
 455   (hash-ref (hive-ambassadors hive) ambassador-address))
 456
 457 (define-method (make-forward-request (hive <hive>) (ambassador <actor>) message)
 458   (make-message (hive-gen-message-id hive) (actor-id ambassador)
 459                 ;; If we make the hive not an actor, we could either switch this
 460                 ;; to #f or to the original actor...?
 461                 ;; Maybe some more thinking should be done on what should
 462                 ;; happen in case of failure to forward?  Handling ambassador failures
 463                 ;; seems like the primary motivation for the hive remaining an actor.
 464                 (actor-id hive)
 465                 '*forward*
 466                 `((original . ,message))))
 467
 468 (define-method (hive-reply-with-error (hive <hive>) original-message
 469                                       error-key error-args)
 470   ;; We only supply the error-args if the original sender is on the same hive
 471   (define (orig-actor-on-same-hive?)
 472     (equal? (hive-id hive)
 473             (address-hive-id (message-from original-message))))
 474   (set-message-replied! original-message #t)
 475   (let* ((new-message-body
 476           (if (orig-actor-on-same-hive?)
 477               `((original-message . ,original-message)
 478                 (error-key . ,error-key)
 479                 (error-args . ,error-args))
 480               `((original-message . ,original-message)
 481                 (error-key . ,error-key))))
 482          (new-message (make-message (hive-gen-message-id hive)
 483                                     (message-from original-message)
 484                                     (actor-id hive) '*error*
 485                                     new-message-body
 486                                     #:in-reply-to (message-id original-message))))
 487     (8sync-nowait (hive-process-message hive new-message))))
 488
 489 (define-method (hive-process-message (hive <hive>) message)
 490   "Handle one message, or forward it via an ambassador"
 491   (define (maybe-autoreply actor)
 492     ;; Possibly autoreply
 493     (if (message-needs-reply message)
 494         ;; @@: Should we give *autoreply* as the action instead of *reply*?
 495         (reply-message actor message
 496                        #:*auto-reply* #t)))
 497
 498   (define (resolve-actor-to)
 499     "Get the actor the message was aimed at"
 500     (let ((actor (hive-resolve-local-actor hive (message-to message))))
 501       (if (not actor)
 502           (throw 'actor-not-found
 503                  (format #f "Message ~a from ~a directed to nonexistant actor ~a"
 504                          (message-id message)
 505                          (address->string (message-from message))
 506                          (address->string (message-to message)))
 507                  message))
 508       actor))
 509
 510   (define (call-catching-coroutine thunk)
 511     (define (call-catching-errors)
 512       (with-throw-handler
 513           #t thunk
 514           (lambda (key . args)
 515             (if (message-needs-reply message)
 516                 ;; If the message is waiting on a reply, let them know
 517                 ;; something went wrong.
 518                 (hive-reply-with-error hive message key args)))))
 519     (call-with-prompt (hive-prompt hive)
 520       call-catching-errors
 521       (lambda (kont actor message)
 522         ;; Register the coroutine
 523         (hash-set! (hive-waiting-coroutines hive)
 524                    (message-id message)
 525                    (cons (actor-id actor) kont))
 526         ;; Send off the message
 527         (8sync (hive-process-message hive message)))))
 528
 529   (define (process-local-message)
 530     (let ((actor (resolve-actor-to)))
 531       (call-catching-coroutine
 532        (lambda ()
 533          (define message-handler (actor-message-handler actor))
 534          ;; @@: Should a more general error handling happen here?
 535          (let ((result
 536                 (message-handler actor message)))
 537            (maybe-autoreply actor)
 538            ;; Returning result allows actors to possibly make a run-request
 539            ;; at the end of handling a message.
 540            ;; ... We do want that, right?
 541            result)))))
 542
 543   (define (resume-waiting-coroutine)
 544     (cond
 545      ((eq? (message-action message) '*reply*)
 546       (call-catching-coroutine
 547        (lambda ()
 548          (match (hash-remove! (hive-waiting-coroutines hive)
 549                               (message-in-reply-to message))
 550            ((_ . (resume-actor-id . kont))
 551             (if (not (equal? (message-to message)
 552                              resume-actor-id))
 553                 (throw 'resuming-to-wrong-actor
 554                        "Attempted to resume a coroutine to the wrong actor!"
 555                        #:expected-actor-id (message-to message)
 556                        #:got-actor-id resume-actor-id
 557                        #:message message))
 558             (let (;; @@: How should we resolve resuming coroutines to actors who are
 559                   ;;   now gone?
 560                   (actor (resolve-actor-to))
 561                   (result (kont message)))
 562               (maybe-autoreply actor)
 563               result))
 564            (#f (throw 'no-waiting-coroutine
 565                       "message in-reply-to tries to resume nonexistent coroutine"
 566                       message))))))
 567      ;; Yikes, we must have gotten an error or something back
 568      (else
 569       ;; @@: Not what we want in the long run?
 570       ;; What we'd *prefer* to do is to resume this message
 571       ;; and throw an error inside the message handler
 572       ;; (say, from send-mesage-wait), but that causes a SIGABRT (??!!)
 573       (hash-remove! (hive-waiting-coroutines hive)
 574                     (message-in-reply-to message))
 575       (let ((explaination
 576              (if (eq? (message-action message) '*reply*)
 577                  "Won't resume coroutine; got an *error* as a reply"
 578                  "Won't resume coroutine because action is not *reply*")))
 579         (throw 'hive-unresumable-coroutine
 580                explaination
 581                #:message message)))))
 582
 583   (define (process-remote-message)
 584     ;; Find the ambassador
 585     (let* ((remote-hive-id (hive-id (message-to message)))
 586            (ambassador (hive-resolve-ambassador remote-hive-id))
 587            (message-handler (actor-message-handler ambassador))
 588            (forward-request (make-forward-request hive ambassador message)))
 589       (message-handler ambassador forward-request)))
 590
 591   (let ((to (message-to message)))
 592     ;; This seems to be an easy mistake to make, so check that addressing
 593     ;; is correct here
 594     (if (not to)
 595         (throw 'missing-addressee
 596                "`to' field is missing on message"
 597                #:message message))
 598     (if (hive-actor-local? hive to)
 599         (if (message-in-reply-to message)
 600             (resume-waiting-coroutine)
 601             (process-local-message))
 602         (process-remote-message))))
 603
 604 (define-method (hive-actor-local? (hive <hive>) address)
 605   (hash-ref (hive-actor-registry hive) address))
 606
 607 (define-method (hive-register-actor! (hive <hive>) (actor <actor>))
 608   (hash-set! (hive-actor-registry hive) (actor-id actor) actor))
 609
 610 (define-method (%hive-create-actor (hive <hive>) actor-class
 611                                    init id-cookie)
 612   "Actual method called by hive-create-actor.
 613
 614 Since this is a define-method it can't accept fancy define* arguments,
 615 so this gets called from the nicer hive-create-actor interface.  See
 616 that method for documentation."
 617   (let* ((actor-id (hive-gen-actor-id hive id-cookie))
 618          (actor (apply make actor-class
 619                        #:hive hive
 620                        #:id actor-id
 621                        init)))
 622     (hive-register-actor! hive actor)
 623     ;; return the actor id
 624     actor-id))
 625
 626 (define* (hive-create-actor hive actor-class #:rest init)
 627   (%hive-create-actor hive actor-class
 628                       init #f))
 629
 630 (define* (hive-create-actor* hive actor-class id-cookie #:rest init)
 631   (%hive-create-actor hive actor-class
 632                       init id-cookie))
 633
 634
 635 \f
 636 ;;; Various API methods for actors to interact with the system
 637 ;;; ==========================================================
 638
 639 ;; TODO: move send-message and friends here...?
 640
 641 (define* (create-actor from-actor actor-class #:rest init)
 642   "Create an instance of actor-class.  Return the new actor's id.
 643
 644 This is the method actors should call directly (unless they want
 645 to supply an id-cookie, in which case they should use
 646 create-actor*)."
 647   (8sync (%hive-create-actor (actor-hive from-actor) actor-class
 648                              init #f)))
 649
 650
 651 (define* (create-actor* from-actor actor-class id-cookie #:rest init)
 652   "Create an instance of actor-class.  Return the new actor's id.
 653
 654 Like create-actor, but permits supplying an id-cookie."
 655   (8sync (%hive-create-actor (actor-hive from-actor) actor-class
 656                              init id-cookie)))
 657
 658
 659 (define (self-destruct actor)
 660   "Remove an actor from the hive."
 661   (hash-remove! (hive-actor-registry (actor-hive actor))
 662                 (actor-id actor)))
 663
 664
 665 \f
 666 ;;; 8sync bootstrap utilities
 667 ;;; =========================
 668
 669 (define* (ez-run-hive hive initial-tasks #:key repl-server)
 670   "Start up an agenda and run HIVE in it with INITIAL-TASKS.
 671
 672 Should we start up a cooperative REPL for live hacking?  REPL-SERVER
 673 wants to know!  You can pass it #t or #f, or if you want to specify a port,
 674 an integer."
 675   (let* ((queue (list->q initial-tasks))
 676          (agenda (make-agenda #:pre-unwind-handler print-error-and-continue
 677                               #:queue queue)))
 678     (cond
 679      ;; If repl-server is an integer, we'll use that as the port
 680      ((integer? repl-server)
 681       (spawn-and-queue-repl-server! agenda repl-server))
 682      (repl-server
 683       (spawn-and-queue-repl-server! agenda)))
 684     (start-agenda agenda)))
 685
 686 (define (bootstrap-message hive to-id action . message-body-args)
 687   (wrap
 688    (apply send-message hive to-id action message-body-args)))
 689
 690
 691 \f
 692 ;;; Basic readers / writers
 693 ;;; =======================
 694
 695 (define (serialize-message message)
 696   "Serialize a message for read/write"
 697   (list
 698    (message-id message)
 699    (message-to message)
 700    (message-from message)
 701    (message-action message)
 702    (message-body message)
 703    (message-in-reply-to message)
 704    (message-wants-reply message)
 705    (message-replied message)
 706    (message-deferred-reply message)))
 707
 708 (define* (write-message message #:optional (port (current-output-port)))
 709   "Write out a message to a port for easy reading later.
 710
 711 Note that if a sub-value can't be easily written to something
 712 Guile's `read' procedure knows how to read, this doesn't do anything
 713 to improve that.  You'll need a better serializer for that.."
 714   (write (serialize-message message) port))
 715
 716 (define (serialize-message-pretty message)
 717   "Serialize a message in a way that's easy for humans to read."
 718   `(*message*
 719     (id ,(message-id message))
 720     (to ,(message-to message))
 721     (from ,(message-from message))
 722     (action ,(message-action message))
 723     (body ,(message-body message))
 724     (in-reply-to ,(message-in-reply-to message))
 725     (wants-reply ,(message-wants-reply message))
 726     (replied ,(message-replied message))
 727     (deferred-reply ,(message-deferred-reply message))))
 728
 729 (define (pprint-message message)
 730   "Pretty print a message."
 731   (pretty-print (serialize-message-pretty message)))
 732
 733 (define* (read-message #:optional (port (current-input-port)))
 734   "Read a message serialized via serialize-message from PORT"
 735   (match (read port)
 736     ((id to from action body in-reply-to wants-reply replied deferred-reply)
 737      (make-message-intern
 738       id to from action body
 739       in-reply-to wants-reply replied deferred-reply))
 740     (anything-else
 741      (throw 'message-read-bad-structure
 742             "Could not read message from structure"
 743             anything-else))))
 744
 745 (define (read-message-from-string message-str)
 746   "Read message from MESSAGE-STR"
 747   (with-input-from-string message-str
 748     (lambda ()
 749       (read-message (current-input-port)))))