8sync/actors.scm

   1 ;;; 8sync --- Asynchronous programming for Guile
   2 ;;; Copyright (C) 2016 Christopher Allan Webber <cwebber@dustycloud.org>
   3 ;;;
   4 ;;; This file is part of 8sync.
   5 ;;;
   6 ;;; 8sync is free software: you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU Lesser General Public License as
   8 ;;; published by the Free Software Foundation, either version 3 of the
   9 ;;; License, or (at your option) any later version.
  10 ;;;
  11 ;;; 8sync is distributed in the hope that it will be useful,
  12 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU Lesser General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU Lesser General Public
  17 ;;; License along with 8sync.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (8sync actors)
  20   #:use-module (oop goops)
  21   #:use-module (srfi srfi-9)
  22   #:use-module (srfi srfi-9 gnu)
  23   #:use-module (ice-9 control)
  24   #:use-module (ice-9 format)
  25   #:use-module (ice-9 match)
  26   #:use-module (ice-9 pretty-print)
  27   #:use-module (8sync agenda)
  28   #:export (;; utilities... ought to go in their own module
  29             big-random-number
  30             big-random-number-string
  31             simple-message-id-generator
  32
  33             <actor>
  34             actor-id
  35             actor-message-handler
  36
  37             %current-actor
  38
  39             ;;; Commenting out the <address> type for now;
  40             ;;; it may be back when we have better serializers
  41             ;; <address>
  42             make-address address?
  43             address-actor-id address-hive-id
  44
  45             address->string
  46             actor-id-actor
  47             actor-id-hive
  48             actor-id-string
  49
  50             actor-alive?
  51
  52             build-actions
  53
  54             define-simple-actor
  55
  56             <hive>
  57             make-hive
  58             ;; There are more methods for the hive, but there's
  59             ;; no reason for the outside world to look at them maybe?
  60             hive-id
  61             hive-create-actor hive-create-actor*
  62
  63             create-actor create-actor*
  64             self-destruct
  65
  66             <message>
  67             make-message message?
  68             message-to message-action message-from
  69             message-id message-body message-in-reply-to
  70             message-wants-reply
  71
  72             message-auto-reply?
  73
  74             <- <-* <-wait <-wait* <-reply <-reply* <-reply-wait <-reply-wait*
  75
  76             call-with-message msg-receive msg-val
  77
  78             run-hive
  79             bootstrap-message
  80
  81             serialize-message write-message
  82             serialize-message-pretty pprint-message
  83             read-message read-message-from-string))
  84
  85 ;; For ids
  86 (define %random-state
  87   (make-parameter (random-state-from-platform)))
  88
  89 ;; Same size as a uuid4 I think...
  90 (define random-number-size (expt 2 128))
  91
  92 (define (big-random-number)
  93   (random random-number-size (%random-state)))
  94
  95 ;; Would be great to get this base64 encoded instead.
  96 (define (big-random-number-string)
  97   ;; @@: This is slow.  Using format here is wasteful.
  98   (format #f "~x" (big-random-number)))
  99
 100 ;; @@: This is slow.  A mere ~275k / second on my (old) machine.
 101 ;;   The main cost seems to be in number->string.
 102 (define (simple-message-id-generator)
 103   ;; Prepending this cookie makes message ids unique per hive
 104   (let ((prefix (format #f "~x:" (big-random-number)))
 105         (counter 0))
 106     (lambda ()
 107       (set! counter (1+ counter))
 108       (string-append prefix (number->string counter)))))
 109
 110
 111 \f
 112 ;;; Messages
 113 ;;; ========
 114
 115
 116 ;; @@: We may want to add a deferred-reply to the below, similar to
 117 ;;   what we had in XUDD, for actors which do their own response
 118 ;;   queueing.... ie, that might receive messages but need to shelve
 119 ;;   them to be acted upon after something else is taken care of.
 120
 121 (define-record-type <message>
 122   (make-message-intern id to from action
 123                        body in-reply-to wants-reply
 124                        replied)
 125   message?
 126   (id message-id)                    ; id of this message
 127   (to message-to)                    ; actor id this is going to
 128   (from message-from)                ; actor id of sender
 129   (action message-action)            ; action (a symbol) to be handled
 130   (body message-body)                ; argument list "body" of message
 131   (in-reply-to message-in-reply-to)  ; message id this is in reply to, if any
 132   (wants-reply message-wants-reply)  ; whether caller is waiting for reply
 133   (replied message-replied           ; was this message replied to?
 134            set-message-replied!))
 135
 136
 137 (define* (make-message id to from action body
 138                        #:key in-reply-to wants-reply
 139                        replied)
 140   (make-message-intern id to from action body
 141                        in-reply-to wants-reply replied))
 142
 143 (define (message-auto-reply? message)
 144   (eq? (message-action message) '*auto-reply*))
 145
 146 (define (message-needs-reply? message)
 147   "See if this message needs a reply still"
 148   (and (message-wants-reply message)
 149        (not (message-replied message))))
 150
 151
 152 (define (kwarg-list-to-alist args)
 153   (let loop ((remaining args)
 154              (result '()))
 155     (match remaining
 156       (((? keyword? key) val rest ...)
 157        (loop rest
 158              (cons (cons (keyword->symbol key) val)
 159                    result)))
 160       (() result)
 161       (_ (throw 'invalid-kwarg-list
 162                 "Invalid keyword argument list"
 163                 args)))))
 164
 165
 166 ;;; See: https://web.archive.org/web/20081223021934/http://mumble.net/~jar/articles/oo-moon-weinreb.html
 167 ;;;   (also worth seeing: http://mumble.net/~jar/articles/oo.html )
 168
 169 ;; This is the internal, generalized message sending method.
 170 ;; Users shouldn't use it!  Use the <-foo forms instead.
 171
 172 ;; @@: Could we get rid of some of the conditional checks through
 173 ;;   some macro-foo?
 174
 175 (define-inlinable (send-message send-options from-actor to-id action
 176                                 replying-to-message wants-reply?
 177                                 message-body-args)
 178   (if replying-to-message
 179       (set-message-replied! replying-to-message #t))
 180   (let* ((hive (actor-hive from-actor))
 181          (new-message
 182           (make-message (hive-gen-message-id hive) to-id
 183                         (actor-id from-actor) action
 184                         message-body-args
 185                         #:wants-reply wants-reply?
 186                         #:in-reply-to
 187                         (if replying-to-message
 188                             (message-id replying-to-message)
 189                             #f))))
 190     (if wants-reply?
 191         (abort-to-prompt (hive-prompt (actor-hive from-actor))
 192                          from-actor new-message send-options)
 193         ;; @@: It might be that eventually we pass in send-options
 194         ;;   here too.  Since <-wait and <-reply-wait are the only ones
 195         ;;   that use it yet, for now it kind of just makes things
 196         ;;   confusing.
 197         (8sync (hive-process-message hive new-message)))))
 198
 199 (define (<- to-id action . message-body-args)
 200   "Send a message from an actor to another actor"
 201   (send-message '() (%current-actor) to-id action
 202                 #f #f message-body-args))
 203
 204 (define (<-* send-options to-id action . message-body-args)
 205   "Like <-*, but allows extra parameters via send-options"
 206   (define* (really-send #:key (actor (%current-actor))
 207                         #:allow-other-keys)
 208     (send-message send-options actor to-id action
 209                   #f #f message-body-args))
 210   (apply really-send send-options))
 211
 212 (define (<-wait to-id action . message-body-args)
 213   "Send a message from an actor to another, but wait until we get a response"
 214   (wait-maybe-handle-errors
 215    (send-message '() (%current-actor) to-id action
 216                  #f #t message-body-args)))
 217
 218 (define (<-wait* send-options to-id action . message-body-args)
 219   "Like <-wait, but allows extra parameters, for example whether to
 220 #:accept-errors"
 221   (define* (really-send #:key (actor (%current-actor))
 222                         #:allow-other-keys)
 223     (apply wait-maybe-handle-errors
 224            (send-message send-options actor to-id action
 225                          #f #t message-body-args)
 226            send-options))
 227   (apply really-send send-options))
 228
 229 ;; TODO: Intelligently ~propagate(ish) errors on -wait functions.
 230 ;;   We might have `send-message-wait-brazen' to allow callers to
 231 ;;   not have an exception thrown and instead just have a message with
 232 ;;   the appropriate '*error* message returned.
 233
 234 (define (<-reply original-message . message-body-args)
 235   "Reply to a message"
 236   (send-message '() (%current-actor) (message-from original-message) '*reply*
 237                 original-message #f message-body-args))
 238
 239 (define (<-reply* send-options original-message . message-body-args)
 240   "Like <-reply, but allows extra parameters via send-options"
 241   (define* (really-send #:key (actor (%current-actor))
 242                         #:allow-other-keys)
 243     (send-message send-options actor
 244                   (message-from original-message) '*reply*
 245                   original-message #f message-body-args))
 246   (apply really-send send-options))
 247
 248 (define (<-auto-reply actor original-message)
 249   "Auto-reply to a message.  Internal use only!"
 250   (send-message '() actor (message-from original-message) '*auto-reply*
 251                 original-message #f '()))
 252
 253 (define (<-reply-wait original-message . message-body-args)
 254   "Reply to a messsage, but wait until we get a response"
 255   (wait-maybe-handle-errors
 256    (send-message '() (%current-actor)
 257                  (message-from original-message) '*reply*
 258                  original-message #t message-body-args)))
 259
 260 (define (<-reply-wait* send-options original-message
 261                        . message-body-args)
 262   "Like <-reply-wait, but allows extra parameters via send-options"
 263   (define* (really-send #:key (actor (%current-actor))
 264                         #:allow-other-keys)
 265     (apply wait-maybe-handle-errors
 266            (send-message send-options actor
 267                          (message-from original-message) '*reply*
 268                          original-message #t message-body-args)
 269            send-options))
 270   (apply really-send send-options))
 271
 272 (define* (wait-maybe-handle-errors message
 273                                    #:key accept-errors
 274                                    #:allow-other-keys)
 275   "Before returning a message to a waiting caller, see if we need to
 276 raise an exception if an error."
 277   (define action (message-action message))
 278   (cond ((and (eq? action '*error*)
 279               (not accept-errors))
 280          (throw 'hive-unresumable-coroutine
 281                 "Won't resume coroutine; got an *error* as a reply"
 282                 #:message message))
 283         (else message)))
 284
 285
 286 \f
 287 ;;; Main actor implementation
 288 ;;; =========================
 289
 290 (define (actor-inheritable-message-handler actor message)
 291   (define action (message-action message))
 292   (define (find-message-handler return)
 293     (for-each (lambda (this-class)
 294                 (define actions
 295                   (or (and (class-slot-definition this-class 'actions)
 296                            (class-slot-ref this-class 'actions))
 297                       '()))
 298                 (for-each (match-lambda
 299                             ((action-name . method)
 300                              (when (eq? action-name action)
 301                                (return method))))
 302                           actions))
 303               (class-precedence-list (class-of actor)))
 304     (throw 'action-not-found
 305            "No appropriate action handler found for actor"
 306            #:action action
 307            #:actor actor
 308            #:message message))
 309   (define method
 310     (call/ec find-message-handler))
 311   (apply method actor message (message-body message)))
 312
 313 (define-syntax-rule (build-actions (symbol method) ...)
 314   "Construct an alist of (symbol . method), where the method is wrapped
 315 with wrap-apply to facilitate live hacking and allow the method definition
 316 to come after class definition."
 317   (list
 318    (cons (quote symbol)
 319          (wrap-apply method)) ...))
 320
 321 (define-class <actor> ()
 322   ;; An address object
 323   (id #:init-keyword #:id
 324       #:getter actor-id)
 325   ;; The hive we're connected to.
 326   ;; We need this to be able to send messages.
 327   (hive #:init-keyword #:hive
 328         #:accessor actor-hive)
 329   ;; How we receive and process new messages
 330   (message-handler #:init-value actor-inheritable-message-handler
 331                    ;; @@: There's no reason not to use #:class instead of
 332                    ;;   #:each-subclass anywhere in this file, except for
 333                    ;;   Guile bug #25211 (#:class is broken in Guile 2.2)
 334                    #:allocation #:each-subclass
 335                    #:getter actor-message-handler)
 336
 337   ;; This is the default, "simple" way to inherit and process messages.
 338   (actions #:init-value (build-actions
 339                          ;; Default cleanup method is to do nothing.
 340                          (*cleanup* (const #f)))
 341            #:allocation #:each-subclass))
 342
 343 ;;; So these are the nicer representations of addresses.
 344 ;;; However, they don't serialize so easily with scheme read/write, so we're
 345 ;;; using the simpler cons cell version below for now.
 346
 347 ;; (define-record-type <address>
 348 ;;   (make-address actor-id hive-id)  ; @@: Do we want the trailing -id?
 349 ;;   address?
 350 ;;   (actor-id address-actor-id)
 351 ;;   (hive-id address-hive-id))
 352 ;;
 353 ;; (set-record-type-printer!
 354 ;;  <address>
 355 ;;  (lambda (record port)
 356 ;;    (format port "<address: ~s@~s>"
 357 ;;            (address-actor-id record) (address-hive-id record))))
 358 ;;
 359
 360 (define (make-address actor-id hive-id)
 361   (vector actor-id hive-id))
 362
 363 (define (address-actor-id address)
 364   (vector-ref address 0))
 365
 366 (define (address-hive-id address)
 367   (vector-ref address 1))
 368
 369 (define (address->string address)
 370   (string-append (address-actor-id address) "@"
 371                  (address-hive-id address)))
 372
 373 (define-method (actor-id-actor (actor <actor>))
 374   "Get the actor id component of the actor-id"
 375   (address-actor-id (actor-id actor)))
 376
 377 (define-method (actor-id-hive (actor <actor>))
 378   "Get the hive id component of the actor-id"
 379   (address-hive-id (actor-id actor)))
 380
 381 (define-method (actor-id-string (actor <actor>))
 382   "Render the full actor id as a human-readable string"
 383   (address->string (actor-id actor)))
 384
 385 (define %current-actor
 386   (make-parameter #f))
 387
 388 (define (actor-alive? actor)
 389   (hive-resolve-local-actor (actor-hive actor) (actor-id actor)))
 390
 391
 392 \f
 393 ;;; Actor utilities
 394 ;;; ===============
 395
 396 (define-syntax-rule (define-simple-actor class action ...)
 397   (define-class class (<actor>)
 398     (actions #:init-value (build-actions action ...)
 399              #:allocation #:each-subclass)))
 400
 401 \f
 402 ;;; The Hive
 403 ;;; ========
 404 ;;;   Every actor has a hive.  The hive is a kind of "meta-actor"
 405 ;;;   which routes all the rest of the actors in a system.
 406
 407 (define-generic hive-handle-failed-forward)
 408
 409 (define-class <hive> (<actor>)
 410   (actor-registry #:init-thunk make-hash-table
 411                   #:getter hive-actor-registry)
 412   (msg-id-generator #:init-thunk simple-message-id-generator
 413                     #:getter hive-msg-id-generator)
 414   ;; Ambassadors are used (or will be) for inter-hive communication.
 415   ;; These are special actors that know how to route messages to other hives.
 416   (ambassadors #:init-thunk make-weak-key-hash-table
 417                #:getter hive-ambassadors)
 418   ;; Waiting coroutines
 419   ;; This is a map from cons cell of message-id
 420   ;;   to a cons cell of (actor-id . coroutine)
 421   ;; @@: Should we have a <waiting-coroutine> record type?
 422   ;; @@: Should there be any way to clear out "old" coroutines?
 423   (waiting-coroutines #:init-thunk make-hash-table
 424                       #:getter hive-waiting-coroutines)
 425   ;; Message prompt
 426   ;; When actors send messages to each other they abort to this prompt
 427   ;; to send the message, then carry on their way
 428   (prompt #:init-thunk make-prompt-tag
 429           #:getter hive-prompt)
 430   (actions #:allocation #:each-subclass
 431            #:init-value
 432            (build-actions
 433             ;; This is in the case of an ambassador failing to forward a
 434             ;; message... it reports it back to the hive
 435             (*failed-forward* hive-handle-failed-forward)
 436             (*cleanup-all* hive-handle-cleanup-all))))
 437
 438 (define-method (hive-handle-failed-forward (hive <hive>) message)
 439   "Handle an ambassador failing to forward a message"
 440   'TODO)
 441
 442 (define-method (hive-handle-cleanup-all (hive <hive>) message)
 443   "Send a message to all actors in our registry to clean themselves up."
 444   ;; Unfortunately we have to do this hack and run over the list
 445   ;; twice, because hash-for-each would result in an unrewindable
 446   ;; continuation.
 447   (define actor-ids
 448     (hash-map->list (lambda (actor-id actor) actor-id)
 449                     (hive-actor-registry hive)))
 450   (for-each (lambda (actor-id)
 451               (<- actor-id '*cleanup*))
 452             actor-ids))
 453
 454 (define* (make-hive #:key hive-id)
 455   (let ((hive (make <hive>
 456                 #:id (make-address
 457                       "hive" (or hive-id
 458                                  (big-random-number-string))))))
 459     ;; Set the hive's actor reference to itself
 460     (set! (actor-hive hive) hive)
 461     ;; Register the actor with itself
 462     (hive-register-actor! hive hive)
 463     hive))
 464
 465 (define-method (hive-id (hive <hive>))
 466   (actor-id-hive hive))
 467
 468 (define-method (hive-gen-actor-id (hive <hive>) cookie)
 469   (make-address (if cookie
 470                     (string-append cookie ":" (big-random-number-string))
 471                     (big-random-number-string))
 472                 (hive-id hive)))
 473
 474 (define-method (hive-gen-message-id (hive <hive>))
 475   "Generate a message id using HIVE's message id generator"
 476   ((hive-msg-id-generator hive)))
 477
 478 (define-method (hive-resolve-local-actor (hive <hive>) actor-address)
 479   (hash-ref (hive-actor-registry hive) actor-address))
 480
 481 (define-method (hive-resolve-ambassador (hive <hive>) ambassador-address)
 482   (hash-ref (hive-ambassadors hive) ambassador-address))
 483
 484 (define-method (make-forward-request (hive <hive>) (ambassador <actor>) message)
 485   (make-message (hive-gen-message-id hive) (actor-id ambassador)
 486                 ;; If we make the hive not an actor, we could either switch this
 487                 ;; to #f or to the original actor...?
 488                 ;; Maybe some more thinking should be done on what should
 489                 ;; happen in case of failure to forward?  Handling ambassador failures
 490                 ;; seems like the primary motivation for the hive remaining an actor.
 491                 (actor-id hive)
 492                 '*forward*
 493                 `((original . ,message))))
 494
 495 (define-method (hive-reply-with-error (hive <hive>) original-message
 496                                       error-key error-args)
 497   ;; We only supply the error-args if the original sender is on the same hive
 498   (define (orig-actor-on-same-hive?)
 499     (equal? (hive-id hive)
 500             (address-hive-id (message-from original-message))))
 501   (set-message-replied! original-message #t)
 502   (let* ((new-message-body
 503           (if (orig-actor-on-same-hive?)
 504               `(#:original-message ,original-message
 505                 #:error-key ,error-key
 506                 #:error-args ,error-args)
 507               `(#:original-message ,original-message
 508                 #:error-key ,error-key)))
 509          (new-message (make-message (hive-gen-message-id hive)
 510                                     (message-from original-message)
 511                                     (actor-id hive) '*error*
 512                                     new-message-body
 513                                     #:in-reply-to (message-id original-message))))
 514     ;; We only return a thunk, rather than run 8sync here, because if
 515     ;; we ran 8sync in the middle of a catch we'd end up with an
 516     ;; unresumable continuation.
 517     (lambda () (hive-process-message hive new-message))))
 518
 519 (define-record-type <waiting-on-reply>
 520   (make-waiting-on-reply actor-id kont send-options)
 521   waiting-on-reply?
 522   (actor-id waiting-on-reply-actor-id)
 523   (kont waiting-on-reply-kont)
 524   (send-options waiting-on-reply-send-options))
 525
 526
 527 (define-method (hive-process-message (hive <hive>) message)
 528   "Handle one message, or forward it via an ambassador"
 529   (define (maybe-autoreply actor)
 530     ;; Possibly autoreply
 531     (if (message-needs-reply? message)
 532         (<-auto-reply actor message)))
 533
 534   (define (resolve-actor-to)
 535     "Get the actor the message was aimed at"
 536     (let ((actor (hive-resolve-local-actor hive (message-to message))))
 537       (if (not actor)
 538           (throw 'actor-not-found
 539                  (format #f "Message ~a from ~a directed to nonexistant actor ~a"
 540                          (message-id message)
 541                          (address->string (message-from message))
 542                          (address->string (message-to message)))
 543                  message))
 544       actor))
 545
 546   (define (call-catching-coroutine thunk)
 547     (define queued-error-handling-thunk #f)
 548     (define (call-catching-errors)
 549       ;; TODO: maybe parameterize (or attach to hive) and use
 550       ;;   maybe-catch-all from agenda.scm
 551       ;; @@: Why not just use with-throw-handler and let the catch
 552       ;;   happen at the agenda?  That's what we used to do, but
 553       ;;   it ended up with a SIGABRT.  See:
 554       ;;     http://lists.gnu.org/archive/html/bug-guile/2016-05/msg00003.html
 555       (catch #t
 556         thunk
 557         ;; In the actor model, we don't totally crash on errors.
 558         (lambda _ #f)
 559         ;; If an error happens, we raise it
 560         (lambda (key . args)
 561           (if (message-needs-reply? message)
 562               ;; If the message is waiting on a reply, let them know
 563               ;; something went wrong.
 564               ;; However, we have to do it outside of this catch
 565               ;; routine, or we'll end up in an unrewindable continuation
 566               ;; situation.
 567               (set! queued-error-handling-thunk
 568                     (hive-reply-with-error hive message key args)))
 569           ;; print error message
 570           (apply print-error-and-continue key args)))
 571       ;; @@: This is a kludge.  See above for why.
 572       (if queued-error-handling-thunk
 573           (8sync (queued-error-handling-thunk))))
 574     (call-with-prompt (hive-prompt hive)
 575       call-catching-errors
 576       (lambda (kont actor message send-options)
 577         ;; Register the coroutine
 578         (hash-set! (hive-waiting-coroutines hive)
 579                    (message-id message)
 580                    (make-waiting-on-reply
 581                     (actor-id actor) kont send-options))
 582         ;; Send off the message
 583         (8sync (hive-process-message hive message)))))
 584
 585   (define (process-local-message)
 586     (let ((actor (resolve-actor-to)))
 587       (call-catching-coroutine
 588        (lambda ()
 589          (define message-handler (actor-message-handler actor))
 590          ;; @@: Should a more general error handling happen here?
 591          (parameterize ((%current-actor actor))
 592            (let ((result
 593                   (message-handler actor message)))
 594              (maybe-autoreply actor)
 595              ;; Returning result allows actors to possibly make a run-request
 596              ;; at the end of handling a message.
 597              ;; ... We do want that, right?
 598              result))))))
 599
 600   (define (resume-waiting-coroutine)
 601     (case (message-action message)
 602       ;; standard reply / auto-reply
 603       ((*reply* *auto-reply* *error*)
 604        (call-catching-coroutine
 605         (lambda ()
 606           (match (hash-remove! (hive-waiting-coroutines hive)
 607                                (message-in-reply-to message))
 608             ((_ . waiting)
 609              (if (not (equal? (message-to message)
 610                               (waiting-on-reply-actor-id waiting)))
 611                  (throw 'resuming-to-wrong-actor
 612                         "Attempted to resume a coroutine to the wrong actor!"
 613                         #:expected-actor-id (message-to message)
 614                         #:got-actor-id (waiting-on-reply-actor-id waiting)
 615                         #:message message))
 616              (let* (;; @@: How should we resolve resuming coroutines to actors who are
 617                     ;;   now gone?
 618                     (actor (resolve-actor-to))
 619                     (kont (waiting-on-reply-kont waiting))
 620                     (result (kont message)))
 621                (maybe-autoreply actor)
 622                result))
 623             (#f (throw 'no-waiting-coroutine
 624                        "message in-reply-to tries to resume nonexistent coroutine"
 625                        message))))))
 626       ;; Unhandled action for a reply!
 627       (else
 628        (throw 'hive-unresumable-coroutine
 629               "Won't resume coroutine, nonsense action on reply message"
 630               #:action (message-action message)
 631               #:message message))))
 632
 633   (define (process-remote-message)
 634     ;; Find the ambassador
 635     (let* ((remote-hive-id (hive-id (message-to message)))
 636            (ambassador (hive-resolve-ambassador remote-hive-id))
 637            (message-handler (actor-message-handler ambassador))
 638            (forward-request (make-forward-request hive ambassador message)))
 639       (message-handler ambassador forward-request)))
 640
 641   (let ((to (message-to message)))
 642     ;; This seems to be an easy mistake to make, so check that addressing
 643     ;; is correct here
 644     (if (not to)
 645         (throw 'missing-addressee
 646                "`to' field is missing on message"
 647                #:message message))
 648     (if (hive-actor-local? hive to)
 649         (if (message-in-reply-to message)
 650             (resume-waiting-coroutine)
 651             (process-local-message))
 652         (process-remote-message))))
 653
 654 (define-method (hive-actor-local? (hive <hive>) address)
 655   (equal? (hive-id hive) (address-hive-id address)))
 656
 657 (define-method (hive-register-actor! (hive <hive>) (actor <actor>))
 658   (hash-set! (hive-actor-registry hive) (actor-id actor) actor))
 659
 660 (define-method (%hive-create-actor (hive <hive>) actor-class
 661                                    init id-cookie)
 662   "Actual method called by hive-create-actor.
 663
 664 Since this is a define-method it can't accept fancy define* arguments,
 665 so this gets called from the nicer hive-create-actor interface.  See
 666 that method for documentation."
 667   (let* ((actor-id (hive-gen-actor-id hive id-cookie))
 668          (actor (apply make actor-class
 669                        #:hive hive
 670                        #:id actor-id
 671                        init)))
 672     (hive-register-actor! hive actor)
 673     ;; return the actor id
 674     actor-id))
 675
 676 (define* (hive-create-actor hive actor-class #:rest init)
 677   "Create an actor on HIVE using ACTOR-CLASS passing in INIT args"
 678   (%hive-create-actor hive actor-class
 679                       init (symbol->string (class-name actor-class))))
 680
 681 (define* (hive-create-actor* hive actor-class id-cookie #:rest init)
 682   "Create an actor, but also allow customizing a 'cookie' added to the id
 683 for debugging"
 684   (%hive-create-actor hive actor-class
 685                       init id-cookie))
 686
 687 (define (call-with-message message proc)
 688   "Applies message body arguments into procedure, with message as first
 689 argument.  Similar to call-with-values in concept."
 690   (apply proc message (message-body message)))
 691
 692 ;; (msg-receive (<- bar baz)
 693 ;;     (baz)
 694 ;;   basil)
 695
 696 ;; Emacs: (put 'msg-receive 'scheme-indent-function 2)
 697
 698 ;; @@: Or receive-msg or receieve-message or??
 699 (define-syntax-rule (msg-receive arglist message body ...)
 700   "Call body with arglist (which can accept arguments like lambda*)
 701 applied from the message-body of message."
 702   (call-with-message message
 703                      (lambda* arglist
 704                        body ...)))
 705
 706 (define (msg-val message)
 707   "Retrieve the first value from the message-body of message.
 708 Like single value return from a procedure call.  Probably the most
 709 common case when waiting on a reply from some action invocation."
 710   (call-with-message message
 711                      (lambda (_ val) val)))
 712
 713 \f
 714 ;;; Various API methods for actors to interact with the system
 715 ;;; ==========================================================
 716
 717 ;; TODO: move send-message and friends here...?
 718
 719 (define* (create-actor from-actor actor-class #:rest init)
 720   "Create an instance of actor-class.  Return the new actor's id.
 721
 722 This is the method actors should call directly (unless they want
 723 to supply an id-cookie, in which case they should use
 724 create-actor*)."
 725   (%hive-create-actor (actor-hive from-actor) actor-class
 726                       init #f))
 727
 728
 729 (define* (create-actor* from-actor actor-class id-cookie #:rest init)
 730   "Create an instance of actor-class.  Return the new actor's id.
 731
 732 Like create-actor, but permits supplying an id-cookie."
 733   (%hive-create-actor (actor-hive from-actor) actor-class
 734                       init id-cookie))
 735
 736
 737 (define* (self-destruct actor #:key (cleanup #t))
 738   "Remove an actor from the hive.
 739
 740 Unless #:cleanup is set to #f, this will first have the actor handle
 741 its '*cleanup* action handler."
 742   (when cleanup
 743     (<-wait (actor-id actor) '*cleanup*))
 744   (hash-remove! (hive-actor-registry (actor-hive actor))
 745                 (actor-id actor)))
 746
 747
 748 \f
 749 ;;; 8sync bootstrap utilities
 750 ;;; =========================
 751
 752 (define* (run-hive hive initial-tasks
 753                    #:key (cleanup #t))
 754   "Start up an agenda and run HIVE in it with INITIAL-TASKS."
 755   (dynamic-wind
 756     (const #f)
 757     (lambda ()
 758       (let* ((queue (list->q initial-tasks))
 759              (agenda (make-agenda #:pre-unwind-handler print-error-and-continue
 760                                   #:queue queue)))
 761         (run-agenda agenda)))
 762     ;; Run cleanup
 763     (lambda ()
 764       (when cleanup
 765         (run-hive-cleanup hive)))))
 766
 767 (define (run-hive-cleanup hive)
 768   (let ((queue (list->q (list (bootstrap-message hive (actor-id hive)
 769                                                  '*cleanup-all*)))))
 770     (run-agenda
 771      (make-agenda #:queue queue))))
 772
 773 (define (bootstrap-message hive to-id action . message-body-args)
 774   (wrap
 775    (apply <-* `(#:actor ,hive) to-id action message-body-args)))
 776
 777
 778 \f
 779 ;;; Basic readers / writers
 780 ;;; =======================
 781
 782 (define (serialize-message message)
 783   "Serialize a message for read/write"
 784   (list
 785    (message-id message)
 786    (message-to message)
 787    (message-from message)
 788    (message-action message)
 789    (message-body message)
 790    (message-in-reply-to message)
 791    (message-wants-reply message)
 792    (message-replied message)))
 793
 794 (define* (write-message message #:optional (port (current-output-port)))
 795   "Write out a message to a port for easy reading later.
 796
 797 Note that if a sub-value can't be easily written to something
 798 Guile's `read' procedure knows how to read, this doesn't do anything
 799 to improve that.  You'll need a better serializer for that.."
 800   (write (serialize-message message) port))
 801
 802 (define (serialize-message-pretty message)
 803   "Serialize a message in a way that's easy for humans to read."
 804   `(*message*
 805     (id ,(message-id message))
 806     (to ,(message-to message))
 807     (from ,(message-from message))
 808     (action ,(message-action message))
 809     (body ,(message-body message))
 810     (in-reply-to ,(message-in-reply-to message))
 811     (wants-reply ,(message-wants-reply message))
 812     (replied ,(message-replied message))))
 813
 814 (define (pprint-message message)
 815   "Pretty print a message."
 816   (pretty-print (serialize-message-pretty message)))
 817
 818 (define* (read-message #:optional (port (current-input-port)))
 819   "Read a message serialized via serialize-message from PORT"
 820   (match (read port)
 821     ((id to from action body in-reply-to wants-reply replied)
 822      (make-message-intern
 823       id to from action body
 824       in-reply-to wants-reply replied))
 825     (anything-else
 826      (throw 'message-read-bad-structure
 827             "Could not read message from structure"
 828             anything-else))))
 829
 830 (define (read-message-from-string message-str)
 831   "Read message from MESSAGE-STR"
 832   (with-input-from-string message-str
 833     (lambda ()
 834       (read-message (current-input-port)))))