8sync/actors.scm

   1 ;;; 8sync --- Asynchronous programming for Guile
   2 ;;; Copyright (C) 2016 Christopher Allan Webber <cwebber@dustycloud.org>
   3 ;;;
   4 ;;; This file is part of 8sync.
   5 ;;;
   6 ;;; 8sync is free software: you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU Lesser General Public License as
   8 ;;; published by the Free Software Foundation, either version 3 of the
   9 ;;; License, or (at your option) any later version.
  10 ;;;
  11 ;;; 8sync is distributed in the hope that it will be useful,
  12 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU Lesser General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU Lesser General Public
  17 ;;; License along with 8sync.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (8sync actors)
  20   #:use-module (oop goops)
  21   #:use-module (srfi srfi-9)
  22   #:use-module (srfi srfi-9 gnu)
  23   #:use-module (ice-9 control)
  24   #:use-module (ice-9 format)
  25   #:use-module (ice-9 match)
  26   #:use-module (ice-9 pretty-print)
  27   #:use-module (8sync agenda)
  28   #:export (;; utilities... ought to go in their own module
  29             big-random-number
  30             big-random-number-string
  31             simple-message-id-generator
  32
  33             <actor>
  34             actor-id
  35             actor-message-handler
  36
  37             %current-actor
  38
  39             ;;; Commenting out the <address> type for now;
  40             ;;; it may be back when we have better serializers
  41             ;; <address>
  42             make-address address?
  43             address-actor-id address-hive-id
  44
  45             address->string
  46             actor-id-actor
  47             actor-id-hive
  48             actor-id-string
  49
  50             actor-alive?
  51
  52             build-actions
  53
  54             define-actor
  55
  56             <hive>
  57             make-hive
  58             ;; There are more methods for the hive, but there's
  59             ;; no reason for the outside world to look at them maybe?
  60             hive-id
  61             bootstrap-actor bootstrap-actor*
  62
  63             create-actor create-actor*
  64             self-destruct
  65
  66             <message>
  67             make-message message?
  68             message-to message-action message-from
  69             message-id message-body message-in-reply-to
  70             message-wants-reply
  71
  72             message-auto-reply?
  73
  74             <- <-* <-wait <-wait* <-reply <-reply* <-reply-wait <-reply-wait*
  75
  76             call-with-message mbody-receive mbody-val
  77
  78             run-hive
  79             bootstrap-message
  80
  81             serialize-message write-message
  82             serialize-message-pretty pprint-message
  83             read-message read-message-from-string))
  84
  85 ;; For ids
  86 (define %random-state
  87   (make-parameter (random-state-from-platform)))
  88
  89 ;; Same size as a uuid4 I think...
  90 (define random-number-size (expt 2 128))
  91
  92 (define (big-random-number)
  93   (random random-number-size (%random-state)))
  94
  95 ;; Would be great to get this base64 encoded instead.
  96 (define (big-random-number-string)
  97   ;; @@: This is slow.  Using format here is wasteful.
  98   (format #f "~x" (big-random-number)))
  99
 100 ;; @@: This is slow.  A mere ~275k / second on my (old) machine.
 101 ;;   The main cost seems to be in number->string.
 102 (define (simple-message-id-generator)
 103   ;; Prepending this cookie makes message ids unique per hive
 104   (let ((prefix (format #f "~x:" (big-random-number)))
 105         (counter 0))
 106     (lambda ()
 107       (set! counter (1+ counter))
 108       (string-append prefix (number->string counter)))))
 109
 110
 111 \f
 112 ;;; Messages
 113 ;;; ========
 114
 115
 116 ;; @@: We may want to add a deferred-reply to the below, similar to
 117 ;;   what we had in XUDD, for actors which do their own response
 118 ;;   queueing.... ie, that might receive messages but need to shelve
 119 ;;   them to be acted upon after something else is taken care of.
 120
 121 (define-record-type <message>
 122   (make-message-intern id to from action
 123                        body in-reply-to wants-reply
 124                        replied)
 125   message?
 126   (id message-id)                    ; id of this message
 127   (to message-to)                    ; actor id this is going to
 128   (from message-from)                ; actor id of sender
 129   (action message-action)            ; action (a symbol) to be handled
 130   (body message-body)                ; argument list "body" of message
 131   (in-reply-to message-in-reply-to)  ; message id this is in reply to, if any
 132   (wants-reply message-wants-reply)  ; whether caller is waiting for reply
 133   (replied message-replied           ; was this message replied to?
 134            set-message-replied!))
 135
 136
 137 (define* (make-message id to from action body
 138                        #:key in-reply-to wants-reply
 139                        replied)
 140   (make-message-intern id to from action body
 141                        in-reply-to wants-reply replied))
 142
 143 (define (message-auto-reply? message)
 144   (eq? (message-action message) '*auto-reply*))
 145
 146 (define (message-needs-reply? message)
 147   "See if this message needs a reply still"
 148   (and (message-wants-reply message)
 149        (not (message-replied message))))
 150
 151
 152 (define (kwarg-list-to-alist args)
 153   (let loop ((remaining args)
 154              (result '()))
 155     (match remaining
 156       (((? keyword? key) val rest ...)
 157        (loop rest
 158              (cons (cons (keyword->symbol key) val)
 159                    result)))
 160       (() result)
 161       (_ (throw 'invalid-kwarg-list
 162                 "Invalid keyword argument list"
 163                 args)))))
 164
 165
 166 ;;; See: https://web.archive.org/web/20081223021934/http://mumble.net/~jar/articles/oo-moon-weinreb.html
 167 ;;;   (also worth seeing: http://mumble.net/~jar/articles/oo.html )
 168
 169 ;; This is the internal, generalized message sending method.
 170 ;; Users shouldn't use it!  Use the <-foo forms instead.
 171
 172 ;; @@: Could we get rid of some of the conditional checks through
 173 ;;   some macro-foo?
 174
 175 (define-inlinable (send-message send-options from-actor to-id action
 176                                 replying-to-message wants-reply?
 177                                 message-body-args)
 178   (if replying-to-message
 179       (set-message-replied! replying-to-message #t))
 180   (let* ((hive (actor-hive from-actor))
 181          (new-message
 182           (make-message (hive-gen-message-id hive) to-id
 183                         (actor-id from-actor) action
 184                         message-body-args
 185                         #:wants-reply wants-reply?
 186                         #:in-reply-to
 187                         (if replying-to-message
 188                             (message-id replying-to-message)
 189                             #f))))
 190     (if wants-reply?
 191         (abort-to-prompt (hive-prompt (actor-hive from-actor))
 192                          from-actor new-message send-options)
 193         ;; @@: It might be that eventually we pass in send-options
 194         ;;   here too.  Since <-wait and <-reply-wait are the only ones
 195         ;;   that use it yet, for now it kind of just makes things
 196         ;;   confusing.
 197         (8sync (hive-process-message hive new-message)))))
 198
 199 (define (<- to-id action . message-body-args)
 200   "Send a message from an actor to another actor"
 201   (send-message '() (%current-actor) to-id action
 202                 #f #f message-body-args))
 203
 204 (define (<-* send-options to-id action . message-body-args)
 205   "Like <-*, but allows extra parameters via send-options"
 206   (define* (really-send #:key (actor (%current-actor))
 207                         #:allow-other-keys)
 208     (send-message send-options actor to-id action
 209                   #f #f message-body-args))
 210   (apply really-send send-options))
 211
 212 (define (<-wait to-id action . message-body-args)
 213   "Send a message from an actor to another, but wait until we get a response"
 214   (wait-maybe-handle-errors
 215    (send-message '() (%current-actor) to-id action
 216                  #f #t message-body-args)))
 217
 218 (define (<-wait* send-options to-id action . message-body-args)
 219   "Like <-wait, but allows extra parameters, for example whether to
 220 #:accept-errors"
 221   (define* (really-send #:key (actor (%current-actor))
 222                         #:allow-other-keys)
 223     (apply wait-maybe-handle-errors
 224            (send-message send-options actor to-id action
 225                          #f #t message-body-args)
 226            send-options))
 227   (apply really-send send-options))
 228
 229 ;; TODO: Intelligently ~propagate(ish) errors on -wait functions.
 230 ;;   We might have `send-message-wait-brazen' to allow callers to
 231 ;;   not have an exception thrown and instead just have a message with
 232 ;;   the appropriate '*error* message returned.
 233
 234 (define (<-reply original-message . message-body-args)
 235   "Reply to a message"
 236   (send-message '() (%current-actor) (message-from original-message) '*reply*
 237                 original-message #f message-body-args))
 238
 239 (define (<-reply* send-options original-message . message-body-args)
 240   "Like <-reply, but allows extra parameters via send-options"
 241   (define* (really-send #:key (actor (%current-actor))
 242                         #:allow-other-keys)
 243     (send-message send-options actor
 244                   (message-from original-message) '*reply*
 245                   original-message #f message-body-args))
 246   (apply really-send send-options))
 247
 248 (define (<-auto-reply actor original-message)
 249   "Auto-reply to a message.  Internal use only!"
 250   (send-message '() actor (message-from original-message) '*auto-reply*
 251                 original-message #f '()))
 252
 253 (define (<-reply-wait original-message . message-body-args)
 254   "Reply to a messsage, but wait until we get a response"
 255   (wait-maybe-handle-errors
 256    (send-message '() (%current-actor)
 257                  (message-from original-message) '*reply*
 258                  original-message #t message-body-args)))
 259
 260 (define (<-reply-wait* send-options original-message
 261                        . message-body-args)
 262   "Like <-reply-wait, but allows extra parameters via send-options"
 263   (define* (really-send #:key (actor (%current-actor))
 264                         #:allow-other-keys)
 265     (apply wait-maybe-handle-errors
 266            (send-message send-options actor
 267                          (message-from original-message) '*reply*
 268                          original-message #t message-body-args)
 269            send-options))
 270   (apply really-send send-options))
 271
 272 (define* (wait-maybe-handle-errors message
 273                                    #:key accept-errors
 274                                    #:allow-other-keys)
 275   "Before returning a message to a waiting caller, see if we need to
 276 raise an exception if an error."
 277   (define action (message-action message))
 278   (cond ((and (eq? action '*error*)
 279               (not accept-errors))
 280          (throw 'hive-unresumable-coroutine
 281                 "Won't resume coroutine; got an *error* as a reply"
 282                 #:message message))
 283         (else message)))
 284
 285
 286 \f
 287 ;;; Main actor implementation
 288 ;;; =========================
 289
 290 (define (actor-inheritable-message-handler actor message)
 291   (define action (message-action message))
 292   (define (find-message-handler return)
 293     (for-each (lambda (this-class)
 294                 (define actions
 295                   (or (and (class-slot-definition this-class 'actions)
 296                            (class-slot-ref this-class 'actions))
 297                       '()))
 298                 (for-each (match-lambda
 299                             ((action-name . method)
 300                              (when (eq? action-name action)
 301                                (return method))))
 302                           actions))
 303               (class-precedence-list (class-of actor)))
 304     (throw 'action-not-found
 305            "No appropriate action handler found for actor"
 306            #:action action
 307            #:actor actor
 308            #:message message))
 309   (define method
 310     (call/ec find-message-handler))
 311   (apply method actor message (message-body message)))
 312
 313 (define-syntax-rule (build-actions (symbol method) ...)
 314   "Construct an alist of (symbol . method), where the method is wrapped
 315 with wrap-apply to facilitate live hacking and allow the method definition
 316 to come after class definition."
 317   (list
 318    (cons (quote symbol)
 319          (wrap-apply method)) ...))
 320
 321 (define-class <actor> ()
 322   ;; An address object
 323   (id #:init-keyword #:id
 324       #:getter actor-id)
 325   ;; The hive we're connected to.
 326   ;; We need this to be able to send messages.
 327   (hive #:init-keyword #:hive
 328         #:accessor actor-hive)
 329   ;; How we receive and process new messages
 330   (message-handler #:init-value actor-inheritable-message-handler
 331                    ;; @@: There's no reason not to use #:class instead of
 332                    ;;   #:each-subclass anywhere in this file, except for
 333                    ;;   Guile bug #25211 (#:class is broken in Guile 2.2)
 334                    #:allocation #:each-subclass
 335                    #:getter actor-message-handler)
 336
 337   ;; This is the default, "simple" way to inherit and process messages.
 338   (actions #:init-value (build-actions
 339                          ;; Default init method is to do nothing.
 340                          (*init* (const #f))
 341                          ;; Default cleanup method is to do nothing.
 342                          (*cleanup* (const #f)))
 343            #:allocation #:each-subclass))
 344
 345 ;;; Addresses are vectors where the first part is the actor-id and
 346 ;;; the second part is the hive-id.  This works well enough... they
 347 ;;; look decent being pretty-printed.
 348
 349 (define (make-address actor-id hive-id)
 350   (vector actor-id hive-id))
 351
 352 (define (address-actor-id address)
 353   (vector-ref address 0))
 354
 355 (define (address-hive-id address)
 356   (vector-ref address 1))
 357
 358 (define (address->string address)
 359   (string-append (address-actor-id address) "@"
 360                  (address-hive-id address)))
 361
 362 (define-method (actor-id-actor (actor <actor>))
 363   "Get the actor id component of the actor-id"
 364   (address-actor-id (actor-id actor)))
 365
 366 (define-method (actor-id-hive (actor <actor>))
 367   "Get the hive id component of the actor-id"
 368   (address-hive-id (actor-id actor)))
 369
 370 (define-method (actor-id-string (actor <actor>))
 371   "Render the full actor id as a human-readable string"
 372   (address->string (actor-id actor)))
 373
 374 (define %current-actor
 375   (make-parameter #f))
 376
 377 (define (actor-alive? actor)
 378   (hive-resolve-local-actor (actor-hive actor) (actor-id actor)))
 379
 380
 381 \f
 382 ;;; Actor utilities
 383 ;;; ===============
 384
 385 (define-syntax-rule (define-actor class inherits
 386                       (action ...)
 387                       slots ...)
 388   (define-class class inherits
 389     (actions #:init-value (build-actions action ...)
 390              #:allocation #:each-subclass)
 391     slots ...))
 392
 393 \f
 394 ;;; The Hive
 395 ;;; ========
 396 ;;;   Every actor has a hive.  The hive is a kind of "meta-actor"
 397 ;;;   which routes all the rest of the actors in a system.
 398
 399 (define-generic hive-handle-failed-forward)
 400
 401 (define-class <hive> (<actor>)
 402   (actor-registry #:init-thunk make-hash-table
 403                   #:getter hive-actor-registry)
 404   (msg-id-generator #:init-thunk simple-message-id-generator
 405                     #:getter hive-msg-id-generator)
 406   ;; Ambassadors are used (or will be) for inter-hive communication.
 407   ;; These are special actors that know how to route messages to other hives.
 408   (ambassadors #:init-thunk make-weak-key-hash-table
 409                #:getter hive-ambassadors)
 410   ;; Waiting coroutines
 411   ;; This is a map from cons cell of message-id
 412   ;;   to a cons cell of (actor-id . coroutine)
 413   ;; @@: Should we have a <waiting-coroutine> record type?
 414   ;; @@: Should there be any way to clear out "old" coroutines?
 415   (waiting-coroutines #:init-thunk make-hash-table
 416                       #:getter hive-waiting-coroutines)
 417   ;; Message prompt
 418   ;; When actors send messages to each other they abort to this prompt
 419   ;; to send the message, then carry on their way
 420   (prompt #:init-thunk make-prompt-tag
 421           #:getter hive-prompt)
 422   (actions #:allocation #:each-subclass
 423            #:init-value
 424            (build-actions
 425             ;; This is in the case of an ambassador failing to forward a
 426             ;; message... it reports it back to the hive
 427             (*failed-forward* hive-handle-failed-forward)
 428             ;; These are called at start and end of run-hive
 429             (*init-all* hive-handle-init-all)
 430             (*cleanup-all* hive-handle-cleanup-all))))
 431
 432 (define-method (hive-handle-init-all (hive <hive>) message)
 433   "Run *init* method on all actors in registry"
 434   ;; We have to do this hack and run over the list
 435   ;; twice, because hash-for-each would result in an unrewindable
 436   ;; continuation, and to avoid the hash-map changing during the
 437   ;; middle of this.
 438   (define actor-ids
 439     (hash-map->list (lambda (actor-id actor) actor-id)
 440                     (hive-actor-registry hive)))
 441   (for-each (lambda (actor-id)
 442               ;; @@: This could maybe just be <-, but we want actors
 443               ;;   to be used to the expectation in all circumstances
 444               ;;   that their init method is "waited on".
 445               (<-wait actor-id '*init*))
 446             actor-ids))
 447
 448 (define-method (hive-handle-failed-forward (hive <hive>) message)
 449   "Handle an ambassador failing to forward a message"
 450   'TODO)
 451
 452 (define-method (hive-handle-cleanup-all (hive <hive>) message)
 453   "Send a message to all actors in our registry to clean themselves up."
 454   ;; We have to do this hack and run over the list
 455   ;; twice, because hash-for-each would result in an unrewindable
 456   ;; continuation, and to avoid the hash-map changing during the
 457   ;; middle of this.
 458   (define actor-ids
 459     (hash-map->list (lambda (actor-id actor) actor-id)
 460                     (hive-actor-registry hive)))
 461   (for-each (lambda (actor-id)
 462               (<- actor-id '*cleanup*))
 463             actor-ids))
 464
 465 (define* (make-hive #:key hive-id)
 466   (let ((hive (make <hive>
 467                 #:id (make-address
 468                       "hive" (or hive-id
 469                                  (big-random-number-string))))))
 470     ;; Set the hive's actor reference to itself
 471     (set! (actor-hive hive) hive)
 472     ;; Register the actor with itself
 473     (hive-register-actor! hive hive)
 474     hive))
 475
 476 (define-method (hive-id (hive <hive>))
 477   (actor-id-hive hive))
 478
 479 (define-method (hive-gen-actor-id (hive <hive>) cookie)
 480   (make-address (if cookie
 481                     (string-append cookie ":" (big-random-number-string))
 482                     (big-random-number-string))
 483                 (hive-id hive)))
 484
 485 (define-method (hive-gen-message-id (hive <hive>))
 486   "Generate a message id using HIVE's message id generator"
 487   ((hive-msg-id-generator hive)))
 488
 489 (define-method (hive-resolve-local-actor (hive <hive>) actor-address)
 490   (hash-ref (hive-actor-registry hive) actor-address))
 491
 492 (define-method (hive-resolve-ambassador (hive <hive>) ambassador-address)
 493   (hash-ref (hive-ambassadors hive) ambassador-address))
 494
 495 (define-method (make-forward-request (hive <hive>) (ambassador <actor>) message)
 496   (make-message (hive-gen-message-id hive) (actor-id ambassador)
 497                 ;; If we make the hive not an actor, we could either switch this
 498                 ;; to #f or to the original actor...?
 499                 ;; Maybe some more thinking should be done on what should
 500                 ;; happen in case of failure to forward?  Handling ambassador failures
 501                 ;; seems like the primary motivation for the hive remaining an actor.
 502                 (actor-id hive)
 503                 '*forward*
 504                 `((original . ,message))))
 505
 506 (define-method (hive-reply-with-error (hive <hive>) original-message
 507                                       error-key error-args)
 508   ;; We only supply the error-args if the original sender is on the same hive
 509   (define (orig-actor-on-same-hive?)
 510     (equal? (hive-id hive)
 511             (address-hive-id (message-from original-message))))
 512   (set-message-replied! original-message #t)
 513   (let* ((new-message-body
 514           (if (orig-actor-on-same-hive?)
 515               `(#:original-message ,original-message
 516                 #:error-key ,error-key
 517                 #:error-args ,error-args)
 518               `(#:original-message ,original-message
 519                 #:error-key ,error-key)))
 520          (new-message (make-message (hive-gen-message-id hive)
 521                                     (message-from original-message)
 522                                     (actor-id hive) '*error*
 523                                     new-message-body
 524                                     #:in-reply-to (message-id original-message))))
 525     ;; We only return a thunk, rather than run 8sync here, because if
 526     ;; we ran 8sync in the middle of a catch we'd end up with an
 527     ;; unresumable continuation.
 528     (lambda () (hive-process-message hive new-message))))
 529
 530 (define-record-type <waiting-on-reply>
 531   (make-waiting-on-reply actor-id kont send-options)
 532   waiting-on-reply?
 533   (actor-id waiting-on-reply-actor-id)
 534   (kont waiting-on-reply-kont)
 535   (send-options waiting-on-reply-send-options))
 536
 537
 538 (define-method (hive-process-message (hive <hive>) message)
 539   "Handle one message, or forward it via an ambassador"
 540   (define (maybe-autoreply actor)
 541     ;; Possibly autoreply
 542     (if (message-needs-reply? message)
 543         (<-auto-reply actor message)))
 544
 545   (define (resolve-actor-to)
 546     "Get the actor the message was aimed at"
 547     (let ((actor (hive-resolve-local-actor hive (message-to message))))
 548       (if (not actor)
 549           (throw 'actor-not-found
 550                  (format #f "Message ~a from ~a directed to nonexistant actor ~a"
 551                          (message-id message)
 552                          (address->string (message-from message))
 553                          (address->string (message-to message)))
 554                  message))
 555       actor))
 556
 557   (define (call-catching-coroutine thunk)
 558     (define queued-error-handling-thunk #f)
 559     (define (call-catching-errors)
 560       ;; TODO: maybe parameterize (or attach to hive) and use
 561       ;;   maybe-catch-all from agenda.scm
 562       ;; @@: Why not just use with-throw-handler and let the catch
 563       ;;   happen at the agenda?  That's what we used to do, but
 564       ;;   it ended up with a SIGABRT.  See:
 565       ;;     http://lists.gnu.org/archive/html/bug-guile/2016-05/msg00003.html
 566       (catch #t
 567         thunk
 568         ;; In the actor model, we don't totally crash on errors.
 569         (lambda _ #f)
 570         ;; If an error happens, we raise it
 571         (lambda (key . args)
 572           (if (message-needs-reply? message)
 573               ;; If the message is waiting on a reply, let them know
 574               ;; something went wrong.
 575               ;; However, we have to do it outside of this catch
 576               ;; routine, or we'll end up in an unrewindable continuation
 577               ;; situation.
 578               (set! queued-error-handling-thunk
 579                     (hive-reply-with-error hive message key args)))
 580           ;; print error message
 581           (apply print-error-and-continue key args)))
 582       ;; @@: This is a kludge.  See above for why.
 583       (if queued-error-handling-thunk
 584           (8sync (queued-error-handling-thunk))))
 585     (call-with-prompt (hive-prompt hive)
 586       call-catching-errors
 587       (lambda (kont actor message send-options)
 588         ;; Register the coroutine
 589         (hash-set! (hive-waiting-coroutines hive)
 590                    (message-id message)
 591                    (make-waiting-on-reply
 592                     (actor-id actor) kont send-options))
 593         ;; Send off the message
 594         (8sync (hive-process-message hive message)))))
 595
 596   (define (process-local-message)
 597     (let ((actor (resolve-actor-to)))
 598       (call-catching-coroutine
 599        (lambda ()
 600          (define message-handler (actor-message-handler actor))
 601          ;; @@: Should a more general error handling happen here?
 602          (parameterize ((%current-actor actor))
 603            (let ((result
 604                   (message-handler actor message)))
 605              (maybe-autoreply actor)
 606              ;; Returning result allows actors to possibly make a run-request
 607              ;; at the end of handling a message.
 608              ;; ... We do want that, right?
 609              result))))))
 610
 611   (define (resume-waiting-coroutine)
 612     (case (message-action message)
 613       ;; standard reply / auto-reply
 614       ((*reply* *auto-reply* *error*)
 615        (call-catching-coroutine
 616         (lambda ()
 617           (match (hash-remove! (hive-waiting-coroutines hive)
 618                                (message-in-reply-to message))
 619             ((_ . waiting)
 620              (if (not (equal? (message-to message)
 621                               (waiting-on-reply-actor-id waiting)))
 622                  (throw 'resuming-to-wrong-actor
 623                         "Attempted to resume a coroutine to the wrong actor!"
 624                         #:expected-actor-id (message-to message)
 625                         #:got-actor-id (waiting-on-reply-actor-id waiting)
 626                         #:message message))
 627              (let* (;; @@: How should we resolve resuming coroutines to actors who are
 628                     ;;   now gone?
 629                     (actor (resolve-actor-to))
 630                     (kont (waiting-on-reply-kont waiting))
 631                     (result (kont message)))
 632                (maybe-autoreply actor)
 633                result))
 634             (#f (throw 'no-waiting-coroutine
 635                        "message in-reply-to tries to resume nonexistent coroutine"
 636                        message))))))
 637       ;; Unhandled action for a reply!
 638       (else
 639        (throw 'hive-unresumable-coroutine
 640               "Won't resume coroutine, nonsense action on reply message"
 641               #:action (message-action message)
 642               #:message message))))
 643
 644   (define (process-remote-message)
 645     ;; Find the ambassador
 646     (let* ((remote-hive-id (hive-id (message-to message)))
 647            (ambassador (hive-resolve-ambassador remote-hive-id))
 648            (message-handler (actor-message-handler ambassador))
 649            (forward-request (make-forward-request hive ambassador message)))
 650       (message-handler ambassador forward-request)))
 651
 652   (let ((to (message-to message)))
 653     ;; This seems to be an easy mistake to make, so check that addressing
 654     ;; is correct here
 655     (if (not to)
 656         (throw 'missing-addressee
 657                "`to' field is missing on message"
 658                #:message message))
 659     (if (hive-actor-local? hive to)
 660         (if (message-in-reply-to message)
 661             (resume-waiting-coroutine)
 662             (process-local-message))
 663         (process-remote-message))))
 664
 665 (define-method (hive-actor-local? (hive <hive>) address)
 666   (equal? (hive-id hive) (address-hive-id address)))
 667
 668 (define-method (hive-register-actor! (hive <hive>) (actor <actor>))
 669   (hash-set! (hive-actor-registry hive) (actor-id actor) actor))
 670
 671 (define-method (%hive-create-actor (hive <hive>) actor-class
 672                                    init-args id-cookie send-init?)
 673   "Actual method called by bootstrap-actor / create-actor.
 674
 675 Since this is a define-method it can't accept fancy define* arguments,
 676 so this gets called from the nicer bootstrap-actor interface.  See
 677 that method for documentation."
 678   (let* ((actor-id (hive-gen-actor-id hive id-cookie))
 679          (actor (apply make actor-class
 680                        #:hive hive
 681                        #:id actor-id
 682                        init-args)))
 683     (hive-register-actor! hive actor)
 684     ;; Wait on actor to init
 685     (when send-init?
 686       (<-wait actor-id '*init*))
 687     ;; return the actor id
 688     actor-id))
 689
 690 (define* (bootstrap-actor hive actor-class #:rest init-args)
 691   "Create an actor on HIVE using ACTOR-CLASS passing in INIT-ARGS args"
 692   (%hive-create-actor hive actor-class
 693                     init-args (symbol->string (class-name actor-class))
 694                     #f))
 695
 696 (define* (bootstrap-actor* hive actor-class id-cookie #:rest init-args)
 697   "Create an actor, but also allow customizing a 'cookie' added to the id
 698 for debugging"
 699   (%hive-create-actor hive actor-class
 700                     init-args id-cookie
 701                     #f))
 702
 703 (define (call-with-message message proc)
 704   "Applies message body arguments into procedure, with message as first
 705 argument.  Similar to call-with-values in concept."
 706   (apply proc message (message-body message)))
 707
 708 ;; (mbody-receive (<- bar baz)
 709 ;;     (baz)
 710 ;;   basil)
 711
 712 ;; Emacs: (put 'mbody-receive 'scheme-indent-function 2)
 713
 714 ;; @@: Or receive-msg or receieve-message or??
 715 (define-syntax-rule (mbody-receive arglist message body ...)
 716   "Call body with arglist (which can accept arguments like lambda*)
 717 applied from the message-body of message."
 718   (call-with-message message
 719                      (lambda* arglist
 720                        body ...)))
 721
 722 (define (mbody-val message)
 723   "Retrieve the first value from the message-body of message.
 724 Like single value return from a procedure call.  Probably the most
 725 common case when waiting on a reply from some action invocation."
 726   (call-with-message message
 727                      (lambda (_ val) val)))
 728
 729 \f
 730 ;;; Various API methods for actors to interact with the system
 731 ;;; ==========================================================
 732
 733 ;; TODO: move send-message and friends here...?
 734
 735 (define* (create-actor from-actor actor-class #:rest init-args)
 736   "Create an instance of actor-class.  Return the new actor's id.
 737
 738 This is the method actors should call directly (unless they want
 739 to supply an id-cookie, in which case they should use
 740 create-actor*)."
 741   (%hive-create-actor (actor-hive from-actor) actor-class
 742                       init-args #f #t))
 743
 744
 745 (define* (create-actor* from-actor actor-class id-cookie #:rest init-args)
 746   "Create an instance of actor-class.  Return the new actor's id.
 747
 748 Like create-actor, but permits supplying an id-cookie."
 749   (%hive-create-actor (actor-hive from-actor) actor-class
 750                       init-args id-cookie #t))
 751
 752
 753 (define* (self-destruct actor #:key (cleanup #t))
 754   "Remove an actor from the hive.
 755
 756 Unless #:cleanup is set to #f, this will first have the actor handle
 757 its '*cleanup* action handler."
 758   (when cleanup
 759     (<-wait (actor-id actor) '*cleanup*))
 760   (hash-remove! (hive-actor-registry (actor-hive actor))
 761                 (actor-id actor)))
 762
 763
 764 \f
 765 ;;; 8sync bootstrap utilities
 766 ;;; =========================
 767
 768 (define* (run-hive hive initial-tasks
 769                    #:key (cleanup #t)
 770                    (handle-signals (list SIGINT SIGTERM)))
 771   "Start up an agenda and run HIVE in it with INITIAL-TASKS.
 772
 773 Keyword arguments:
 774  - #:cleanup: Whether to run *cleanup* on all actors.
 775  - #:handle-sigactions: a list of signals to set up interrupt
 776    handlers for, so cleanup sill still happen as expected.
 777    Defaults to a list of SIGINT and SIGTERM."
 778   (dynamic-wind
 779     (const #f)
 780     (lambda ()
 781       (define (run-it escape)
 782         (define (handle-signal signum)
 783           (restore-signals)
 784           (escape signum))
 785         (for-each (lambda (signum)
 786                     (sigaction signum handle-signal))
 787                   handle-signals)
 788         (let* ((queue (list->q
 789                        (cons (bootstrap-message hive (actor-id hive) '*init-all*)
 790                              initial-tasks)))
 791                (agenda (make-agenda #:pre-unwind-handler print-error-and-continue
 792                                     #:queue queue)))
 793           (run-agenda agenda)))
 794       (call/ec run-it))
 795     ;; Run cleanup
 796     (lambda ()
 797       (when cleanup
 798         (run-hive-cleanup hive)))))
 799
 800 (define (run-hive-cleanup hive)
 801   (let ((queue (list->q (list (bootstrap-message hive (actor-id hive)
 802                                                  '*cleanup-all*)))))
 803     (run-agenda
 804      (make-agenda #:queue queue))))
 805
 806 (define (bootstrap-message hive to-id action . message-body-args)
 807   (wrap
 808    (apply <-* `(#:actor ,hive) to-id action message-body-args)))
 809
 810
 811 \f
 812 ;;; Basic readers / writers
 813 ;;; =======================
 814
 815 (define (serialize-message message)
 816   "Serialize a message for read/write"
 817   (list
 818    (message-id message)
 819    (message-to message)
 820    (message-from message)
 821    (message-action message)
 822    (message-body message)
 823    (message-in-reply-to message)
 824    (message-wants-reply message)
 825    (message-replied message)))
 826
 827 (define* (write-message message #:optional (port (current-output-port)))
 828   "Write out a message to a port for easy reading later.
 829
 830 Note that if a sub-value can't be easily written to something
 831 Guile's `read' procedure knows how to read, this doesn't do anything
 832 to improve that.  You'll need a better serializer for that.."
 833   (write (serialize-message message) port))
 834
 835 (define (serialize-message-pretty message)
 836   "Serialize a message in a way that's easy for humans to read."
 837   `(*message*
 838     (id ,(message-id message))
 839     (to ,(message-to message))
 840     (from ,(message-from message))
 841     (action ,(message-action message))
 842     (body ,(message-body message))
 843     (in-reply-to ,(message-in-reply-to message))
 844     (wants-reply ,(message-wants-reply message))
 845     (replied ,(message-replied message))))
 846
 847 (define (pprint-message message)
 848   "Pretty print a message."
 849   (pretty-print (serialize-message-pretty message)))
 850
 851 (define* (read-message #:optional (port (current-input-port)))
 852   "Read a message serialized via serialize-message from PORT"
 853   (match (read port)
 854     ((id to from action body in-reply-to wants-reply replied)
 855      (make-message-intern
 856       id to from action body
 857       in-reply-to wants-reply replied))
 858     (anything-else
 859      (throw 'message-read-bad-structure
 860             "Could not read message from structure"
 861             anything-else))))
 862
 863 (define (read-message-from-string message-str)
 864   "Read message from MESSAGE-STR"
 865   (with-input-from-string message-str
 866     (lambda ()
 867       (read-message (current-input-port)))))